INCLUDE	AINCLUDE:IncDirs.i
		INCLUDE	datatypes/datatypes.i
		INCLUDE	dos/doshunks.i

		* assemble and save as absolute-data (no Amiga DOS executable stuff)

Start		DC.L	ID_FORM,End-Start-8,ID_DTYP

		DC.L	ID_NAME,.NameEnd-*-4
		DC.B	"REKO Cardset"
.NameEnd	EVEN

		DC.L	"ANNO",.AnnoEnd-*-4
		DC.B	"$VER: REKO_Cardset 1.2 (12.10.1999) by Dirk Stöcker <stoecker@epost.de>",0
.AnnoEnd	EVEN	* always word aligned chunks

		DC.L	ID_DTHD,.HeadEnd-*-4
.HeadBase	DC.L	.dth_Name-.HeadBase
		DC.L	.dth_BaseName-.HeadBase
		DC.L	.dth_Pattern-.HeadBase
		DC.L	0 *.dth_Mask-.HeadBase
.dth_GroupID	DC.L	GID_PICTURE
.dth_ID		DC.L	"reko"
.dth_MaskLen	DC.W	0	*4
.dth_Pad	DC.W	0
.dth_Flags	DC.W	0	*DTF_CASE
.dth_Priority	DC.W	0
*.dth_Mask 	DC.W	*"R","E","K","O"
.dth_Name	DC.B	"REKO Cardset",0
.dth_BaseName	DC.B	"reko",0
.dth_Pattern	DC.B	"#?",0
		CNOP	0,4		* necessary for CODE chunk!
.HeadEnd	EVEN	* always word aligned chunks

		DC.L	ID_CODE,.HookEnd-*-4
		DC.L	HUNK_HEADER,0,1,0,0,(.CodeEnd-.CodeStart)>>2
		DC.L	HUNK_CODE,(.CodeEnd-.CodeStart)>>2

.CodeStart	MOVEQ	#0,D0
		MOVE.L	dthc_BufferLength(A0),D1
		CMPI.L	#6,D1
		BLO.B	.no
		MOVEA.L	dthc_Buffer(A0),A1
		MOVE.L	A1,D1
		BEQ.B	.no
		CMPI.W	#'PC',(A1)
		BNE.B	.Next
		ADDQ.L	#2,A1
.Next		CMPI.L	#'REKO',(A1)
		BNE.B	.no
	  	MOVEQ	#1,D0
.no:	  	RTS
		CNOP	0,4
.CodeEnd	DC.L	HUNK_END
.HookEnd	EVEN	* always word aligned chunks

End
		END