/*
** Druck-, Vorschau, Sichern der Briefumschlag an Lieferanten C6-Format  mit Hilfe von FinalWriter
** $VER: FWUmschlagLief_C6.inbrexx V1.00 (16.11.98)
*/

PARSE ARG ARexxPort;

ADDRESS VALUE ARexxPort;
OPTIONS RESULTS;

FWVorlage	= "FWDokumente/Umschlag_C6.fw";
FWDokument	= "t:Umschlag_C6.fw";
FWPort		= "FINALW."

LF				= '0a'x;							/* Zeilenvorschub				*/

Gefunden = 0;
DO i = 1 TO 20 WHILE(Gefunden = 0)
	IF show(ports, (FWPort || i)) THEN
		DO;
			Gefunden = 1;
			FWPort 	= FWPort || i;
		END;
END;

IF Gefunden = 0 THEN
	DO;
		ES_TITLE				= "Warnung";
		ES_TEXTFORMAT		= "FinalWriter ist nicht aktiv, bitte starten sie dieses" || LF || "und versuchen Sie es erneut";
		ES_GADGETFORMAT	= "Abbrechen";
		EASY_REQUEST;
		EXIT;
	END;

/* Original FW-Dokument nach t: kopieren, um ein versehentliches überschreiben */
/* dieser Vorlage zu verhindern */
GET_REXXPATH;
FWVorlage		= MTR_RESULT || FWVorlage;
ADDRESS COMMAND "copy" FWVorlage FWDokument;

/* Oberfläche sperren */
LOCKGUI;

/* Art ermitteln: 0 = Drucken, 1 = Vorschau, 2 = Speichern */
PRINTSTATE;
Druckart = MTR_RESULT;

Ende_Kennzeichen = 'N';

/* Suchen der zu druckenden Daten */
PRINTFIND;

DO WHILE( MTR_RESULT > 0 & Ende_Kennzeichen = 'N');
	ADDRESS VALUE FWPort;
	SCREENTOFRONT;

	CALL DatenAufbereiten;
	SELECT;
		WHEN Druckart = 0 THEN	/* Drucken	*/
			DO;
				ADDRESS VALUE FWPort;
				PRINT;
				ADDRESS VALUE ARexxPort;
				MTSCREENTOFRONT;
			END;
		WHEN Druckart = 1 THEN	/* Vorschau	*/
			ADDRESS VALUE ARexxPort;
		WHEN Druckart = 2 THEN	/* Sichern	*/
			DO;
				ADDRESS VALUE FWPort;
				SAVEAS;
				ADDRESS VALUE ARexxPort;
				MTSCREENTOFRONT;
			END;
		OTHERWISE
			DO;
				ES_TITLE				= "Warnung";
				ES_TEXTFORMAT		= "Druckart wird nicht unterstützt!";
				ES_GADGETFORMAT	= "Ok";
				EASY_REQUEST;
				Ende_Kennzeichen	= 'J';
			END;
	END;

	PRINTFIND;
END;

/* WordWorth-Datei aus t: wieder entfernen */
ADDRESS COMMAND "delete" FWDokument;

/* Oberfläche wieder entsperren */
ADDRESS VALUE ARexxPort;
FREEGUI;

EXIT;

DatenAufbereiten:
	CLEARDOC;
	OPEN FWDokument;

	DruckString	= IB.OFFICE.ADDRESS.ADDRESS.2 || LF;
	i = INDEX( DruckString, LF);
	IF i > 0 THEN
		DO;
			DruckTeil	= LEFT( DruckString, (i - 1) );
			DruckString = SUBSTR(DruckString, (i + 1) );
			i = INDEX( DruckString, LF);
		END;
	ELSE
		DruckTeil	= DruckString;

	SETFIND CASE NO WRAP YES;
	FIND "<SENDER.ADDRESS.2>";
	FINDNEXT;
	STATUS LinePos;
	PARSE VAR RESULT BegLine BegPosition EndLine EndPosition;
	TYPE DruckTeil;

	DO WHILE( i > 0 );
		DruckTeil	= LEFT( DruckString, (i - 1) );
		DruckString = SUBSTR(DruckString, (i + 1) );
		BegLine		= BegLine + 1;
		MoveToLine BegLine 0;
		TYPE DruckTeil;
		i = INDEX( DruckString, LF);
	END;

	DruckString	= IB.SUPPLIER.ADDRESS.ADDRESS.2 || LF;
	i = INDEX( DruckString, LF);
	IF i > 0 THEN
		DO;
			DruckTeil	= LEFT( DruckString, (i - 1) );
			DruckString = SUBSTR(DruckString, (i + 1) );
			i = INDEX( DruckString, LF);
		END;
	ELSE
		DruckTeil	= DruckString;

	FIND "<RECEIVER.ADDRESS.2>";
	STATUS LinePos;
	PARSE VAR RESULT BegLine BegPosition EndLine EndPosition;
	TYPE DruckTeil;

	DO WHILE( i > 0 );
		DruckTeil	= LEFT( DruckString, (i - 1) );
		DruckString = SUBSTR(DruckString, (i + 1) );
		BegLine		= BegLine + 1;
		MoveToLine BegLine 0;
		TYPE DruckTeil;
		i = INDEX( DruckString, LF);
	END;
RETURN;