/*
** Druck-, Vorschau, Sichern der Überweisung der Registriersumme in EUR mit Hilfe von FinalWriter
** $VER: FWRegüberw_EUR.brarexx V1.00 (14.11.98)
*/

PARSE ARG ARexxPort;

ADDRESS VALUE ARexxPort;
OPTIONS RESULTS;

FWVorlage	= "FWDokumente/Überweisung.fw";
FWDokument	= "t:Überweisung.fw";
FWPort		= "FINALW."

LF				= '0a'x;							/* Zeilenvorschub				*/

Gefunden = 0;
DO i = 1 TO 20 WHILE(Gefunden = 0)
	IF show(ports, (FWPort || i)) THEN
		DO;
			Gefunden = 1;
			FWPort 	= FWPort || i;
		END;
END;

IF Gefunden = 0 THEN
	DO;
		ES_TITLE				= "Warnung";
		ES_TEXTFORMAT		= "FinalWriter ist nicht aktiv, bitte starten sie dieses" || LF || "und versuchen Sie es erneut";
		ES_GADGETFORMAT	= "Abbrechen";
		EASY_REQUEST;
		EXIT;
	END;

/* Original FW-Dokument nach t: kopieren, um ein versehentliches überschreiben */
/* dieser Vorlage zu verhindern */
GET_REXXPATH;
FWVorlage		= MTR_RESULT || FWVorlage;
ADDRESS COMMAND "copy" FWVorlage FWDokument;

/* Oberfläche sperren */
LOCKGUI;

/* Art ermitteln: 0 = Drucken, 1 = Vorschau, 2 = Speichern */
PRINTSTATE;
Druckart = MTR_RESULT;

Ende_Kennzeichen = 'N';

/* Suchen der zu druckenden Daten */
PRINTFIND;

DO WHILE( MTR_RESULT > 0 & Ende_Kennzeichen = 'N');
	ADDRESS VALUE FWPort;
	SCREENTOFRONT;

	CALL DatenAufbereiten;
	SELECT;
		WHEN Druckart = 0 THEN	/* Drucken	*/
			DO;
				ADDRESS VALUE FWPort;
				PRINT;
				ADDRESS VALUE ARexxPort;
				MTSCREENTOFRONT;
			END;
		WHEN Druckart = 1 THEN	/* Vorschau	*/
			ADDRESS VALUE ARexxPort;
		WHEN Druckart = 2 THEN	/* Sichern	*/
			DO;
				ADDRESS VALUE FWPort;
				SAVEAS;
				ADDRESS VALUE ARexxPort;
				MTSCREENTOFRONT;
			END;
		OTHERWISE
			DO;
				ES_TITLE				= "Warnung";
				ES_TEXTFORMAT		= "Druckart wird nicht unterstützt!";
				ES_GADGETFORMAT	= "Ok";
				EASY_REQUEST;
				Ende_Kennzeichen	= 'J';
			END;
	END;

	PRINTFIND;
END;

/* WordWorth-Datei aus t: wieder entfernen */
ADDRESS COMMAND "delete" FWDokument;

/* Oberfläche wieder entsperren */
ADDRESS VALUE ARexxPort;
FREEGUI;

EXIT;

DatenAufbereiten:

	ADDRESS VALUE FWPort;
	CLEARDOC;
	OPEN FWDokument;

	FIND "<RECEIVER.SUR_PREN>";
	FINDNEXT;
	TYPE "Tremmel Manfred";

	FIND "<R.ACCOUNT>";
	TYPE "30872";

	FIND "<R.BCM>";
	TYPE "70169495";

	FIND "<RECEIVER.BANK_NAME>";
	TYPE "Raiffeisenbank Schwindegg";

	FIND "<W>";
	TYPE "EUR";

	FIND "<B.TOTAL>";
	TYPE "15,00";
	FINDNEXT;
	TYPE "15,00";
	MoveToLine 1 1;

	FIND "RECHNUNG: <B.BILL_NUMBER>"
	TYPE "Registrierung MT-Rechnung";

	FIND "KUNDENNUMMER: <REC.NUMBER>";
	TYPE " ";

	IF OFFICE.ADDRESS.COMPANY1 > "" THEN
		ZW_Adresse = LEFT( (OFFICE.ADDRESS.COMPANY1 || ", " ||OFFICE.ADDRESS.CITY), 27);
	ELSE
		ZW_Adresse = LEFT( (OFFICE.ADDRESS.PRENAME OFFICE.ADDRESS.SURNAME || ", " ||OFFICE.ADDRESS.CITY), 27);
	FIND "<SENDER.SUR_PRENAME>";
	TYPE ZW_Adresse;

	FIND "<S.ACCOUNT>";
	TYPE LEFT(OFFICE.ADDRESS.ACCOUNT, 10);

RETURN;