/*
** Druck-, Vorschau, Sichern der Adressenübersicht mit Hilfe von WordWorth
** $VER: WWAdressüber.adrrexx V1.00 (28.08.98)
*/

PARSE ARG ARexxPort;

ADDRESS VALUE ARexxPort;
OPTIONS RESULTS;

WWVorlage	= "WWDokumente/Adressübersicht.ww";
WWDokument	= "t:Adressübersicht.ww";
WWPort		= "WORDWORTH."

LF					= '0a'x;							/* Zeilenvorschub				*/

Gefunden = 0;
DO i = 1 TO 20 WHILE(Gefunden = 0)
	IF show(ports, (WWPort || i)) THEN
		DO;
			Gefunden = 1;
			WWPort = WWPort || i;
		END;
END;

IF Gefunden = 0 THEN
	DO;
		ES_TITLE				= "Warnung";
		ES_TEXTFORMAT		= "WordWorth ist nicht aktiv, bitte starten sie dieses" || LF || "und versuchen Sie es erneut";
		ES_GADGETFORMAT	= "Abbrechen";
		EASY_REQUEST;
		EXIT;
	END;

/* Original WW-Dokument nach t: kopieren, um ein versehentliches überschreiben */
/* dieser Vorlage zu verhindern */
GET_REXXPATH;
WWVorlage		= MTR_RESULT || WWVorlage;
ADDRESS COMMAND "copy" WWVorlage WWDokument;

/* Oberfläche sperren */
LOCKGUI;

/* Art ermitteln: 0 = Drucken, 1 = Vorschau, 2 = Speichern */
PRINTSTATE;
Druckart = MTR_RESULT;

Ende_Kennzeichen = 'N';

/* Suchen der zu druckenden Daten */
GET_PREFS;
PRINTFIND;

/* Neues Dokument öffnen */
ADDRESS VALUE WWPort;
NEW;
WWPort = RESULT;

IF (MTR_RESULT > 0 & Ende_Kennzeichen = 'N') THEN
	DO;
		CALL DatenAufbereiten;
		SELECT;
			WHEN Druckart = 0 THEN	/* Drucken	*/
				DO;
					ADDRESS VALUE WWPort;
					PRINT;
					ADDRESS VALUE ARexxPort;
					MTSCREENTOFRONT;
				END;
			WHEN Druckart = 1 THEN	/* Vorschau	*/
				ADDRESS VALUE ARexxPort;
			WHEN Druckart = 2 THEN	/* Sichern	*/
				DO;
					ADDRESS VALUE WWPort;
					SAVEAS;
					ADDRESS VALUE ARexxPort;
					MTSCREENTOFRONT;
				END;
			OTHERWISE
				DO;
					ES_TITLE				= "Warnung";
					ES_TEXTFORMAT		= "Druckart wird nicht unterstützt!";
					ES_GADGETFORMAT	= "Ok";
					EASY_REQUEST;
					Ende_Kennzeichen	= 'J';
				END;
		END;
	END;

/* WordWorth-Datei aus t: wieder entfernen */
ADDRESS COMMAND "delete" WWDokument;

/* Oberfläche wieder entsperren */
ADDRESS VALUE ARexxPort;
FREEGUI;

EXIT;

DatenAufbereiten:

	ADDRESS VALUE WWPort;
	OPEN FILENAME WWDokument FORCE;
	POSITION SOF;
	SHIFTDOWN;
	LINE 3;
	SHIFTUP;
	CUT;

	DO WHILE( MTR_RESULT > 0 & Ende_Kennzeichen = 'N');
		ADDRESS VALUE WWPort;
		POSITION EOF;
		PASTE;

		IF PREFS.NUMBER_DIGITS > 0 THEN
			ZW_Nummer = RIGHT( (Copies("0",PREFS.NUMBER_DIGITS) || MTR_RESULT), PREFS.NUMBER_DIGITS );
		ELSE
			ZW_Nummer = MTR_RESULT;

		IF ADDRESS.COMPANY1 > "" THEN
			ZW_Name = ADDRESS.COMPANY1;
		ELSE
			ZW_Name = ADDRESS.PRENAME ADDRESS.SURNAME;

		POSITION SOF;
		FINDCHANGE FIND "<NR>" CHANGE ZW_Nummer;
		FINDCHANGE FIND "<COMPANY_NAME>" CHANGE ZW_Name;
		FINDCHANGE FIND "<STREET>" CHANGE ADDRESS.STREET;
		FINDCHANGE FIND "<ZIP>" CHANGE ADDRESS.ZIP;
		FINDCHANGE FIND "<CITY>" CHANGE ADDRESS.CITY;
		FINDCHANGE FIND "<PHONE>" CHANGE ADDRESS.PHONE;
		FINDCHANGE FIND "<FAX>" CHANGE ADDRESS.FAX;
		FINDCHANGE FIND "<E-MAIL>" CHANGE ADDRESS.EMAIL.0;

		ADDRESS VALUE ARexxPort;
		PRINTFIND;
	END;
RETURN;