/*
** Druck-, Vorschau, Sichern der Bestellung mit Hilfe von FinalWriter
** $VER: FWBestellung2.inbrexx V1.00 (27.11.98)
*/

PARSE ARG ARexxPort;

ADDRESS VALUE ARexxPort;
OPTIONS RESULTS;

FWVorlage	= "FWDokumente/Bestellung2.fw";
FWDokument	= "t:Bestellung2.fw";
FWPort		= "FINALW."

LF				= '0a'x;							/* Zeilenvorschub				*/

Gefunden = 0;
DO i = 1 TO 20 WHILE(Gefunden = 0)
	IF show(ports, (FWPort || i)) THEN
		DO;
			Gefunden = 1;
			FWPort 	= FWPort || i;
		END;
END;

IF Gefunden = 0 THEN
	DO;
		ES_TITLE				= "Warnung";
		ES_TEXTFORMAT		= "FinalWriter ist nicht aktiv, bitte starten sie dieses" || LF || "und versuchen Sie es erneut";
		ES_GADGETFORMAT	= "Abbrechen";
		EASY_REQUEST;
		EXIT;
	END;

/* Original FW-Dokument nach t: kopieren, um ein versehentliches überschreiben */
/* dieser Vorlage zu verhindern */
GET_REXXPATH;
FWVorlage		= MTR_RESULT || FWVorlage;
ADDRESS COMMAND "copy" FWVorlage FWDokument;

/* Oberfläche sperren */
LOCKGUI;

/* Art ermitteln: 0 = Drucken, 1 = Vorschau, 2 = Speichern */
PRINTSTATE;
Druckart = MTR_RESULT;

Ende_Kennzeichen = 'N';

/* Suchen der zu druckenden Daten */
GET_PREFS;
PRINTFIND;

DO WHILE( MTR_RESULT > 0 & Ende_Kennzeichen = 'N');
	ADDRESS VALUE FWPort;
	SCREENTOFRONT;

	CALL DatenAufbereiten;
	SELECT;
		WHEN Druckart = 0 THEN	/* Drucken	*/
			DO;
				ADDRESS VALUE FWPort;
				PRINT;
				ADDRESS VALUE ARexxPort;
				MTSCREENTOFRONT;
			END;
		WHEN Druckart = 1 THEN	/* Vorschau	*/
			ADDRESS VALUE ARexxPort;
		WHEN Druckart = 2 THEN	/* Sichern	*/
			DO;
				ADDRESS VALUE FWPort;
				SAVEAS;
				ADDRESS VALUE ARexxPort;
				MTSCREENTOFRONT;
			END;
		OTHERWISE
			DO;
				ES_TITLE				= "Warnung";
				ES_TEXTFORMAT		= "Druckart wird nicht unterstützt!";
				ES_GADGETFORMAT	= "Ok";
				EASY_REQUEST;
				Ende_Kennzeichen	= 'J';
			END;
	END;

	PRINTFIND;
END;

/* WordWorth-Datei aus t: wieder entfernen */
ADDRESS COMMAND "delete" FWDokument;

/* Oberfläche wieder entsperren */
ADDRESS VALUE ARexxPort;
FREEGUI;

EXIT;

DatenAufbereiten:

	ADDRESS VALUE ARexxPort;

	FORMAT_DATE_LONG date(s);
	PRINTDATE = MTR_RESULT;

	FORMAT_DATE_LONG IB.DATE_ORDER;
	IF MTR_RESULT = "" THEN
		DATE_ORDER = " ";
	ELSE
		DATE_ORDER = MTR_RESULT;

	w = IB.CURRENCY_USED;
	IF w < 2 THEN
		FORMAT_MONEY1 IB.TOTAL_M_ALL_CH.w;
	ELSE
		FORMAT_MONEY2 IB.TOTAL_M_ALL_CH.w;
	ZW_Betrag	= MTR_RESULT;

	IF w < 2 THEN
		FORMAT_MONEY1 IB.DISPATCH_COSTS.w;
	ELSE
		FORMAT_MONEY2 IB.DISPATCH_COSTS.w;
	ZW_Versand	= MTR_RESULT;

	FORMAT_NUMBER IB.DISCOUNT_PERCENT PREFS.FRAC_DIGITS_PERCENT;
	DISP	= MTR_RESULT;

	IF w < 2 THEN
		FORMAT_MONEY1 IB.DISCOUNT.w;
	ELSE
		FORMAT_MONEY2 IB.DISCOUNT.w;
	DIS	= MTR_RESULT;

	IF w < 2 THEN
		FORMAT_MONEY1 IB.TOTAL_M_ALL_CH.0;
	ELSE
		FORMAT_MONEY2 IB.TOTAL_M_ALL_CH.2;
	SUM_NET		= MTR_RESULT;

	IF w < 2 THEN
		FORMAT_MONEY1 IB.TOTAL_M_ALL_CH.1;
	ELSE
		FORMAT_MONEY2 IB.TOTAL_M_ALL_CH.3;
	SUM_GROSS	= MTR_RESULT;

	ADDRESS VALUE FWPort;
	CLEARDOC;
	OPEN FWDokument;

	DruckString	= IB.OFFICE.ADDRESS.ADDRESS.2 || LF;
	i = INDEX( DruckString, LF);
	IF i > 0 THEN
		DO;
			DruckTeil	= LEFT( DruckString, (i - 1) );
			DruckString = SUBSTR(DruckString, (i + 1) );
			i = INDEX( DruckString, LF);
		END;
	ELSE
		DruckTeil	= DruckString;
	FIND "<OFFICE.ADDRESS.2>";
	FINDNEXT;
	STATUS LinePos;
	PARSE VAR RESULT BegLine BegPosition EndLine EndPosition;
	TYPE DruckTeil;
	FIND "<PRINTDATE>"
	TYPE PRINTDATE;

	DO WHILE( i > 0 );
		DruckTeil	= LEFT( DruckString, (i - 1) );
		DruckString = SUBSTR(DruckString, (i + 1) );
		BegLine		= BegLine + 1;
		MoveToLine BegLine 0;
		TYPE DruckTeil;
		i = INDEX( DruckString, LF);
	END;

	FIND "<OFFICE.ADDRESS.ADDRESS.0>";
	TYPE IB.OFFICE.ADDRESS.ADDRESS.0;

	DruckString	= IB.SUPPLIER.ADDRESS.ADDRESS.2 || LF;
	i = INDEX( DruckString, LF);
	IF i > 0 THEN
		DO;
			DruckTeil	= LEFT( DruckString, (i - 1) );
			DruckString = SUBSTR(DruckString, (i + 1) );
			i = INDEX( DruckString, LF);
		END;
	ELSE
		DruckTeil	= DruckString;
	FIND "<CUSTOMER.ADDRESS.ADDRESS.2>";
	STATUS LinePos;
	PARSE VAR RESULT BegLine BegPosition EndLine EndPosition;
	TYPE DruckTeil;
	DO WHILE( i > 0 );
		DruckTeil	= LEFT( DruckString, (i - 1) );
		DruckString = SUBSTR(DruckString, (i + 1) );
		BegLine		= BegLine + 1;
		MoveToLine BegLine 0;
		TYPE DruckTeil;
		i = INDEX( DruckString, LF);
	END;


	FIND "<IB.CLIENT_CODE>";
	IF IB.SUPPLIER.CLIENT_CODE = "" THEN
		TYPE " ";
	ELSE
		TYPE IB.SUPPLIER.CLIENT_CODE;
	FIND "<IB.DATE_ORDER>";
	TYPE DATE_ORDER;
	FIND "<IB.EMPLOYEE.SUR_PRENAME>";
	TYPE (IB.EMPLOYEE.ADDRESS.PRENAME IB.EMPLOYEE.ADDRESS.SURNAME);

	FIND "<ARTICLE>";
	STATUS LinePos;
	PARSE VAR RESULT BegLine BegPosition EndLine EndPosition;
	BACKSPACE;

	DO i = 1 to IB.COUNT_ARTICLE;

		ADDRESS VALUE ARexxPort;

		ZW_ArtikelNr	= IB.i.POS_ARTICLE_NUMBER_FORMATED;

		FORMAT_NUMBER (IB.i.POS_QUANTITY / IB.i.POS_PRICE_UNIT) PREFS.FRAC_DIGITS;
		ZW_Anzahl		= MTR_RESULT;

		NAME_OF_QUANTITY_UNIT IB.i.ARTICLE.QUANTITY_UNIT;
		ZW_Einheit		= MTR_RESULT;

		j = IB.i.POS_VALUE;
		FORMAT_NUMBER IB.VALUE_PERCENT.j PREFS.FRAC_DIGITS_PERCENT;
		ZW_MWSt			= MTR_RESULT;

		ZW_Bezeichnung = IB.i.ARTICLE.DESCRIPTION;

		IF w < 2 THEN
			FORMAT_MONEY1 IB.i.POS_SINGLE_PRICE.w;
		ELSE
			FORMAT_MONEY2 IB.i.POS_SINGLE_PRICE.w;
		ZW_EinzelPreis	= MTR_RESULT;
		
		ADDRESS VALUE FWPort;

		TYPE ZW_ArtikelNr || "	" || ZW_Anzahl || "	" || ZW_Bezeichnung || "	" || ZW_Einheit || "	" || ZW_MWSt || "	" || ZW_EinzelPreis;

		IF IB.i.ARTICLE.ADDITIONAL_TEXT > "" THEN
			DO;
				DruckString	= IB.i.ARTICLE.ADDITIONAL_TEXT || LF;
				i2 = INDEX( DruckString, LF);
				DO WHILE( i2 > 0 );
					DruckTeil	= LEFT( DruckString, (i2 - 1) );
					DruckString = SUBSTR(DruckString, (i2 + 1) );
					BegLine		= BegLine + 1;
					MoveToLine BegLine 0;
					TYPE "		" || DruckTeil || "			";
					i2 = INDEX( DruckString, LF);
				END;
			END;

		IF IB.i.POS_REMARK > "" THEN
			DO;
				DruckString	= IB.i.POS_REMARK || LF;
				i2 = INDEX( DruckString, LF);
				DO WHILE( i2 > 0 );
					DruckTeil	= LEFT( DruckString, (i2 - 1) );
					DruckString = SUBSTR(DruckString, (i2 + 1) );
					BegLine		= BegLine + 1;
					MoveToLine BegLine 0;
					TYPE "		" || DruckTeil || "			";
					i2 = INDEX( DruckString, LF);
				END;
			END;

		DO i2 = 0 TO 2;
			IF IB.i.POS_ADD_RED_USED.i2 > 0 THEN
				DO;
					ADDRESS VALUE ARexxPort;

					j2 = IB.i.POS_ADD_RED_USED.i2 - 1;
					IF IB.i.POS_ADD_RED_TYPE.i2 = 0 | IB.i.POS_ADD_RED_TYPE.i2 = 5 THEN
						DO;
							FORMAT_NUMBER IB.i.POS_ADD_RED_VALUE.i2.w PREFS.FRAC_DIGITS_PERCENT;
						END;
					ELSE
						DO;
							IF w < 2 THEN
								FORMAT_MONEY1 IB.i.POS_ADD_RED_VALUE.i2.w;
							ELSE
								FORMAT_MONEY2 IB.i.POS_ADD_RED_VALUE.i2.w;
						END;
					ZW_EinzelZuAb	= RIGHT(MTR_RESULT, 15);

					IF w < 2 THEN
						FORMAT_MONEY1 IB.i.POS_ADD_RED_VALUE_POS.i2.w;
					ELSE
						FORMAT_MONEY2 IB.i.POS_ADD_RED_VALUE_POS.i2.w;
					ZW_PosZuAb		= RIGHT(MTR_RESULT, 15);

					ADDRESS VALUE FWPort;
					BegLine		= BegLine + 1;
					MoveToLine BegLine 0;
					TYPE "		" || PREFS.ADD_RED_TEXT.j2 || "		" || ZW_EinzelZuAb || "	" || ZW_PosZuAb;
				END;
		END;

		ADDRESS VALUE ARexxPort;

		IF w < 2 THEN
			FORMAT_MONEY1 IB.i.POS_SUM_M_ALL.w;
		ELSE
			FORMAT_MONEY2 IB.i.POS_SUM_M_ALL.w;
		ZW_PosPreis		= MTR_RESULT;

		ADDRESS VALUE FWPort;
		TYPE "	" || ZW_PosPreis;
		BegLine		= BegLine + 1;
		MoveToLine BegLine 0;

	END;

	FIND "<DESCRIPTION>";
	j2 = 0;
	IF IB.REMARK > "" THEN
		DO;
			DruckString	= IB.REMARK || LF;
			i2 = INDEX( DruckString, LF);
			DO WHILE( i2 > 0 );
				DruckTeil	= LEFT( DruckString, (i2 - 1) );
				DruckString = SUBSTR(DruckString, (i2 + 1) );
				IF j2 > 0 THEN
					NEWPARAGRAPH;
				TYPE DruckTeil;
				i2 = INDEX( DruckString, LF);
				j2 = j2 + 1;
			END;
		END;
	ELSE
		DO;
			STATUS LinePos;
			PARSE VAR RESULT BegLine BegPosition EndLine EndPosition;
			MoveToLine BegLine 0;
			ShiftDown;
			MoveToLine (BegLine + 2) 0;
			ShiftUp;
			DELETE;
		END;

	FIND "<DISPATCH>";
	TYPE ZW_Versand;

	FIND "<VALUE>";
	STATUS LinePos;
	PARSE VAR RESULT BegLine BegPosition EndLine EndPosition;
	MoveToLine BegLine 0;
	ShiftDown;
	MoveToLine (BegLine + 1) 0;
	ShiftUp;
	COPY;

	j = 0;
	DO i = 0 to 9;
		IF IB.VALUE_M_ALL_CH.i.0 > 0 THEN
			DO;
				ADDRESS VALUE ARexxPort;
				FORMAT_NUMBER IB.VALUE_PERCENT.i PREFS.FRAC_DIGITS_PERCENT;
				ZW_MWStProzentsatz	= MTR_RESULT;
				IF w < 2 THEN
					FORMAT_MONEY1 IB.VALUE_M_ALL_CH.i.0;
				ELSE
					FORMAT_MONEY2 IB.VALUE_M_ALL_CH.i.1;
				ZW_MWStBetrag			= MTR_RESULT;

				ADDRESS VALUE FWPort;
				j = j + 1;
				IF j > 1 THEN
					DO;
						BegLine = BegLine + 1;
						MoveToLine BegLine 0;
						PASTE;
					END;
				MoveToLine BegLine 0;
				FIND "<VALUEP>";
				TYPE ZW_MWStProzentsatz;
				FIND "<VALUE>";
				TYPE ZW_MWStBetrag;
			END;
	END;

	IF j = 0 THEN
		DO;
			MoveToLine BegLine 0;
			ShiftDown;
			MoveToLine (BegLine + 2) 0;
			ShiftUp;
			DELETE;
		END;

	FIND "<ADD_RED_TEXT>";
	STATUS LinePos;
	PARSE VAR RESULT BegLine BegPosition EndLine EndPosition;
	MoveToLine BegLine 0;
	ShiftDown;
	MoveToLine (BegLine + 1) 0;
	ShiftUp;
	COPY;

	i2 = 0;
	DO i = 0 to 2;
		IF IB.ADD_RED_USED.i > 0 THEN
			DO;
				IF i2 > 0 THEN
					DO;
						BegLine = BegLine + 1;
						MoveToLine BegLine 0;
						PASTE;
					END;

				MoveToLine BegLine 0;
				ADDRESS VALUE ARexxPort;
				j2 = IB.ADD_RED_USED.i - 1;
				IF IB.ADD_RED_TYPE.i = 0 | IB.ADD_RED_TYPE.i = 5 THEN
					DO;
						FORMAT_NUMBER IB.ADD_RED_VALUE.i.w PREFS.FRAC_DIGITS_PERCENT;
					END;
				ELSE
					DO;
						IF w < 2 THEN
							FORMAT_MONEY1 IB.ADD_RED_VALUE.i.w;
						ELSE
							FORMAT_MONEY2 IB.ADD_RED_VALUE.i.w;
					END;
				ZW_EinzelPreis	= MTR_RESULT;

				IF w < 2 THEN
					FORMAT_MONEY1 IB.ADD_RED_VALUE_POS.i.w;
				ELSE
					FORMAT_MONEY2 IB.ADD_RED_VALUE_POS.i.w;
				ZW_PosPreis		= MTR_RESULT;

				ADDRESS VALUE FWPort;
				FIND "<ADD_RED_TEXT>";
				TYPE PREFS.ADD_RED_TEXT.j2;
				FIND "<ADD_RED>";
				TYPE ZW_EinzelPreis;
				FIND "<ADD_RED_POS>";
				TYPE ZW_PosPreis;
				i2 = i2 + 1;
			END;
	END;

	IF i2 = 0 THEN
		DO;
			MoveToLine BegLine 0;
			ShiftDown;
			MoveToLine (BegLine + 2) 0;
			ShiftUp;
			DELETE;
		END;

	FIND "<DISP>";
	TYPE DISP;
	FIND "<DIS>";
	TYPE DIS;

	FIND "<SUM_NET>";
	TYPE SUM_NET;
	FIND "<SUM_GROSS>";
	TYPE SUM_GROSS;

	FIND "<BANK_NAME>";
	TYPE IB.OFFICE.ADDRESS.BANK_NAME;
	FIND "<BANK_CODE>";
	TYPE IB.OFFICE.ADDRESS.BANK_CODE_NUMBER;
	FIND "<ACCOUNT>";
	TYPE IB.OFFICE.ADDRESS.ACCOUNT;

RETURN;