/* MiamiOnline.yam - Go online in Miami
 *
 * $VER: MiamiOnline.yam 1.02 (7.8.01) © H. van der Ree <hivdree@uwnet.nl>
 *
 * Don't forget to change miamipath into the one you use!
 *                        ---------
 * If you use WBStartEmu change wbstarter on line 58 into wbrun!
 *                              ---------                 -----
 */

OPTIONS RESULTS

PARSE ARG args .

/* Change this path if required */
miamipath = "Miami:Miami"
miamiport = "MIAMI.1"

IF ~SHOW('L', 'rexxsupport.library') THEN
  CALL ADDLIB('rexxsupport.library', 0, -30)
IF ~SHOW('L', 'rexxdossupport.library') THEN
  CALL ADDLIB('rexxdossupport.library', 0, -30)

action = GETVAR(YAMSTARTED, "GLOBAL")
IF action = "YES" THEN
DO
  CALL DELETEVAR(YAMSTARTED, "GLOBAL")
  EXIT 0
END

IF pos("NEWS", upper(args)) ~= 0 THEN
DO
  CALL OPEN('FS', 'T:YAMSTATUSLIST', 'W')
  ADDRESS YAM
  SETFOLDER 'Outgoing'
  FOLDERINFO STEM folder.
  LISTSELECT None
  DO i = 0 TO folder.TOTAL - 1
    SETMAIL i
    MAILINFO STEM mess.
    IF POS("@NEWS", upper(mess.TO)) ~= 0 THEN
    DO
      IF upper(mess.STATUS) ~= 'H' THEN
      DO
        CALL SETVAR("CHANGEDYAMSTATUS", "YES", "GLOBAL")
        CALL WRITELN(FS, mess.MSGID)
        MAILSTATUS H
      END
    END
  END
  LISTSELECT ALL
  CALL CLOSE(FS)
END

IF ~SHOW('P', miamiport) THEN
DO
  ADDRESS COMMAND
  'wbstarter' miamipath
  'WaitForPort' miamiport
  CALL SETVAR(STARTEDBYYAM, "YES", "GLOBAL")
  started = "YES"
  CALL DELAY(100)
END

ADDRESS VALUE miamiport
ISONLINE
RCN = RC
IF RCN ~= 1 THEN
DO
  SHOW
  CALL SETVAR(YAMSTART, "YES", "GLOBAL")
  IF RCN ~= 2 THEN
  DO
    ONLINE
  END
  RCN = 0
  DO UNTIL RCN = 1
    ISONLINE
    RCN = RC
    IF RCN = 0 THEN
    DO
      CALL DELETEVAR(YAMSTART, "GLOBAL")
      EXIT 5
    END
    IF RCN ~= 1 THEN CALL DELAY(100)
  END
  CALL DELAY(100)
END
ELSE
DO
  IF started = "YES" THEN
  DO
    CALL SETVAR(YAMSTART, "YES", "GLOBAL")
    CALL DELAY(100)
  END
  ELSE
  DO
    IF pos("CLOSE", upper(args)) ~= 0 THEN
    DO
      ADDRESS 'YAM'
      'REQUEST "Go OffLine after getting email?" "_Yes|_No"'
      IF RESULT = 1 THEN
        CALL SETVAR(YAMSTART, "YES", "GLOBAL")
    END
  END
END

EXIT 0