; $VER: Install UrlBase 1.0 (21.06.2001)

set PATH `cd`       ; default path [PROGDIR]
set UDIR $PATH      ; default installation path
set PATT "#?(.awebrx|.rexx|.yam|_URL)"
set STR "WORK:Caches/"
set DIR "UrlBase"
set INF ".info"
set ISA "false"
set ISY "false"

ASSIGN "AWeb:" EXISTS >NIL:
If WARN
    ASSIGN "AWeb3:" EXISTS >NIL:
    If WARN
        set ADIR "ram:"
    ELSE
        set ADIR "AWeb3:"
    EndIf
ELSE
    set ADIR "AWeb:"
EndIf
ASSIGN "Yam:" EXISTS >NIL:
If WARN
    set YDIR "ram:"
ELSE
    set YDIR "Yam:"
EndIf

; Start - MAINMENU
Lab MAINMENU
requestchoice TITLE "Batch: Install UrlBase" BODY "*nPlease select the path, where you*nwant the UrlBase to be copied to!*n" GADGETS "Select|Abort" >ENV:CHOICE
IF VAL $CHOICE EQ 1
    skip PATHMENU
ENDIF
IF VAL $CHOICE EQ 0
    skip EXITMENU
ENDIF
; End - MAINMENU

; Start - DOMENU
Lab DOMENU
requestchoice TITLE "Batch: Install UrlBase" BODY "*nPlease make your choice, if you*nwant the UrlBase to be installed at:*n*n*"$UDIR*"*n" GADGETS "Install|Select|Abort" >ENV:CHOICE
IF VAL $CHOICE EQ 1
    skip INSTALL
ENDIF
IF VAL $CHOICE EQ 2
    skip PATHMENU
ENDIF
IF VAL $CHOICE EQ 0
    skip EXITMENU
ENDIF
; End - DOMENU

; Start - PROMENU
Lab PROMENU
requestchoice TITLE "Batch: Install UrlBase Plugins" BODY "*nPlease make your choice, if you*nwant the Plugins to be installed.*n*nUrlBase installed: true*n AWEB installed: $ISA*n  YAM installed: $ISY*n" GADGETS "AWeb|Yam|Abort" >ENV:CHOICE
IF VAL $CHOICE EQ 1
    IF $ADIR EQ "ram:"
        requestfile DRAWER "$ADIR" TITLE "Select AWeb Path..." DRAWERSONLY NOICONS >ENV:CHOICE
        IF NOT WARN
            set ADIR $CHOICE
            skip AWEB
        ELSE
            skip PROMENU BACK
        ENDIF
    ELSE
        skip AWEB
    ENDIF
ENDIF
IF VAL $CHOICE EQ 2
    IF $YDIR EQ "ram:"
        requestfile DRAWER "$YDIR" TITLE "Select Yam Path..." DRAWERSONLY NOICONS >ENV:CHOICE
        IF NOT WARN
            set YDIR $CHOICE
            skip YAM
        ELSE
            skip PROMENU BACK
        ENDIF
    ELSE
        skip YAM
    ENDIF
ENDIF
IF VAL $CHOICE EQ 0
    skip EXITMENU
ENDIF
; End - PROMENU

; Start - EXITMENU
Lab EXITMENU
    unsetenv CHOICE
    quit
; End - EXITMENU

; Start - PATHMENU
Lab PATHMENU
requestfile DRAWER "$UDIR" TITLE "Select UrlBase Path..." DRAWERSONLY NOICONS >ENV:CHOICE
IF NOT WARN
    set UDIR $CHOICE
    skip DOMENU BACK
ELSE
    skip MAINMENU BACK
ENDIF
; End - PATHMENU

; Start - INSTALL
Lab INSTALL
    echo >Install.log "START - Installing UrlBase to *"$UDIR*""
    makedir >>Install.log "$UDIR$DIR"
    copy >>Install.log "$DIR$INF" TO "$UDIR"
    echo >>Install.log "Replacing 'url_base' value from *"$STR$DIR*" to *"$UDIR$DIR*""
    list "$PATH" PAT "$PATT" ALL FILES LFORMAT "c/replace *"%p%n*" *"$STR*" *"$UDIR*" I" >T:Cmd.tmp
    Stack 20000
    execute T:Cmd.tmp
    Delete T:Cmd.tmp QUIET
    protect >>Install.log "$PATT" +s ALL
    copy >>Install.log FROM "$DIR" TO "$UDIR$DIR" ALL
    copy >>Install.log "C/RequestString" TO "C:RequestString"
    copy >>Install.log FROM "S" TO "S:" ALL
    echo >>Install.log "FINISH - Installing UrlBase complete!"
    copy "env:sys/def_project.info" TO "Install.log.info" QUIET
    skip PROMENU BACK
; End - INSTALL

; Start - AWEB
Lab AWEB
    IF $ISA EQ "false"
        echo >>Install.log "START - Installing AWeb Plugin"
        copy >>Install.log FROM "AWeb" TO "$ADIR" ALL
        echo >>Install.log "FINISH - Installing AWeb Plugin complete!"
        set ISA "true"
    ENDIF
    skip PROMENU BACK
; End - AWEB

; Start - YAM
Lab YAM
    IF $ISY EQ "false"
        echo >>Install.log "START - Installing YAM Script"
        copy >>Install.log FROM "YAM" TO "$YDIR" ALL
        echo >>Install.log "FINISH - Installing YAM Script complete!"
        set ISY "true"
    ENDIF
    skip PROMENU BACK
; End - YAM