;Install script for SCDPlayer 1.5.1
;©1996 Juan Jesús García de Soria Lucena
;
;ENGLISH
(
    (set #making_drawer "Making SCDPlayer's drawer...")
    (set #copying_icons "Copying icons...")
    (set #copying_program "Copying SCDPlayer's binary...")
    (set #copying_lyrics "Copying SCDPLyrics ARexx module...")
    (set #copying_support "Copying support executable...")
    (set #making_arexx "Making drawer for ARexx scripts...")
    (set #copying_arexx "Copying ARexx scripts...")
    (set #copying_docs "Copying AmigaGuide® docs...")
    (set #making_disks "Making Disks drawer...")
    (set #making_images "Making Images drawer...")
    (set #catalogs "Installing catalog files...")
    (set #enter_device "Enter the device driver name for your CD-Rom drive (for example 'scsi.device').")
    (set #dev_help (cat
        "Enter the device driver name for your CD-Rom drive here. This should be the same as found in"
        " 'DEVICE=' line in the mountlist for your CD-Rom.\nIf you are not sure, check"
        " 'devs:dosdrivers/CD0' if you are running Workbench 2.1 or up, or 'devs:mountlist' otherwise."
    ))
    (set #ask_dir "Select in which directory the drawer 'SCDPlayer' will be created.")
    (set #dir_help (cat
        "You must select now in which directory install SCDPlayer. A new drawer named 'SCDPlayer'"
        " will be created there.\n"
        @askdir-help
    ))
    (set #enter_unit "Enter the device driver unit number for your CD-Rom drive.")
    (set #unit_help (cat
        "Enter the device driver unit number for your CD-Rom drive here. This should be the same as found in"
        " 'UNIT=' line in the mountlist for your CD-Rom.\nIf you are not sure, check"
        " 'devs:dosdrivers/CD0' if you are running Workbench 2.1 or up, or 'devs:mountlist' otherwise."
    ))
    (set #ok_vals "The following values for your CD-Rom drive have been obtained from a previous installation:\n")
    (set #ok_vals2 "Are they ok?")
    (set #ask_choices "Which elements do you wish to install?")
    (set #choice1 "SCDPlayer")
    (set #choice2 "SCDPlayer docs")
    (set #choice3 "SCDPlayer catalogs")
    (set #choice4 "Example ARexx scripts")
    (set #choice5 "SCDPlayer sources")
    (set #choice6 "SCDPlayer button images")
    (set #choice7 "SCDPLyrics ARexx module")
    (set #choice8 "'Delay' support executable")
    (set #parts_help (cat "Select which parts do you want to install." @askoptions-help))
    (set #msg_scdpdir "About to make 'SCDPlayer' drawer.")
    (set #msg_scdpprogram "SCDPlayer program will get copied now.")
    (set #msg_scdpdocs "Proceeding to copy documentation.")
    (set #diskdrwhelp "If you will use ID-files in another directory, skip this.")
    (set #copying_images "Copying images for buttons.")
    (set #imagesnormal "Standard SCDPlayer images")
    (set #images3d "3D images")
    (set #selectimages "Select which style of images for the buttons do you wish to install:")
    (set #imageshelp (cat
        "Standard images are solid black symbols on default background colour,"
        "3D ones are embossed, but a little less readable.\n"
        @askchoice-help
    ))
    (set #selecticons "Select which style of icons to install:")
    (set #newicons "NewIcons style")
    (set #magicwb1 "MagicWB style 1")
    (set #magicwb2 "MagicWB style 2")
    (set #iconshelp (cat
        "MagicWB 1 & 2 styles differ in SCDPlayer's executable icon."
        " Type 1 has a CD and a musical score, while type 2"
        " has a CD and MUI symbol.\n"
        @askchoice-help
    ))
    (set #catselect "Select which catalogs to install:")
    (set #catdeutsch "Deutsch")
    (set #catespañol "Español")
    (set #catnorsk "Norsk")
    (set #catsvenska "Svenska")
    (set #catfrançais "Français")
    (set #cathelp (cat
        "Select which catalog files you wish to install. SCDPlayer will be automatically"
        " translated to your preferred language if it's selected in your Locale Preferences.\n"
        @askoptions-help
    ))
    (set #copying_sources "Copying SCDPlayer's sources...")
    
    (set #catbits 0)

    (set #docselect "Select which AmigaGuide® docs to install:")
    (set #docdeutsch "Deutsch")
    (set #docenglish "English")
    (set #dochelp (cat
        "Select which documentation files you wish to install. Select your preferred language(s).\n"
        @askoptions-help
    ))
    (set #supporthelp (cat
    	"The Delay executable is needed by the ARexx scripts and SCDPLyrics. It should be installed somewhere in your default path.\n"
    	@copyfiles-help
    ))
    (set #askautolyrics "Do you want SCDPLyrics to be started whenever SCDPlayer is run?")
    (set #helpautolyrics "Select 'yes' if you want SCDPLyrics window to open automatically when you start SCDPlayer. Select 'no' otherwise.")

    (set #askres "Do you want Delay to be made resident?")
    (set #promptres "Adding a line to your User-Startup...")
    (set #helpres "This will add a line to your User-Startup for making Delay resident. This will take 2kB of memory at startup, but ARexx functions and SCDPLyrics won't access disk for waiting.")
    
    (set #docbits 2)
)
;DEUTSCH
(if (= @language "deutsch")
    (
        (set #catbits 1)
        (set #docbits 1)
    )
)
;NORSK
(if (= @language "norsk")
    (set #catbits 4)
)
;SVENSKA
(if (= @language "svenska")
    (set #catbits 8)
)
;FRANÇAIS
(if (= @language "français")
    (set #catbits 16)
)
;ESPAÑOL
(if (= @language "español")
    (
        (set #catbits 2)
    
        (set #making_drawer "Haciendo el cajón de SCDPlayer...")
        (set #copying_icons "Copiando iconos...")
        (set #copying_program "Copiando el ejecutable de SCDPlayer...")
    	(set #copying_lyrics "Copiando el módulo ARexx SCDPLyrics...")
	    (set #copying_support "Copiando el executable de soporte...")
        (set #making_arexx "Haciendo el cajón para los programas ARexx...")
        (set #copying_arexx "Copiando programas ARexx...")
        (set #copying_docs "Copiando documentación AmigaGuide®...")
        (set #making_images "Haciendo el cajón para las imágenes...")
        (set #making_disks "Haciendo el cajón 'Disks'...")
        (set #catalogs "Instalando los ficheros de traducción...")
        (set #enter_device "Teclee el nombre del controlador de dispositivo para su unidad CD-Rom (por ejemplo 'scsi.device').")
        (set #dev_help (cat
            "Teclee aquí el nombre del controlador de dispositivo de su unidad CD-Rom. Éste debería ser"
            " el mismo que haya en la línea 'DEVICE=' del mountlist de su CD-Rom.\nSi no está seguro,"
            " compruebe 'devs:dosdrivers/CD0' si está corriendo el Workbench 2.1 o superior, o"
            " 'devs:mountlist' en otro caso."
        ))
        (set #ask_dir "Elija en qué directorio se creará el cajón 'SCDPlayer'.")
        (set #dir_help (cat
            "Debe usted seleccionar ahora un directorio en qué instalar SCDPlayer."
            " Un nuevo cajón llamado 'SCDPlayer' será creado allí.\n"
            @askdir-help
        ))
        (set #enter_unit "Teclee el número de unidad del controlador de dispositivo para su unidad CD-Rom (por ejemplo 'scsi.device').")
        (set #unit_help (cat
            "Teclee aquí el número de unidad del controlador de dispositivo de su unidad CD-Rom. Éste debería ser"
            " el mismo que haya en la línea 'UNIT=' del mountlist de su CD-Rom.\nSi no está seguro,"
            " compruebe 'devs:dosdrivers/CD0' si está corriendo el Workbench 2.1 o superior, o"
            " 'devs:mountlist' en otro caso."
        ))
        (set #ok_vals "Los siguientes valores de su unidad de CD-Rom han sido obtenidos de una instalación previa:\n")
        (set #ok_vals2 "¿Son correctos?")
        (set #ask_choices "¿Qué elementos desea instalar?")
        (set #choice1 "SCDPlayer")
        (set #choice2 "Documentación de SCDPlayer")
        (set #choice3 "Ficheros de traducción de SCDPlayer")
        (set #choice4 "Programas ARexx de ejemplo")
        (set #choice5 "Ficheros fuente de SCDPlayer")
        (set #choice6 "Imágenes para los botones de SCDPlayer")
        (set #choice7 "Módulo ARexx SCDPLyrics")
	    (set #choice8 "Ejecutable de soporte 'Delay'")
        (set #parts_help (cat "Elija qué partes de SCDPlayer desea instalar." @askoptions-help))
        (set #msg_scdpdir "Se creará el cajón 'SCDPlayer'.")
        (set #msg_scdpprogram "Ahora se copiará el programa SCDPlayer.")
        (set #msg_scdpdocs "Procediendo a la copia de la documentación.")
        (set #diskdrwhelp "Si va usted a usar los ficheros ID en otro directorio, salte esta parte.")
        (set #copying_images "Copiando las imágenes de los botones.")
        (set #imagesnormal "Imágenes estándar de SCDPlayer")
        (set #images3d "Imágenes 3D")
        (set #selectimages "Elija qué tipo de imágenes para los botones desea instalar:")
        (set #imageshelp (cat
            "Las imágenes estándar son símbolos sólidos negros sobre el color de fondo por defecto,"
            "Las 3D tienen efecto de bajorrelieve, pero son algo menos legibles.\n"
            @askchoice-help
        ))
        (set #selecticons "Elija qué estilo de iconos instalar:")
        (set #newicons "Estilo NewIcons")
        (set #magicwb1 "Estilo MagicWB 1")
        (set #magicwb2 "Estilo MagicWB 2")
        (set #iconshelp (cat
            "Los estilos MagicWB 1 y 2 se diferencian en el icono del ejecutable de"
            " SCDPlayer. El de tipo 1 tiene un CD y una partitura musical, mientras el"
            " tipo 2 tiene un CD y el símbolo de MUI.\n"
            @askchoice-help
        ))
        (set #catselect "Elija qué ficheros de traducción instalar:")
        (set #catdeutsch "Deutsch")
        (set #catespañol "Español")
        (set #catnorsk "Norsk")
        (set #catsvenska "Svenska")
        (set #cathelp (cat
            "Elija qué ficheros de traducción instalar. SCDPlayer será traducido de forma automática"
            " a su idioma preferido si está seleccionado en sus Preferencias de Locale.\n"
            @askoptions-help
        ))
        (set #copying_sources "Copiando el código fuente de SCDPlayer...")
        
        (set #docselect "Seleccione qué documentos AmigaGuide® instalar:")
        (set #docdeutsch "Deutsch")
        (set #docenglish "English")
        (set #dochelp (cat
            "Seleccione qué ficheros de documentación desea instalar. Elija su(s) idioma(s) preferido(s).\n"
            @askoptions-help
        ))
	    (set #supporthelp (cat
	    	"El ejecutable Delay hace falta para los programas ARexx y SCDPLyrics. Debería instalarse en alguna parte de su ruta por defecto.\n"
	    	@copyfiles-help
	    ))
    	(set #askautolyrics "¿Quiere arrancar SCDPLyrics cada vez que se cargue SCDPlayer?")
	    (set #helpautolyrics "Seleccione 'sí' si desea que la ventana de SCDPLyrics se abra automáticamente al arrancar SCDPlayer. Seleccione 'no' en otro caso.")
    
	    (set #askres "¿Quiere que Delay sea hecho residente?")
	    (set #promptres "Añadiendo una línea a su User-Startup...")
    	(set #helpres "Esto añadirá una línea a su User-Startup para hacer Delay residente, lo que tomará 2kB de memoria al arrancar, pero las funciones ARexx functions y SCDPLyrics no accederán a disco para esperar.")

        (set #docbits 2)

    )
)

(welcome)

(if (<= @user-level 1)
    (
        (complete 0)
        (set #pre-default-dest (askdir (prompt #ask_dir) (default @default-dest) (help #dir_help)))
        (set @default-dest #pre-default-dest)

        (set #total_dir (tackon @default-dest "SCDPlayer"))
        
        (set #icon (tackon #total_dir "SCDP"))
        
        (set #dev '')
        (set #unit '')
        (set #def_dev "scsi.device")
        (set #def_unit "4")
        (set #flag 0)

        (if (exists (tackon #total_dir "SCDP.info"))
            (
                (iconinfo (dest #icon) (gettooltype "DEVICE" "#dev") (gettooltype "UNIT" "#unit"))
                (set #def_dev #dev)
                (set #def_unit #unit)
                (set #flag (not (askbool (prompt (cat #ok_vals "DEVICE=" #dev "\nUNIT=" #unit "\n" #ok_vals2)) (help "adiós") (default 1))))
            )
        )       
        
        (if (OR (= #dev '') (= #unit '') #flag)
            (
                (set #dev (askstring (prompt #enter_device) (help #dev_help) (default #def_dev)))
                (set #unit (cat (asknumber (prompt #enter_unit) (help #unit_help) (default (+ #def_unit)) (range 0 1023))))
            )
        )

        (makedir #total_dir (prompt #making_drawer))
        (if (not (exists (tackon @default-dest "SCDPlayer.info")))
            (
                (copyfiles (source "/SCDPlayer.info") (dest @default-dest) (prompt #copying_icons))
                (tooltype (dest (tackon @default-dest "SCDPlayer")) (noposition))
            )
        )
        
        (complete 10)
                
        (copyfiles (source "SCDP") (dest #total_dir) (infos) (prompt #copying_program))
        (tooltype (dest #icon) (settooltype "DEVICE" #dev) (settooltype "UNIT" #unit))
        (copyfiles (source "SCDPLyrics.rexx") (dest #toal_dir) (prompt #copying_lyrics))
        (copyfiles (source "c/Delay") (dest "C:") (prompt #copying_support))
        
        (complete 20)
        
        (copyfiles (source "SCDP_English.guide") (dest #total_dir) (infos) (prompt #copying_docs))
        (copyfiles (source "SCDP_Deutsch.guide") (dest #total_dir) (infos) (prompt #copying_docs))
        
        (complete 30)
        
        (makedir (tackon #total_dir "Disks") (prompt #making_disks))
        
        (complete 40)
        
        (makedir (tackon #total_dir "Images") (prompt #making_images))
        (if (not (exists (tackon #total_dir "Images.info")))
            (copyfiles (source "Images.info") (dest #total_dir) (prompt #copying_icons))
        )
        
        (set #images_dir (tackon #total_dir "Images"))
        
        (complete 50)
        
        (foreach "Images" "#?"
            (if (not (exists (tackon #images_dir @each-name)))
                (copyfiles (source (tackon "Images" @each-name)) (dest #images_dir))
            )
        )
        
        (complete 60)
        
        (set #arexx_dir (tackon #total_dir "Rexx"))
        (makedir #arexx_dir (prompt #making_arexx))
        (copyfiles (source "Rexx.info") (dest #total_dir) (prompt #copying_icons))
        
        (complete 70)
        
        (copyfiles (source "Rexx/") (pattern "#?.scdp") (dest #arexx_dir) (infos) (prompt #copying_arexx))

        (complete 80)

        (makedir (tackon #total_dir "Catalogs") (prompt #catalogs))
        (if (not (exists (tackon #total_dir "Catalogs.info")))
            (copyfiles (source "Catalogs.info") (dest #total_dir) (prompt #copying_icons))
        )
        
        (complete 90)
        
        (copyfiles (source "Catalogs") (dest (tackon #total_dir "Catalogs")) (all) (infos) (prompt #catalogs))
        
        (complete 100)
    )
)

(if (= @user-level 2)
    (
        (set #pre-default-dest (askdir (prompt #ask_dir) (default @default-dest) (help #dir_help)))
        (set @default-dest #pre-default-dest)

        (set #total_dir (tackon @default-dest "SCDPlayer"))
        (set #icon (tackon #total_dir "SCDP"))
        
        (set #parts (askoptions (choices #choice1 #choice2 #choice3 #choice4 #choice5 #choice6 #choice7 #choice8) (default 239) (prompt #ask_choices) (help #parts_help)))
        
        (if (BITAND #parts 32)
            (
                (set #imagetype (askchoice (choices #imagesnormal #images3d) (prompt #selectimages) (help #imageshelp)))
        
                (if (= #imagetype 0)
                    (set #imagessrc "Images")
                    (set #imagessrc "Alternative/Images")
                )
            )
        )
        
        (set #icontype (askchoice (choices #newicons #magicwb1 #magicwb2) (prompt #selecticons) (help #iconshelp)))

        (if (BITAND #parts 4)
            (
                (set #catbits (askoptions (choices #catdeutsch #catespañol #catnorsk #catsvenska #catfrançais) (default #catbits) (prompt #catselect) (help #cathelp)))
            )
        )

        (if (BITAND #parts 2)
            (
                (set #docbits (askoptions (choices #docdeutsch #docenglish) (default #docbits) (prompt #docselect) (help #dochelp)))
            )
        )
        
        (if (BITAND #parts 64)
        	(set #autolyrics (askbool (prompt #askautolyrics) (help #helpautolyrics) (default 0)))
        )

        (if (BITAND #parts 128)
        	(set #res (askbool (prompt #askres) (help #helpres) (default 1)))
        )

        (set #dev '')
        (set #unit '')
        (set #def_dev "scsi.device")
        (set #def_unit "4")
        (set #flag 0)

        (if (BITAND #parts 1)
            (
                (if (exists (tackon #total_dir "SCDP.info"))
                    (
                        (iconinfo (dest #icon) (gettooltype "DEVICE" "#dev") (gettooltype "UNIT" "#unit"))
                        (set #def_dev #dev)
                        (set #def_unit #unit)
                        (set #flag (not (askbool (prompt (cat #ok_vals "DEVICE=" #dev "\nUNIT=" #unit "\n" #ok_vals2)) (help "adiós") (default 1))))
                    )
                )       
            
                (if (OR (= #dev '') (= #unit '') #flag)
                    (
                        (set #dev (askstring (prompt #enter_device) (help #dev_help) (default #def_dev)))
                        (set #unit (cat (asknumber (prompt #enter_unit) (help #unit_help) (default (+ #def_unit)) (range 0 1023))))
                    )
                )
            )
        )
        
        (message #msg_scdpdir)
        
        (makedir #total_dir (prompt #making_drawer))
        (if (not (exists (tackon @default-dest "SCDPlayer.info")))
            (
                (copyfiles (newname "SCDPlayer.info") (source (select #icontype "/SCDPlayer.info" "alternative/mwb_icons/SCDPlayer_drawer.info" "alternative/mwb_icons/SCDPlayer_drawer.info")) (dest @default-dest) (prompt #copying_icons))
                (tooltype (dest (tackon @default-dest "SCDPlayer")) (noposition))
            )
        )
        
        (if (BITAND #parts 1)
            (       
                (message #msg_scdpprogram)
                (copyfiles (source "SCDP") (dest #total_dir) (infos) (prompt #copying_program))
                (if (> #icontype 0)
                    (copyfiles (dest #total_dir) (newname "SCDP.info") (source (select (- #icontype 1) "alternative/mwb_icons/SCDP.info" "alternative/mwb_icons/SCDPnew.info")) (prompt #copying_icons))
                )
                (tooltype (dest #icon) (settooltype "DEVICE" #dev) (settooltype "UNIT" #unit))
                
                (if (not (BITAND #parts 8))
                    (
                        (tooltype (dest #icon) (settooltype "SCRIPTONINSERT") (settooltype "SCRIPTONSTART") (settooltype "SCRIPTONINSERT") (settooltype "SCRIPTONQUIT") (settooltype "MENUSCRIPT") (settooltype "MENUSCRIPT") (settooltype "BUTTONSCRIPT") (settooltype "BUTTONSCRIPT"))
                    )
                )
                
                (makedir (tackon #total_dir "Disks") (prompt #making_disks) (confirm) (help #diskdrwhelp))
            )
        )

        (if (BITAND #parts 64)
            (       
                (message #copying_lyrics)
                (copyfiles (source "SCDPLyrics.rexx") (dest #total_dir) (prompt #copying_lyrics))
                
                (if (BITAND #parts 1)
                    (
                        (tooltype (dest #icon) (settooltype "SCRIPTONQUIT" "Rexx/QuitLyrics.scdp"))
                        (if #autolyrics
                        	(tooltype (dest #icon) (settooltype "SCRIPTONSTART" "Rexx/StartLyrics.scdp"))
                        )
                    )
                )
            )
        )

        (if (BITAND #parts 128)
            (       
                (message #copying_support)
                (copyfiles (source "c/Delay") (dest "C:") (prompt #copying_support) (confirm) (help #supporthelp))
                
                (if #res
                	(startup "SCDPlayer" (command "resident C:Delay pure") (prompt #promptres) (help #helpres))
                )
            )
        )

        (if (BITAND #parts 2)
            (
                (if (BITAND #docbits 2)
                    (
                        (message #msg_scdpdocs)
                        (copyfiles (source "SCDP_English.guide") (dest #total_dir) (infos) (prompt #copying_docs))
                        (if (> #icontype 0)
                            (copyfiles (dest #total_dir) (newname "SCDP_English.guide.info") (source "alternative/mwb_icons/SCDP_English.guide.info") (prompt #copying_icons))
                        )
                    )
                )
                (if (BITAND #docbits 1)
                    (
                        (message #msg_scdpdocs)
                        (copyfiles (source "SCDP_Deutsch.guide") (dest #total_dir) (infos) (prompt #copying_docs))
                        (if (> #icontype 0)
                            (copyfiles (dest #total_dir) (newname "SCDP_Deutsch.guide.info") (source "alternative/mwb_icons/SCDP_English.guide.info") (prompt #copying_icons))
                        )
                    )
                )
            )
        )
        
        (if (BITAND #parts 32)
            (
        
                (message #copying_images)
        
                (makedir (tackon #total_dir "Images") (prompt #making_images))
                (if (not (exists (tackon #total_dir "Images.info")))
                    (copyfiles (newname "Images.info") (source (select #icontype "Images.info" "alternative/mwb_icons/drawer.info" "alternative/mwb_icons/drawer.info")) (dest #total_dir) (prompt #copying_icons))
                )
        
                (set #images_dir (tackon #total_dir "Images"))
        
                (foreach #imagessrc "#?"
                    (if (not (exists (tackon #images_dir @each-name)))
                        (copyfiles (source (tackon #imagessrc @each-name)) (dest #images_dir))
                    )
                )
            )
        )
        
        (if (BITAND #parts 8)
            (
                (message #copying_arexx)
                (set #arexx_dir (tackon #total_dir "Rexx"))
                (makedir #arexx_dir (prompt #making_arexx))
                (copyfiles (newname "Rexx.info") (source (select #icontype "Rexx.info" "alternative/mwb_icons/drawer.info" "alternative/mwb_icons/drawer.info")) (dest #total_dir) (prompt #copying_icons))
                (copyfiles (source "Rexx/") (pattern "#?.scdp") (dest #arexx_dir) (infos) (prompt #copying_arexx))
                (if #icontype
                    (delete (tackon #arexx_dir "#?.info"))
                )
            )
        )
        (if (BITAND #parts 4)
            (
                (message #catalogs)
                (makedir (tackon #total_dir "Catalogs") (prompt #catalogs))
                (if (not (exists (tackon #total_dir "Catalogs.info")))
                    (copyfiles (newname "Catalogs.info") (source (select #icontype "Catalogs.info" "alternative/mwb_icons/drawer.info" "alternative/mwb_icons/drawer.info")) (dest #total_dir) (prompt #copying_icons))
                )
                (copyfiles (source "Catalogs") (dest (tackon #total_dir "Catalogs")) (all) (infos) (prompt #catalogs))
                (set #catdir (tackon #total_dir "Catalogs"))
                (if (BITAND 1 #catbits)
                    (
                        (if #icontype
                            (
                                (delete (tackon #catdir "deutsch.info"))
                                (delete (tackon #catdir "deutsch/scdp.catalog.info"))
                            )
                        )
                    )
                    (
                        (delete (tackon #catdir "deutsch.info"))
                        (delete (tackon #catdir "deutsch") (all))
                    )
                )
                (if (BITAND 2 #catbits)
                    (
                        (if #icontype
                            (
                                (delete (tackon #catdir "español.info"))
                                (delete (tackon #catdir "español/scdp.catalog.info"))
                            )
                        )
                    )
                    (
                        (delete (tackon #catdir "español.info"))
                        (delete (tackon #catdir "español") (all))
                    )
                )
                (if (BITAND 4 #catbits)
                    (
                        (if #icontype
                            (
                                (delete (tackon #catdir "norsk.info"))
                                (delete (tackon #catdir "norsk/scdp.catalog.info"))
                            )
                        )
                    )
                    (
                        (delete (tackon #catdir "norsk.info"))
                        (delete (tackon #catdir "norsk") (all))
                    )
                )
                (if (BITAND 8 #catbits)
                    (
                        (if #icontype
                            (
                                (delete (tackon #catdir "svenska.info"))
                                (delete (tackon #catdir "svenska/scdp.catalog.info"))
                            )
                        )
                    )
                    (
                        (delete (tackon #catdir "svenska.info"))
                        (delete (tackon #catdir "svenska") (all))
                    )
                )
                (if (BITAND 16 #catbits)
                    (
                        (if #icontype
                            (
                                (delete (tackon #catdir "français.info"))
                                (delete (tackon #catdir "français/scdp.catalog.info"))
                            )
                        )
                    )
                    (
                        (delete (tackon #catdir "français.info"))
                        (delete (tackon #catdir "français") (all))
                    )
                )
            )
        )
        
        (if (BITAND #parts 16)
            (
        
                (message #copying_sources)
        
                (makedir (tackon #total_dir "Sources") (prompt #copying_sources))
                (if (not (exists (tackon #total_dir "Sources.info")))
                    (copyfiles (newname "Sources.info") (source (select #icontype "Sources.info" "alternative/mwb_icons/drawer.info" "alternative/mwb_icons/drawer.info")) (dest #total_dir) (prompt #copying_icons))
                )
        
                (set #sources_dir (tackon #total_dir "Sources"))
        
                (copyfiles (dest #sources_dir) (source "Sources") (all))
                
                (if #icontype
                    (delete (tackon #sources_dir "#?.info"))
                )
            )
        )
        
    )
)