;$VER: PhotoCD_Manager Install 1.0 (1.3.96) 
;Copyright ©1996 Asimware Innovations Inc.

(complete 0)


(onerror 
	((makeassign "PCDMInst")
	(makeassign "PCDM_Dest")
))

(set @default-dest "SYS:PhotoCD_Manager")
(set #theirlevel @user-level )

(set #wbversion (getversion "libs:version.library"))
(set #wbversion (/ #wbversion 65536) )
(if (< #wbversion 37)
	(abort "\n\nAmigaDOS 2.0 or higher is required for PhotoCD Manager.  "
			 "An upgrade will be needed for your Amiga."
			 "\n\nYou are currently running version " #wbversion ".")
)




(if (exists "l:AsimCDFS")
	((set #version (getversion "l:AsimCDFS"))		
	(set #asimversion (/ #version 65536) )
	(set #asimrevision (- #version (* #asimversion 65536) ) )
	(if (and (= #asimversion 3) (< #asimrevision 4))
		((user 2)
		(message "\n\nYou have version AsimCDFS v" #asimversion "." #asimrevision " installed on your system.  "
				 "PhotoCD_Manager will function better with AsimCDFS v3.5, or higher.  Consult your AsimCDFS v3 manual for update details.\n\n"
				 "You can continue using AsimCDFS v" #asimversion "." #asimrevision ".  However, you will have to use the DiscChanger program to manually "
				 "select the ISO 9660 volume or use AsimCDFS_Prefs and turn off the \"Mount PhotoCD First?\" option."
		)
		)
	))
)



(askdisk
	(prompt "Please insert the disk labeled \"PhotoCD_Manager_CD\".")
	(help	"The PhotoCD Manager program and files will be copied "
			"from this disk into your system.")
	(dest  "PhotoCD_Manager_CD")
	(newname "PCDMInst")
)



(user 2)
(set #PCDMDir
	(askdir
		(prompt "Specify the directory in which the PhotoCD_Manager program will be placed:" )
		(help "PhotoCD_Manager will be placed in the directory specified.")
		(default @default-dest)
		(newpath)
	)
)
(user #theirlevel)


(if (not (exists #PCDMDir (noreq)))
	(makedir #PCDMDir
		(prompt "Creating the PhotoCD_Manager: directory...")
		(help "This will create the specified directory for the program.")
		(infos)
		)
)
(makeassign "PCDM_Dest" #PCDMDir)






(set #instPCDM
	(askbool
		(prompt "\n\nShould PhotoCD Manager be installed?")
		(help "\n\nThis will copy over the PhotoCD Manager program "
				"to the " #PCDMDir " directory\n\nIf you do not "
				"wish the PhotoCD Manager program to be transferred to your system, "
				"skip this step.\n" )
		(default 1)
	)
)

(if #instPCDM 
	((protect "PCDM_Dest:PhotoCD_Manager" "rwed" )
	(protect "PCDM_Dest:PhotoCD_Manager.info" "rwed" )
	(protect "PCDM_Dest:Data/Main_PAL.ham8.img" "rwed" )
	(protect "PCDM_Dest:Data/Main_NTSC.ham.img" "rwed" )
	(protect "PCDM_Dest:Data/Copyright.ham8.img" "rwed" )
	(protect "PCDM_Dest:Data/Copyright.ham.img" "rwed" )
	(protect "PCDM_Dest:Data/Main_NTSC.ham8.img" "rwed" )
	(protect "PCDM_Dest:Data/Main_PAL.ham.img" "rwed" )



;***************************************************
; determine if HAM or HAM-8 version is needed
(if (run "PCDMInst:c/is_AGA")
	(set #PCDMVer "PCDMInst:PhotoCD_Manager_HAM8")
	(set #PCDMVer "PCDMInst:PhotoCD_Manager_HAM")
)



;***************************************************
; copy over main program 
	(copyfiles
		(prompt "\n\nCopying the PhotoCD_Manager program to the "
				  #PCDMDir " directory.\n" )
		(source #PCDMVer)
		(dest "PCDM_Dest:")
		(newname "PhotoCD_Manager")
		(infos)
		(help "\n\nThis will copy over the PhotoCD_Manager program"
				"to your"  #PCDMDir " directory.\n" )
		(confirm)
	)

	(tooltype
		(prompt "\n\Setting PhotoCD_Manager icon.\n" )
		(dest "PCDM_Dest:PhotoCD_Manager")
		(noposition)
		(help "\n\nThis will reset the PhotoCD_Manager icon.\n")
		(confirm)
	)



;***************************************************
; copy over data files
	(set #temp "PCDM_Dest:Data")
	(if (not (exists #temp (noreq)))
		(makedir #temp
			(prompt "Creating the PhotoCD_Manager:Data directory...")
			(help "This will create a sub-directory into which support files will be placed.")
			(infos)
			)
	)

	(copyfiles
		(prompt "\n\nCopying Data support files to the "
				  #temp " directory.\n" )
		(source "PCDMInst:Data")
		(dest #temp)
		(all)
		(help "\n\nThis will copy over support files into the "
				#temp " directory.\n" )
		(confirm)
	)



;***************************************************
; make shows directory
	(set #temp "PCDM_Dest:Shows")
	(if (not (exists #temp (noreq)))
		(makedir #temp
			(prompt "Creating the PhotoCD_Manager:Shows directory...")
			(help "This will create a sub-directory into which slide shows will be saved.")
			(infos)
			)
	)


;***************************************************
; make buffer directory
	(set #temp "PCDM_Dest:Buffer")
	(if (not (exists #temp (noreq)))
		(makedir #temp
			(prompt "Creating the PhotoCD_Manager:Buffer directory...")
			(help "This will create a sub-directory into which overview pictures will be buffered.")
			(infos)
			)
	)

))

(protect "S:User-Startup" "rwed" )
(protect "S:Startup-Sequence" "rwed" )

(startup "PhotoCD_Manager"
	(command (cat "assign PhotoCD_Manager: \"" #PCDMDir "\"\n"))
	(command (cat "assign PhotoCD_Manager_Shows: PhotoCD_Manager:Shows\n"))
	(command (cat "assign PhotoCD_Manager_Buffer: PhotoCD_Manager:Buffer\n"))
	(prompt "Inserting assignment commands into the startup-sequence")
	(help "Assignment commands are being inserted into your "
			"\"S:Startup-Sequence\" or \"S:User-Startup\" file to "
			"allow PhotoCD_Manager to find the needed files." )
)

(makeassign "PhotoCD_Manager" #PCDMDir)
(makeassign "PhotoCD_Manager_Shows" "PhotoCD_Manager:Shows")
(makeassign "PhotoCD_Manager_Buffer" "PhotoCD_Manager:Buffer")

(makeassign "PCDMInst")
(makeassign "PCDM_Dest")