;Install script for Adagis v3.2
;Š 1996 Stv
;
;Install the main program
;
(set directory
	(askdir
		(prompt "A on vols instal.lar Adagis ?\n(no es crearā cap directori)")
		(help @askdir-help)
		(default "Sys:WBStartUp")
	)
)
(set @default-dest directory)
(copyfiles
	(prompt "Copiant Adagis:")
	(help @copyfiles-help)
	(dest directory)
	(source "/bin/Adagis")
)
;
;Select the Icon
;
(set icon
	(askchoice
		(help @askchoice-help)
		(prompt "Quina icona vols instal.lar per Adagis ?")
		(choices "NewIcon" "MagicWB 1" "MagicWB 2" "Iconographics")
		(default 0)
	)
)
(select icon
	(set icon "/icons/newicon.info")
	(set icon "/icons/magicwb1.info")
	(set icon "/icons/magicwb2.info")
	(set icon "/icons/Iconographics.info")
)
(copyfiles
	(prompt "Instalant l'icona d'Adagis")
	(help @copyfiles-help)
	(dest directory)
	(source icon)
	(newname "Adagis.info")
)
(set fulliconfile (tackon directory "Adagis"))
;
;Install Adagis.data
;
(set quinfitxer
	(askchoice
		(help @askchoice-help)
		(prompt "Quin Adagis.data vols instal.lar ?\n\nQUALSEVOL ADAGIS.DARA ANTERIOR SERÁ ESBORRAT\n")
		(choices "Anglés" "Catalā" "Espaņol" "Cap")
		(default 1)
	)
)
(set datadir
	(askdir
		(prompt "On vols instal.lar l'Adagis.data ?\n(No es crearā cap directori)")
		(help @askdir-help)
		(default "s:")
	)
)
(if (<> 3 quinfitxer)			; Delete file if required
	(delete "s:adagis.data"
		(help @delete-help)
		(prompt "Esborrant l'Adagis.data")
	)
)
(select quinfitxer
	(set datafile "/s/adagis.data.eng")
	(set datafile "/s/adagis.data.cat")
	(set datafile "/s/adagis.data.esp")
)
(copyfiles
	(prompt "Copiant l'Adagis.data")
	(help @copyfiles-help)
	(dest datadir)
	(source datafile)
	(newname "adagis.data")
)
(set fulldatafile (tackon datadir "adagis.data"))
(tooltype
	(prompt "Modificant el tooltype ADAGISFILE")
	(settooltype "ADAGISFILE" fulldatafile)
	(dest fulliconfile)
)
;
;Install locale files
;
(set locales
	(askoptions
		(prompt "Quins catālegs vols instal.lar ?")
		(help @askoptions-help)
		(choices "Espaņol" "Catalā")
		(default %10)
	)
)
(if (in locales 0)
	(copyfiles
		(source "/locale/catalogs/espaņol/adagis.catalog")
		(dest "locale:catalogs/espaņol/")
		(prompt "Copiant el catāleg espaņol")
		(help @copyfiles-help)
	)
)
(if (in locales 1)
	(copyfiles
		(source "/locale/catalogs/catalā/adagis.catalog")
		(dest "locale:catalogs/catalā/")
		(prompt "Copiant el catāleg catalā")
		(help @copyfiles-help)
	)
)