; $VER: Alfabet Smierci AGA HD Install-Script V1.0 (09.03.96) by Kostek
; based upon Roland's Installer for Mortal Kombat II

(set GameDir "Alfabet")
(set TotalDisks 4)
(set CurrentDisk 0)
(set Percent 22)
(set DiskPercent (/ (- 100 Percent) TotalDisks))

;try to figure out a place where the user usually installs his games
(if (exists "Games:" (noreq) )
    (set @default-dest "Games:")
    (if (exists "SYS:Games" (noreq) )
        (set @default-dest "SYS:Games")
        (if (exists "Work:Games" (noreq) )
            (set @default-dest "Work:Games")
            (set @default-dest "SYS:")
        )
    )
)

;ask the user to select a directory to install the game into
(set default-dest
     (tackon (askdir (prompt "Where would you like " @app-name " installed?\n"
                             "A drawer called " GameDir " will be created.")
                     (help @askdir-help)
                     (default @default-dest)
                     (newpath)
             )
     GameDir
     )
)
(set @default-dest default-dest)
(complete 5)

;create the selected directory
(makedir @default-dest
         (infos)
)
(complete 10)
;copy all extra files to this directory
(copyfiles (source "Alfabet")
           (dest @default-dest)
)

(complete Percent)

;copy all the disks to the data directory
(until (= CurrentDisk TotalDisks)
       (set CurrentDisk (+ CurrentDisk 1))
       (message "\n\n\n\n\n\nPlease insert " @app-name " Disk "
                CurrentDisk " into DF0:"
       )
       (working "Converting disk " CurrentDisk
                "\nCall one of our boards:\n"
                "     One Eight Seven - +31-534337569\n"
                "                       +31-534339671\n"
                "Electronic Confusion - +45-316095-50\n"
                "      Digital Extasy - +1-2013454315\n"
                "          CheckPoint - +47-51593123\n" 
                "          Riot House - +31-541355073\n"
                "             Nemezis - +48-321038256\n"
                "          Phoenix II - +46-880-0747\n" 
                "            Homeless - +49-PRIIIVATE\n"
                "                       +49-PRIIIVATE\n"
                "             Pitstop - +47-333-87955\n"
                "                       +47-333-84269\n"
       )
       (run (cat "Read" CurrentDisk " " @default-dest))
       (set Percent (+ Percent DiskPercent))
       (complete Percent)
)
(complete 100)