;***********************************************
; Script to install MultiTerm
; $VER: Install-MT 510.25 (25.10.95)
;
; © 1995-1996 TKR GmbH & Co. KG
;***********************************************

;=============================================================================
; German strings
(set default_lang 2)

(set @abort-button "Abbruch")
(set #msg-oldoperatingsystem
	(cat	"Die Version des Betriebsystems Ihres Rechners ist zu alt. "
		"MultiTerm benötigt mindestens eine Version 2.04 des Betriebsystems. "
		"Bitte wenden Sie sich zwecks einer Aufrüstung des Betriebssystems "
		"an Ihren örtlichen Amiga-Fachhändler."
	)
)
(set #ask-target-prompt
	(cat	"Auf welches Laufwerk oder in welches Verzeichnis soll "
		"MultiTerm installiert werden (\"Hilfe...\" beachten!) ?"
	)
)
(set #ask-target-help
	(cat	"Das Verzeichnis \"MultiTerm\" wird auf dem gewünschten "
		"Laufwerk oder in dem gewünschten Verzeichnis automatisch "
		"eingerichtet."
	)
)
(set #already-exists-prompt
	(cat	"Das Verzeichnis \"MultiTerm\" existiert bereits! "
		"Soll die Installation trotzdem durchgeführt werden?"
		"\n\n"
		"Dieses ist nur sinnvoll bei einer Reinstallation des KIT-Dekoders!"
		"\n\n"
		"Bitte beachten Sie unbedingt den Hilfetext hierzu "
		"(Schalter \"Hilfe...\")"
	)
)
(set #already-exists-help
	(cat	"JA - Ein bereits eingerichtetes MultiTerm "
		"wird überschrieben. Es wird dabei davon ausgegangen, daß es "
		"sich hierbei um eine bereits installierte KIT-Version des "
		"MultiTerm handelt. Im Falle einer älteren Version kann eine "
		"Lauffähigkeit nicht garantiert werden und eine Nutzung unterliegt "
		"ganz Ihrem Risiko."
		"\n\n"
		"NEIN - Die Installation wird nicht durchgeführt. Vermutlich ist "
		"dort eine ältere Version (1.x - 3.x) vorhanden. Benennen Sie "
		"einfach das Verzeichnis um, bevor Sie die Installation noch "
		"einmal beginnen."
	)
)
(set #choices-yes
	(cat	"JA"
	)
)
(set #choices-no
	(cat	"NEIN"
	)
)
(set #ask-name-prompt
	(cat	"\n\nBitte geben Sie jetzt Ihren Vor- und Nachnamen ein. Dieser "
		"erscheint später in Ihrem MultiTerm-Programm. Firmen geben hier "
		"bitte den Namen des Mitarbeiters bzw. der Mitarbeiterin ein, der "
		"bzw. die dieses MultiTerm-Exemplar benutzt."
	)
)
(set #ask-company-prompt
	(cat	"\n\nBitte geben Sie jetzt den Namen Ihrer Firma ein. Die "
		"Eingabe ist freigestellt. Das Feld kann auch leer bleiben."
	)
)
(set #ask-sernumber-prompt
	(cat	"\n\nBitte geben Sie jetzt die 12-stellige Seriennummer Ihres "
		"MultiTerm-Exemplares ein. Sie finden sie auf der ersten "
		"Programmdiskette."
	)
)
(set #installinfo-name
	(cat	"MT_4.0_Disk_1:Tools/MT-Install.info"
	)
)
(set #askstring-errormsg
	(cat	"Eingabe fehlerhaft. Bitte starten Sie die Installation erneut."
	)
)
(set #install-errormsg
	(cat	"Allgemeiner Installationfehler. Versuchen Sie die Installation "
		"bitte noch einmal. Tritt dieser Fehler erneut auf, wenden Sie "
		"sich bitte an den Support und nennen die folgende Fehlernummer: "
	)
)
(set #ask-disk2-prompt
	(cat	"Bitte legen Sie Diskette 1 des Programmpaketes in "
		"ein Laufwerk."
	)
)
(set #ask-disk2.1-prompt
	(cat	"Bitte legen Sie Diskette 2 des Programmpaketes in "
		"ein Laufwerk."
	)
)
(set #ask-disk2.2-prompt
	(cat	"Bitte legen Sie Diskette 3 des Programmpaketes in "
		"ein Laufwerk."
	)
)
(set #ask-disk2-help
	(cat	"Die Programme des MultiTerm werden auf Ihr System kopiert."
	)
)
(set #ask-libstarget-prompt
	(cat	"In welches Verzeichnis sollen die MultiTerm-Bibliotheken kopiert "
		"werden (\"Hilfe...\" beachten!) ?"
	)
)
(set #ask-libstarget-help
	(cat	"Das Verzeichnis \"Libs:\" ist das für diesen Zweck auf dem Amiga "
		"standardmäßig vorgesehene. Sie sollten diesen Eintrag nur ändern, "
		"wenn Sie ein anderes Verzeichnis für diesen Zweck eingerichtet und "
		"dem System auch für diesen Zweck bekannt gemacht haben."
	)
)
(set #ask-options-prompt
	(cat	"Bitte wählen Sie die zu kopierenden Dateien:"
	)
)
(set #ask-options-help
	(cat	"Hiermit können Sie auch eine teilweise Installation durchführen. "
		"Für eine normale Installation wählen Sie bitte alle Punkte an."
	)
)
(set #ask-options-program
	(cat	"Programm"
	)
)
(set #ask-options-libraries
	(cat	"Bibliotheken"
	)
)
(set #msg-installing
	(cat	"\n\nInstalliere MultiTerm\n\nnach\n\n"
	)
)
(set #insert-assign-prompt
	(cat	"Einfügen eines ASSIGN in Ihre \"S:user-startup\".\n"
		"Dieser ist nach dem nächsten Start des Rechners aktiv."
	)
)
(set #insert-assign-help
	(cat	"Dieser ASSIGN ist für den Betrieb von MultiTerm notwendig. "
		"Sie können diesen Abschnitt aber auch überspringen (Skip "
		"This Part) und den ASSIGN später per Hand durchführen."
	)
)
(set #msg-finished
	(cat	"Der Installationsvorgang ist nun beendet. Nehmen Sie bitte "
		"jetzt die MultiTerm-Disketten aus dem Laufwerk."
		"\n\n"
	)
)
(set #readmanual-prompt
	(cat	"Ein Nachtrag mit etwaigen Änderungen des Programmpaketes "
		"nach Drucklegung der Handbuchergänzung wurde auf "
		"Ihrem System unter dem Namen \"Lies_mich_!!\" installiert. "
		"Möchten Sie die Änderungen gleich lesen?!"
	)
)
(set #msg-nohelpavailable
	(cat	"\n\nKeine Hilfe verfügbar."
	)
)
(set #ask-update-prompt
	(cat	"Ist diese Version ein Update zu einer MultiTerm-Version "
		"1.x, 2.x oder 3.x ?"
		"\n\n"
		"Möchten Sie die alten Einstellungen übernehmen?"
		"\n\n"
		"Wenn Sie beide Fragen mit JA beantworten können, dann "
		"drücken Sie den Schalter \"JA\", sonst \"NEIN\"."
	)
)
(set #ask-updatesource-prompt
	(cat	"Bitte wählen Sie das Parameter-Verzeichnis Ihres MultiTerm 3.x aus."
	)
)
;=============================================================================

	; set up a error cleanup routine
(onerror
	(makeassign "MultiTerm_Disk" (safe))
)

(complete 0)

	; Prüfung auf ein Betriebsystem von mindestens OS2.04 (37.xxx).
(
(set vernum (getversion))
(set ver (/ vernum 65536))
(set rev (- vernum (* ver 65536)))
(set osversion ver)
(if (< osversion 37)
	(
	(abort #msg-oldoperatingsystem)
	)
)
)

(set n (askstring (prompt #ask-name-prompt) (help #msg-nohelpavailable)))
(if (= n "") (abort #askstring-errormsg))
(if (< (strlen n) 6) (abort #askstring-errormsg))
(if (= (substr n 0 6) "      ") (abort #askstring-errormsg))
(set f (askstring (prompt #ask-company-prompt) (help #msg-nohelpavailable)))
(set s (askstring (prompt #ask-sernumber-prompt) (help #msg-nohelpavailable)))
(if (= s "") (abort #askstring-errormsg))
(if (< (strlen s) 12) (abort #askstring-errormsg))
(if (= (substr s 0 6) "      ") (abort #askstring-errormsg))
(if (> (run (cat #installinfo-name " c " s)) 0) (abort #askstring-errormsg))

	; just in case the installation was restarted
(makeassign "MultiTerm_Disk" (safe))	; start fresh

	; see if this is really an update
	; if update, be sure they want program in same place
	; if not an update, get a location for program
(set mterm_destdir
		(askdir
			(prompt #ask-target-prompt)
			(help	#ask-target-help)
			(default @default-dest)
			(disk)
		)
)
(set mterm_dest
	(tackon mterm_destdir "MultiTerm")
)

	; now lock on to volume 'mterm'
(set reinstall 0)
(if (exists mterm_dest)
		; Es gibt dort bereits ein MultiTerm-Verzeichnis.
	(
	(set reinstall
		(askbool
			(prompt #already-exists-prompt)
			(help	#already-exists-help)
			(choices #choices-yes #choices-no)
		)
	)
	(if (not reinstall)
		(exit)
	)
	)
)

(askdisk
	(prompt	#ask-disk2-prompt)
	(help	#ask-disk2-help)
	(dest  "MT_4.0_Disk_1")
	(newname "MultiTerm_Disk")
)

	; make MFax drawer & icon if not there
(if (not reinstall)
	(
	(makedir mterm_dest (infos))
		; MultiTerm-Fenster-Piktogramm kopieren wegen der Fenstergröße.
	(run (cat "Copy CLONE QUIET MultiTerm_Disk:Installation/MultiTerm.info TO \"" mterm_destdir "\""))
	)
)

	; at this point we have a valid destination, so we tell installer where
	; the application will end up so the exit page will be correct -- also,
	; the installation log file (if any) will be copied to the destination
(set @default-dest mterm_dest)

(set whichfiles 
	(askoptions
		(prompt #ask-options-prompt)
		(help	#ask-options-help)
		(choices #ask-options-program
			 #ask-options-libraries
		)
	)
)


	; Programm
(if	(in whichfiles 0)
	(
		(working #msg-installing mterm_dest)
		(textfile
			(dest "RAM:Install-HD")
			(append "CD \"" mterm_dest "\"\n")
			(append "MultiTerm_Disk:Tools/LHArc -m x MultiTerm_Disk:MT.LZH\n")
		)
		(execute "RAM:Install-HD")
		(delete "RAM:Install-HD" (safe))
		(if (not @pretend) (makeassign "MultiTerm" mterm_dest))
		(set res (run (cat #installinfo-name " s " s " \"" n "\" \"" f "\"")))
		(if (> res 0) (abort (cat #install-errormsg res)))
	)
)

(complete 95)

	; Bibliotheken
(if	(in whichfiles 1)
	(
			; Abfrage des Verzeichnisses für die Bibliotheken.
		(set libs_dest
			(askdir
				(prompt #ask-libstarget-prompt)
				(help	#ask-libstarget-help)
				(default "Libs:")
				(disk)
			)
		)
		(copylib
			(source "MultiTerm_Disk:Libs/tkrtools.library")
			(dest libs_dest)
		)
	)
)

	; Lies_mich_!!-Text mit dem entsprechenden Standardprogramm versehen.
(if (>= osversion 39)
	(
		; Ab OS3.0 ist MultiView dabei. Dies ersetzt das
		; Programm More. Sollte also auch als Standard-
		; programm genommen werden.
	(tooltype
		(dest (tackon mterm_dest "Lies_mich_!!.info"))
		(setdefaulttool "SYS:Utilities/MultiView")
	)
	)
)

(tooltype
	(dest mterm_dest)
	(noposition)
)


(complete 98)

	; modify S:User-Startup
(startup "MultiTerm"
	(prompt #insert-assign-prompt)
	(command
		"ASSIGN MultiTerm: \"" mterm_dest "\"\n"
	)
	(help #insert-assign-help)
)

	; reinitialize assigns
(if (not @pretend)
	(makeassign "MultiTerm" mterm_dest)
)

	; Alte Einstellunge übernehmen?
(set isupdate
	(askbool
		(prompt #ask-update-prompt)
		(help #msg-nohelpavailable)
		(choices #choices-yes #choices-no)
	)
)
(if (> isupdate 0)
	(
		(set mterm_updateparams
			(askdir
				(prompt #ask-updatesource-prompt)
				(help	#ask-updatesource-help)
				(default @default-dest)
				(disk)
			)
		)
		(if (not (= mterm_updateparams ""))
			(
			(copyfiles
				(source mterm_updateparams)
				(dest (tackon mterm_dest "Parameter"))
				(pattern "MULTI-Default.#?BTX")
			)
			(delete (tackon mterm_dest "Btx.INF"))
			)
		)
	)
)

(complete 100)

	; cleanup
(makeassign "MultiTerm_Disk" (safe))

(message #msg-finished)

	; Zum Schluß hat der Anwender gleich Gelegenheit, das Ergänzungshandbuch
	; zu lesen. Aber nur, wenn er es auch installiert hat.
(set readmanual
	(askbool
		(prompt #readmanual-prompt)
		(help #msg-nohelpavailable)
		(choices #choices-yes #choices-no)
	)
)
(if (> readmanual 0)
	(
	(set editor "SYS:Utilities/More")
		; Prüfung auf ein Betriebsystem von mindestens OS3.0 (39.xxx).
	(if (>= osversion 39)
			; Ab OS3.0 ist MultiView dabei. Dies ersetzt das
			; Programm More. Sollte also auch als Anzeige-
			; programm genommen werden.
		(set editor "SYS:Utilities/MultiView")
	)
	(textfile
		(dest "RAM:TMP")
		(append (cat "Run >NIL: " editor " MultiTerm:Lies_mich_!!\n"))
	)
	(execute "RAM:TMP")
	(run "Delete QUIET RAM:TMP")
	)
)



	; this is not strictly necessary, but doesn't hurt -- there is always
	; a default (exit) at the end of any script
(exit (quiet))