;$VER Install-LZXGui.script V1.0 (5.8.1995)
;copyright © 1995 Olaf Gramkow (tHE aLIEN/pHANTASM)
;All rights reserved

(set progname "LZXGui")
(set version "V1.0")

(complete 0)

; --- English (default) strings ---

(set #introduction
	(cat
		"\n"
		("%s - Gui for LZX\n" progname)
		"\n"
		("%s ©1995 tHE aLIEN/pHANTASM\n" progname)
		"\n"
		("%s is Shareware. If you use it\n" progname)
		"you have to register yourself!\n"
		"Please have a look in the help-file.\n"
		"Thank you.\n"
	)
)

(set #badkick "\n Sorry, this package requires OS V2.0 or better.\n")

(set #LZXGuiInstallieren
	(cat
		("Where should I install %s %s?\n" progname version)
		"An own directory will not be created."
	)
)

(set #LZXGuiInstallierenHelp
	(cat
		("Here you can choose where I should install %s %s?\n" progname version)
		"An own directory will not be created."
	)
)

(set #HotHelpInstall
	(cat
		"Where should I install the HotHelp-Files?\n"
		"An own directory will be created."
	)
)

(set #HotHelpInstallHelp
	(cat
		"Here you can choose where I should install the HotHelp-Files.\n"
		"An own directory will be created.\n\n"
	)
)

(set #Speech "Which speech should I install?")

(set #SpeechEnglish "English")

(set #SpeechGerman "German")

(set #SpeechHelp "Here you can select, which speech should be installed.\n\n")

(set #CopyTEXToolsLibrary "Copy TEXTools.library to libs:")

(set #CopyTEXToolsLibraryHelp
	(cat
		"Here you can choose, if the TEXTools.library should be installed. "
		"The TEXTools.library will be copied to libs:.\n"
	)
)

(set #CopyTEXStandardLibrary "Copy TEXStandard.library to libs:")

(set #CopyTEXStandardLibraryHelp
	(cat
		"Here you can choose, if the TEXStandard.library should be installed. "
		"The TEXStandard.library will be copied to libs:.\n"
	)
)

(set #CopyHotHelpLibrary "Copy HotHelp.library to libs:")

(set #CopyHotHelpLibraryHelp
	(cat
		"Here you can choose, if the HotHelp.library should be installed. "
		"The HotHelp.library will be copied to libs:.\n"
	)
)

(set #StartupText "\n\nThe following assign will be created:\n\n")

; --- German strings ---

(if (= @language "deutsch")
	(
		(set #introduction
			(cat
				"\n"
				("%s - Gui für LZX\n" progname)
				"\n"
				("%s ©1995 tHE aLIEN/pHANTASM\n" progname)
				"\n"
				("%s ist Shareware. Wenn Sie es\n" progname)
				"benutzen, müssen Sie sich registrieren\n"
				"lassen! Bitte schauen Sie in die.\n"
				"Anleitung. Vielen Dank.\n"
			)
		)

		(set #badkick "\n Tut mir leid, dieses Paket benötigt mind. OS V2.0.\n")

		(set #LZXGuiInstallieren
			(cat
				("Wo soll %s %s installiert werden?\n" progname version)
				"Es wird keine eigene Schublade erstellt."
			)
		)

		(set #LZXGuiInstallierenHelp
			(cat
				("Hier können Sie wählen wo %s %s installiert werden soll.\n" progname version)
				"Es wird keine eigene Schublade erstellt.\n\n"
			)
		)

		(set #HotHelpInstall
			(cat
				"Wo sollen die HotHelp-Dateien installiert werden?\n"
				"Es wird eine eigene Schublade angelegt."
			)
		)

		(set #HotHelpInstallHelp
			(cat
				"Hier können Sie wählen, wo die HotHelp-Dateien installiert werden sollen.\n"
				"Es wird eine eigene Schublade angelegt.\n\n"
			)
		)

		(set #Speech "Welche Sprache soll installiert werden?")

		(set #SpeechEnglish "Englisch")

		(set #SpeechGerman "Deutsch")

		(set #SpeechHelp "Hier können Sie wählen, welche Sprache installiert werden soll.\n\n")

		(set #CopyTEXToolsLibrary "Kopiere die TEXTools.library nach libs:")

		(set #CopyTEXToolsLibraryHelp
			(cat
				"Hier können Sie wählen, ob die TEXTools.library installiert werden soll. "
				"Die TEXTools.library wird nach libs: kopiert.\n"
			)
		)

		(set #CopyTEXStandardLibrary "Kopiere die TEXStandard.library nach libs:")

		(set #CopyTEXStandardLibraryHelp
			(cat
				"Hier können Sie wählen, ob die TEXStandard.library installiert werden soll. "
				"Die TEXStandard.library wird nach libs: kopiert.\n"
			)
		)

		(set #CopyHotHelpLibrary "Kopiere die HotHelp.library nach libs:")

		(set #CopyHotHelpLibraryHelp
			(cat
				"Hier können Sie wählen, ob die HotHelp.library installiert werden soll. "
				"Die HotHelp.library wird nach libs: kopiert.\n"
			)
		)

		(set #StartupText "\n\nDas folgende Assign wird angelegt:\n\n")
	)
)

; are we running under OS2.0+ ROM?

(if (< (/ (getversion) 65536) 36)
	(
		(message #badkick)
		(exit
			(quiet)
		)
	)
)

(complete 0)

(message #introduction)

(welcome)

(set @default-dest "")

; set default language selection (catalogs) to 'none'

(set catalogs 0)

(if (not (exists "c:LZX" (noreq)))
	(copyfiles
		(source "lzx")
		(dest "c:")
	)
)

(complete 10)

(set lzxguidest
	(askdir
		(prompt	#LZXGuiInstallieren)
		(help
			#LZXGuiInstallierenHelp
			@askdir-help
		)
		(default "sys:")
	)
)

(copyfiles
	(source "Main")
	(dest lzxguidest)
	(all)
)

(complete 20)

(if (not (exists "HotHelp:" (noreq)))
	(
		(set hothelpdest
			(tackon
				(askdir
					(prompt #HotHelpInstall)
					(help
						#HotHelpInstallHelp
						@askdir-help
					)
					(default "sys:")
				)
				"HotHelp"
			)
		)

		(makedir hothelpdest)

		(complete 25)

		(copyfiles
			(source "HotHelp")
			(dest hothelpdest)
			(all)
		)
	)
)

(complete 40)

(copyfiles
	(source "s")
	(dest "s:")
	(all)
)

(complete 45)

;which speech?
(set speech
	(askchoice
		(prompt #Speech)
		(choices
			;bit position 0
			#SpeechEnglish
			;bit position 1
			#SpeechGerman
		)
		(help
			#SpeechHelp
			@askoptions-help
		)
		(default 0)
	)
)

(if (= speech 0) ;bit position 0
	(
		(copyfiles
			(source "Reader/English")
			(dest lzxguidest)
			(all)
		)

		(if (exists "HotHelp:Projekte" (noreq))
			(copyfiles
				(source "Help/LZXGui/English")
				(dest "HotHelp:Projekte")
				(all)
			)
			(
				(set hothelpprojekte
					(tackon
						("%s" hothelpdest)
						"Projekte"
					)
				)

				(copyfiles
					(source "Help/LZXGui/English")
					(dest hothelpprojekte)
					(all)
				)
			)
		)
	)
)

(if (= speech 1) ;bit position 1
	(
		(copyfiles
			(source "Reader/Deutsch")
			(dest lzxguidest)
			(all)
		)

		(if (exists "HotHelp:Projekte" (noreq))
			(copyfiles
				(source "Help/LZXGui/Deutsch")
				(dest "HotHelp:Projekte")
				(all)
			)
			(copyfiles
				(source "Help/LZXGui/Deutsch")
				(dest
					("%s/Projekte" hothelpdest)
				)
				(all)
			)
		)
	)
)

(complete 60)

(if (> (/ (getversion) 65536) 37)
	(
		(if (exists "Locale:Catalogs" (noreq))
			(
				(copyfiles
					(source "HotHelpCatalog")
					(dest "Locale:Catalogs")
					(all)
				)

				(complete 65)

				(copyfiles
					(source "Catalogs")
					(dest "Locale:Catalogs")
					(all)
				)
			)
		)
	)
)

(complete 70)

(copylib
	(prompt #CopyTEXToolsLibrary)
	(help
		#CopyTEXToolsLibraryHelp
		@copylib-help
	)
	(source "libs/TEXTools.library")
	(dest "libs:")
	(confirm)
)

(complete 80)

(copylib
	(prompt #CopyTEXStandardLibrary)
	(help
		#CopyTEXStandardLibraryHelp
		@copylib-help
	)
	(source "libs/TEXStandard.library")
	(dest "libs:")
	(confirm)
)

(complete 90)

(copylib
	(prompt #CopyHotHelpLibrary)
	(help
		#CopyHotHelpLibraryHelp
		@copylib-help
	)
	(source "libs/HotHelp.library")
	(dest "libs:")
	(confirm)
)

(complete 98)

; Assigns

(if (not (exists "HotHelp:" (noreq)))
	(
		(set assignhothelp
			("assign HotHelp: %s" hothelpdest)
		)

		(makeassign "HotHelp:" hothelpdest)

		(startup
			progname
			(prompt
				#StartupText
				("%s\n" assignhothelp)
			)
			(help @startup-help)
			(command
				("%s:\n" assignhothelp)
			)
		)
	)
)

(complete 100)