; Dit is het installatie script voor Off-Line Amiga.
; Prints out debugging info if run from CLI

(set destdir
	(askdir
		(prompt "In welke lade moet " @app-name " geļnstalleerd worden? "
                "Installatie vindt plaats in een lade genaamd OLA2.")
		(help "In de geselecteerde lade zal een lade OLA2 aangemaakt worden. "
	  		  "Installatie 'over' een oudere installatie dan versie 2.0 is "
			  "NIET mogelijk. Installatie over een  bestaande versie 2.0 wel.\n\n"
		 	  "Wanneer in de betreffende lade ook een lade OLA aangetroffen "
			  "wordt, zullen de keyfile en eventuele scherminstellingen "
			  "overgenomen worden.\n"
			@askdir-help
		)
		(default "SYS:")
	)
)

; Controleren of ik in een directory sta waar OLA in staat.
(if (NOT (exists (tackon destdir "Off-Line")))
(
	(set destdir (tackon destdir "OLA2"))
	(makedir destdir (infos))
)
)
(set @default-dest destdir)

; Controleren of ik een key-file te copieren heb.
(if (AND (exists "OLA2/OLA.key") (NOT (exists (tackon destdir "OLA.key"))))
	(copyfiles
		(prompt "Kopiėren van de key-file naar " destdir)
		(help @copyfiles-help)
		(source "OLA2/OLA.key")
		(dest destdir)
	)
)

;Controleren of ik een nieuwere versie heb of alleen de key-file
;hoefde te kopieren. Getversion werkte niet, dus gebruik ik getsize.
(if (exists (tackon destdir "Off-line"))
	(if (= (getsize "OLA2/Off-line") (getsize (tackon destdir "Off-line")))
		(exit "Deze versie van OLA was al geļnstalleerd. Alleen een mogelijke "
		"keyfile is toegevoegd wanneer je een geregistreerd gebruiker bent." )
	)
)

(copyfiles
	(prompt "Kopiėren van de programma's naar " destdir)
	(help @copyfiles-help)
	(source "OLA2")
	(dest destdir)
	(choices "AVE" "AVE.guide" "Off-Line" "Off-Line.guide" "DATA"
			 "AVE.Screens" "AVE.Phone" "AVE.Prefs")
)

; Iconen alleen copieren als ze er nog niet zijn. Hierdoor worden
; Eventuele positie-bepalingen niet teniet gedaan.
(if (NOT (exists (tackon destdir "Off-Line.info")))
	(copyfiles
		(prompt "Kopiėren van icoon bestanden naar " destdir)
		(help @copyfiles-help)
		(source "OLA2")
		(dest destdir)
		(pattern "#?.info")
	)
)

(copylib
	(prompt "Kopiėren van de EAGUI.ligrary")
	(help "Off-line gebruikt sinds versie 1.1 de EAGUI.library voor het opbouwen "
		"van het grafishe gebruikersinterface. Zonder deze kleine library (15K) "
		"kan Off-line niet werken. De EAGUI.library is (c) door Marcel Offermans "
		"en Frank Groen.\n\n" @copylib-help)
	(source "OLA2/Libs/EAGUI.library")
	(dest "LIBS:")
	(confirm)
)


; Viditelfont copieren
(set destfont "FONTS:")
(if (= @user-level 2)
	(set destfont
		(askdir
			(prompt "In welke lade moet het Viditel lettertype geļnstalleerd worden?")
			(help "Het Amiga Viditel Emulatie (AVE) programma heeft voor de weergave "
				"van de Viditel schermen een speciaal Viditel lettertype nodig. "
				"Normaalgesproken zal dit in de systeem FONTS: lade geplaatst worden. "
				"Je kunt hier eventueel een andere lade aangeven. Het programma AVE zal "
				"voor het lettertype eerst in de lade " destdir " zoeken, "
				"om het mogelijk te maken meerdere Viditel lettertypes "
				"voor verschillende programma's te gebruiken.\n\n"
				@askdir-help
			)
			(default destfont)
		)
	)
)

(copyfiles
	(prompt "Kopiėren van het Viditel lettertype naar " destfont)
	(help @copyfiles-help)
	(source "OLA2/Fonts")
	(dest destfont)
	(all)
)


; Eventueel oude key-file copieren
(if (exists (cat destdir "//OLA/OLA.key"))
	(copyfiles
		(prompt "Kopiėren van de key-file naar " destdir)
		(help @copyfiles-help)
		(source (cat destdir "//OLA/OLA.key"))
		(dest destdir)
	)
)

; Eventueel oude screen-settings copieren
(if (exists (cat destdir "//OLA/DATA/OLA050"))
	(copyfiles
		(prompt "Kopiėren van de scherm instellingen naar ")
		(help @copyfiles-help)
		(source (cat destdir "//OLA/DATA/OLA050"))
		(dest (cat destdir "/DATA"))
	)
)