;
; MagicClock-Installer deutsch
;
	(complete 0)
	(welcome)

;output strings --------------------------------------------------------

	(set WrongKick "\nDu mußt mindestens\nKickStart 2.04\nhaben, wenn du MagicClock benutzen willst.")
	(set WrongCPU  "\nDu mußt mindestens eine\n68020 CPU\nhaben, wenn du MagicClock benutzen willst.")

;-----------------------------------------------------------------------
	(set currentver (/ (getversion "libs:iff.library") 65536))
	(set currentrev (BITAND (getversion "libs:iff.library") 65535))
	(set myver      (/ (getversion "libs/iff.library") 65536))
	(set myrev      (BITAND (getversion "libs/iff.library") 65535))
;-----------------------------------------------------------------------
	(if (< (/ (getversion) 65536) 37)
	  (abort WrongKick)
	)

	(set version (database "cpu"))
	(if (> "68020" version)
		(abort WrongCPU)
	)

(complete 10)

	(message
	"\n\n\n"
	"Willcommen\n"
	"zum\n"
	"MagicClock V1.1\n"
	"Installations Skript"
	)

	(set maindir
		(askdir (prompt "Wähle ein Verzeichnis aus in das MagicClock\ninstalliert werden soll\n"
			 "(ein Verzeichnis 'MagicClock' wird angelegt)")
			(help @askdir-help)
			(default "sys:")
		)
	)
(copyfiles (source "extraicon/MagicClock.info")(dest maindir)(files))
(if (OR (patmatch "#?:" maindir)
        (patmatch "#?/" maindir)
    )
    (makedir(set maindir (cat maindir "MagicClock"))(infos))
    (makedir(set maindir (cat maindir "/MagicClock"))(infos))
)

	(complete 20)

	(set destdir
		(askdir (prompt "Wähle ein Verzeichnis in welches das Hauptprogramm\n'MagicClock' installiert werden soll."
			 "\nz.B. WBStartup / C ...")
			(help @askdir-help)
			(default maindir)
		)
	)

(complete 30)

	(copyfiles 
		(prompt "\nKopiere MagicClock zu "destdir" ...\n")
		(source "MagicClock")
		(dest destdir)
		(files)
	)

(complete 40)

	(if(askbool
		(prompt "\n Möchtest Du ein Icon für MagicClock in\n"destdir" installieren ?")
		(help @askbool_help)
		(default 1)) 
		(copyfiles 
			(prompt "\nKopiere MagicClock-Icon...\n")
			(source "MagicClock.info")
			(dest maindir)
			(files)
			(infos)
		)
	)

(complete 50)

	(if(askbool
		(prompt "\n Möchtest Du den Polygon Editor installieren ?")
		(help @askbool_help)
		(default 1)) 
		((set destdirmc
			(askdir (prompt "Wähle ein Verzeichnis in welches der\n Polygon Editor 'MC-Edit' installiert werden soll.")
				(help @askdir-help)
				(default maindir)
			)
		)
		(copyfiles 
			(prompt "\nKopiere MC-Edit...\n")
			(source "MC-Edit")
			(dest destdirmc)
			(files)
			(infos)
		))
	)

(complete 60)

	(if(askbool
		(prompt "\nWillst Du die\n\niff.library Version "myver"."myrev"\n\nin dein LIBS: Verzeichnis installieren ?\n\n"
			"Die aktuelle Version ist "currentver"."currentrev"\n\n")
		(help "Installiert die mitgelieferte Version der iff.library in dein Libs: Verzeichnis, "
		      "wenn du willst.")
		(default 1)) 
		(copyfiles 
			(prompt "\nKopiere die iff.library...\n")
			(source "libs/iff.library")
			(dest   "Libs:")
			(files)
		)
	)

(complete 70)

	(if(askbool
		(prompt "\n  Möchtest Du Dokumentationen zum Programm installieren ?\n")
		(help "")
		(default 1))
		((set doc(askoptions 
		 	(prompt "Wähle die Dokumentation(en) aus, die Du installieren möchtest.")
		 	(help "")
		 	(choices 
;		"Deutsches  Textfile"
						"Deutsches  Guidefile"
;						"Englisches Textfile"
						"Englisches Guidefile"
						"Deutsches  MC-Edit Textfile"
						"Englisches MC-Edit Textfile")))
			(set docdir
				(askdir (prompt "Wähle ein Verzeichnis in welches Du die\nDokumentation(en) installieren möchtest."
				 "\n(ein neues Verzeichnis wird nicht angelegt)")
				(help @askdir-help)
				(default maindir)
				)
			)
			(set n 0)
			(while
				(set docfile
					(select n 
									"docs/MagicClock_deu.guide"
									"docs/MagicClock_eng.guide"
									"docs/MC-Edit.dok"
									"docs/MC-Edit.doc"
									""
					)
				)
				(if (in doc n)
					((if (= n 0)
						(copyfiles
							(source "docs/Registrierungsformular")
							(dest docdir)
							(files)
							(infos))
					)
					(if (= n 1)
						(copyfiles
							(source "docs/Registration_form")
							(dest docdir)
							(files)
							(infos))
					)
					(copyfiles
						(source docfile)
						(dest docdir)
						(files)
						(infos)))
				)
				(set n (+ n 1))
			)
		)
	)

(complete 90)

	(if(askbool
		(prompt "\nMöchtest Du die mitgelieferten Beispiel-Zeiger installieren ?")
		(help @askbool_help)
		(default 1))
		(
			(set dirdir
				(askdir (prompt "Wähle ein Verzeichnis in welches Du die Zeiger\ninstallieren willst.\nEin Verzeichnis 'Hands' wird angelegt.")
				(help @askdir-help)
				(default maindir)
				)
			)
			(if	(OR	(patmatch "#?:" dirdir)
							(patmatch "#?/" dirdir)
					)
				(makedir(set dirdir (cat dirdir "Hands")))
				(makedir(set dirdir (cat dirdir "/Hands")))
			)
			(copyfiles
				(source "hands")
				(dest dirdir)
				(all))
		)
	)


(set @default-dest maindir)
(complete 100)
(exit "Viel Spaß mit MagicClock.\n\nMagicClock ist Shareware!\nLies das Guidefile für weitere Informationen.")