; $VER: FinalWriter-030_Install 1.8 (14.6.95)

(set version "3.0")

(onerror (exit (quiet)))

(message
	"\n\nFinalWriter " version "-030 International"
	"\nCopyright 1995 Martin Berndt"
	"\n\n\nThis Patch is SHAREWARE !"
	"\n\nPlease read the \"ReadMe.txt\" file."
)

(set @default-dest
	(askdir
		(prompt "Where is your FinalWriter Drawer?")
		(help @askfile-help)
		(default "SYS:FinalWriter")
		(newpath)
	)
)

(set language
	(askchoice
		(prompt "Select Language")
		(help @askchoice-help)
		(choices "US1  23-Nov-94 (American English)"
			 "US2  14-Dec-94 (American English)"
			 "US3   3-Jan-95 (American English)"
			 "US4  13-Mar-95 (American English)"
			 "GB1  23-Nov-94 (British English)"
			 "GB2  14-Dec-94 (British English)"
			 "GB3   3-Jan-95 (British English)"
			 "GER1  7-Dec-94 (German)"
			 "GER2 14-Dec-94 (German)"
			 "GER3  3-Jan-95 (German)"
			 "GER4 13-Mar-95 (German)")
	)
)

(set backup
	(askoptions
		(prompt "Options")
		(help @askoptions-help)
		(choices "Create Backup Files")
	)
)

(set n 0)
(set percent 0)

(while (set name (select n "FinalWriter" "swpost.library" "swshell.library"
			   "cachemap.library" "qfont.library" "")) (
	(set n (+ n 1))
	(complete percent)
	(if (= n 1)
		(set file name)
		(set file (cat "FWLibs/" name))
	)
	(set newfile (tackon @default-dest file))
	(set oldfile (cat newfile ".bak"))
	(if (= (exists newfile) 0)
		(abort name " not found!")
	)
	(rename newfile oldfile)
	(if (< n 4) (
		(if (= n 1)
			(set name (cat name (select language "US1" "US2" "US3" "US4" "GB1" "GB2" "GB3" "GER1" "GER2" "GER3" "GER4")))
		)
		(working "\n\n" newfile)
		(if (<> (run (cat "spatch \"-o" newfile "\" -p" name ".pch \"" oldfile "\"")) 0) (
			(rename oldfile newfile)
			(abort "Wrong Version!")
		))
		(set percent (+ percent 30))
	) (
		(copyfiles
			(prompt "Copying " name)
			(help @copyfiles-help)
			(source name)
			(dest (tackon @default-dest "FWLibs"))
			(optional "force" "askuser")
		)
		(set percent (+ percent 5))
	))
	(if (= backup 0) (delete oldfile))
))