; $VER: Install 2.1 (07.02.95)
; Script to install Release 2.1 DosWedge
(complete 0)

(set @default-dest "SYS:WBStartup")
(set @startupdir "SYS:Startup")

(set target @default-dest)

;********************************************************************

(set #Yes-text
(cat "Yes"
))

(set #No-text
(cat "No"
))


(set #Overwrite
(cat "Replace"
))

(set #Abort
(cat "Abort"
))

;********************************************************************

(set #warn-kickstart-text
(cat	"\nBAD VERSION OF KICKSTART\n\n"
	"DosWedge requires KickStart 2.0 (V37) or higher. It will not work on earlier versions.\n"
	"You currently are running KickStart V%ld.\n\n"
	"Continue with installation?"
))

;********************************************************************

(set #docs-install-text
(cat "Installing documentation"
))

(set #docs-query-text
(cat "\nWould you like to install documentation for DosWedge?"
))

(set #docs-help-text
(cat ""
))

(set #docs-query-dir-text
(cat "Where to install documentation?"
))

(set #docs-query-dir-help
(cat @askdir-help
))

;********************************************************************

(set #StartupMagaer-query
(cat "\nStartupManager Installation?\n\n"
     "I have found StartupManager in your SYS:WBStartup drawer."
     " You have a drawer named SYS:Startup which is where StartupManager"
     " runs programs from when you boot. Would you like DosWedge installed"
     " here?"
))

;********************************************************************
(set #path-text
(cat "Select directory to install DosWedge into"
))

(set #path-help
(cat @askdir-help
))

;********************************************************************

(set #Overwrite-text
(cat "\nThere is a version of DosWedge installed already. "
     "Would you like to replace it with this version?"
))

(set #Overwrite-abort-text
(cat "Installation has been aborted, old version remains untouched."
))

;********************************************************************

(set #MatrixLib-text
(cat "\nInstalling matrix.library\n\nCopyright ©1992-95 David Swasbrook"
))

(set #MatrixLib-help
(cat "This will copy matrix.library into your LIBS: directory.\nCopyright ©1992-95 David Swasbrook\n\n"
     @copylib-help
))


;********************************************************************


;********************************************************************
;**** END OF TEXT
;********************************************************************


;********************************
;**** CHECK THE KICKSTART VERSION
;****
(set ver (/ (getversion) 65536) )
(if (< ver 37) (
	(set warning (#warn-kickstart-text ver) ) (message warning)
))

(complete 10)

(set setaskdir 1)

(if (exists "SYS:WBStartup/StartupManager")
(
	(if (exists @startupdir)
	(
		(set target @startupdir)
		(if(askbool (prompt #StartupMagaer-query) (help #Overwrite-text) (choices #Yes-text #No-text)  )
		(
			(set setaskdir 0)
		))
	))
	
))

(if setaskdir
(set target
(askdir (prompt #path-text) (help #path-help) (default target)
))
)


(if (exists (tackon target "DosWedge"))
(
	(if(askbool (prompt #Overwrite-text) (help #Overwrite-text) (choices #Overwrite #Abort)  )
	(
		(copyfiles (source "DosWedge") (dest target) )
	)
	(
		(abort #Overwrite-abort-text )
	))
)
(
	(copyfiles (source "DosWedge") (dest target) (infos) )
	(complete 60)
	(tooltype	(dest (tackon target "DosWedge"))
		(settooltype "DONOTWAIT" )
		(noposition)
	)
))

(complete 60)

(copylib (prompt #MatrixLib-text) (help #MatrixLib-help) (source "matrix.library") (dest "LIBS:") (confirm) )

(complete 80) (working #docs-install-text)

(if(= (askbool (prompt #docs-query-text) (help #docs-query-help)) 1)
	(
		(set docs-target (askdir (prompt #docs-query-dir-text) (help #docs-query-dir-help) (default "SYS:")))
		(copyfiles (source "DosWedge.guide") (dest docs-target ) (infos) )
	)
)

(set @default-dest target)
(complete 100)