.KEY Sys3.1_Partition,Ask/S,NoReq/S
.BRA {
.KET }

;$VER: Fix_WB3.1 38.1 (20.8.94)
;© 1994 by Klaus Weber. Freely redistributable.

set result "-cancelled-"

if "{Sys3.1_Partition}" EQ ""
   if $language EQ "deutsch"
      set result `RequestFile DRAWER="SYS:" TITLE="Bitte wählen Sie Ihre 3.1 Systempartition oder -schublade:" DRAWERSONLY NOICONS`
   else
      set result `RequestFile DRAWER="SYS:" TITLE="Please select your 3.1 System Partition or Drawer:" DRAWERSONLY NOICONS`
   endif
else
   if {Ask} EQ "Ask"
      if $language EQ "deutsch"
         set result `RequestFile DRAWER="{Sys3.1_Partition}" TITLE="Bitte wählen Sie Ihre 3.1 Systempartition oder -schublade:" DRAWERSONLY NOICONS`
      else
         set result `RequestFile DRAWER="{Sys3.1_Partition}" TITLE="Please select your 3.1 System Partition or Drawer:" DRAWERSONLY NOICONS`
      endif
   else
      set result "{Sys3.1_Partition}"
   endif
endif

if $result EQ "-cancelled-"
   if $language EQ "deutsch"
      echo "Benutzerabbruch"
      quit 5
   else
      echo "User break"
      quit 5
   endif
endif

set validdest TRUE

if NOT exists $result
   set validdest FALSE
endif

set System System
set Rexxc Rexxc
set Utilities Utilities
set C C

if NOT exists $result$System
   set validdest FALSE
endif

if NOT exists $result$Rexxc
   set validdest FALSE
endif

if NOT exists $result$Utilities
   set validdest FALSE
endif

if NOT exists $result$C
   set validdest FALSE
endif

if NOT $validdest EQ "TRUE"
   if $language EQ "deutsch"
      echo "'$result' ist kein gültiges System-Verzeichnis. Operation abgebrochen"
      quit 6
   else
      echo "'$result' is not a valid system directory. Operation cancelled"
      quit 6
   endif
endif

unset validdest

if NOT {NoReq} EQ "NoReq"
   if $language EQ "deutsch"
      set confirm `RequestChoice "Sicherheitsabfrage" "PURE-Bits auf '$result' setzen?" "Weiter|Abbruch"`
   else
      set confirm `RequestChoice "Please confirm" "Set PURE-Bits on '$result'?" "Continue|Abort"`
   endif
   if $confirm EQ 0
      if $language EQ "deutsch"
         echo "Benutzerabbruch"
         quit 5
      else
         echo "User break"
         quit 5
      endif
   endif
   unset confirm
endif

echo ""

if $language EQ "deutsch"
   echo Setze PURE-Bits auf '$result' "*N" 
else
   echo Setting PURE-Bits on '$result' "*N" 
endif

failat 50

; Generated from <16840@cbmger.de.so.commodore.com> by Dr. Peter Kittel

echo " " NOLINE
echo $result$System/CLI ... NOLINE
protect $result$System/CLI p add

echo OK "*N" $result$System/DiskCopy ... NOLINE
protect $result$System/DiskCopy p add

echo OK "*N" $result$System/FixFonts ... NOLINE
protect $result$System/FixFonts p add

echo OK "*N" $result$System/Format ... NOLINE
protect $result$System/Format p add

echo OK "*N" $result$Rexxc/HI ... NOLINE
protect $result$Rexxc/HI p add

echo OK "*N" $result$Rexxc/RX ... NOLINE
protect $result$Rexxc/RX p add

echo OK "*N" $result$Rexxc/RXC ... NOLINE
protect $result$Rexxc/RXC p add

echo OK "*N" $result$Rexxc/RXLIB ... NOLINE
protect $result$Rexxc/RXLIB p add

echo OK "*N" $result$Rexxc/RXSET ... NOLINE
protect $result$Rexxc/RXSET p add

echo OK "*N" $result$Rexxc/TCC ... NOLINE
protect $result$Rexxc/TCC p add

echo OK "*N" $result$Rexxc/TCO ... NOLINE
protect $result$Rexxc/TCO p add

echo OK "*N" $result$Rexxc/TE ... NOLINE
protect $result$Rexxc/TE p add

echo OK "*N" $result$Rexxc/TS ... NOLINE
protect $result$Rexxc/TS p add

echo OK "*N" $result$Rexxc/WaitForPort ... NOLINE
protect $result$Rexxc/WaitForPort p add

echo OK "*N" $result$Utilities/More ... NOLINE
protect $result$Utilities/More p add

echo OK "*N" $result$Utilities/MultiView ... NOLINE
protect $result$Utilities/MultiView p add

echo OK "*N" $result$C/AddBuffers ... NOLINE
protect $result$C/AddBuffers p add

echo OK "*N" $result$C/AddDataTypes ... NOLINE
protect $result$C/AddDataTypes p add

echo OK "*N" $result$C/Assign ... NOLINE
protect $result$C/Assign p add

echo OK "*N" $result$C/Avail ... NOLINE
protect $result$C/Avail p add

echo OK "*N" $result$C/Break ... NOLINE
protect $result$C/Break p add

echo OK "*N" $result$C/ChangeTaskPri ... NOLINE
protect $result$C/ChangeTaskPri p add

echo OK "*N" $result$C/ConClip ... NOLINE
protect $result$C/ConClip p add

echo OK "*N" $result$C/Copy ... NOLINE
protect $result$C/Copy p add

echo OK "*N" $result$C/CPU ... NOLINE
protect $result$C/CPU p add

echo OK "*N" $result$C/Date ... NOLINE
protect $result$C/Date p add

echo OK "*N" $result$C/Delete ... NOLINE
protect $result$C/Delete p add

echo OK "*N" $result$C/Dir ... NOLINE
protect $result$C/Dir p add

echo OK "*N" $result$C/DiskChange ... NOLINE
protect $result$C/DiskChange p add

echo OK "*N" $result$C/Ed ... NOLINE
protect $result$C/Ed p add

echo OK "*N" $result$C/Edit ... NOLINE
protect $result$C/Edit p add

echo OK "*N" $result$C/Eval ... NOLINE
protect $result$C/Eval p add

echo OK "*N" $result$C/Execute ... NOLINE
protect $result$C/Execute p add

echo OK "*N" $result$C/Filenote ... NOLINE
protect $result$C/Filenote p add

echo OK "*N" $result$C/IconX ... NOLINE
protect $result$C/IconX p add

echo OK "*N" $result$C/Info ... NOLINE
protect $result$C/Info p add

echo OK "*N" $result$C/Install ... NOLINE
protect $result$C/Install p add

echo OK "*N" $result$C/Join ... NOLINE
protect $result$C/Join p add

echo OK "*N" $result$C/List ... NOLINE
protect $result$C/List p add

echo OK "*N" $result$C/Lock ... NOLINE
protect $result$C/Lock p add

echo OK "*N" $result$C/MagTape ... NOLINE
protect $result$C/MagTape p add

echo OK "*N" $result$C/MakeDir ... NOLINE
protect $result$C/MakeDir p add

echo OK "*N" $result$C/MakeLink ... NOLINE
protect $result$C/MakeLink p add

echo OK "*N" $result$C/Mount ... NOLINE
protect $result$C/Mount p add

echo OK "*N" $result$C/Protect ... NOLINE
protect $result$C/Protect p add

echo OK "*N" $result$C/Relabel ... NOLINE
protect $result$C/Relabel p add

echo OK "*N" $result$C/RemRAD ... NOLINE
protect $result$C/RemRAD p add

echo OK "*N" $result$C/Rename ... NOLINE
protect $result$C/Rename p add

echo OK "*N" $result$C/RequestChoice ... NOLINE
protect $result$C/RequestChoice p add

echo OK "*N" $result$C/RequestFile ... NOLINE
protect $result$C/RequestFile p add

echo OK "*N" $result$C/Search ... NOLINE
protect $result$C/Search p add

echo OK "*N" $result$C/SetClock ... NOLINE
protect $result$C/SetClock p add

echo OK "*N" $result$C/SetDate ... NOLINE
protect $result$C/SetDate p add

echo OK "*N" $result$C/SetFont ... NOLINE
protect $result$C/SetFont p add

echo OK "*N" $result$C/SetKeyboard ... NOLINE
protect $result$C/SetKeyboard p add

echo OK "*N" $result$C/Sort ... NOLINE
protect $result$C/Sort p add

echo OK "*N" $result$C/Status ... NOLINE
protect $result$C/Status p add

echo OK "*N" $result$C/Type ... NOLINE
protect $result$C/Type p add

echo OK "*N" $result$C/Version ... NOLINE
protect $result$C/Version p add

echo OK "*N" $result$C/Wait ... NOLINE
protect $result$C/Wait p add

echo OK "*N" $result$C/Which ... NOLINE
protect $result$C/Which p add

echo "OK"

unset System
unset Rexxc
unset Utilities
unset C

unset result

if $language EQ "deutsch"
   echo "fertig*N"
else
   echo "done*N"
endif