; $VER: Install-PAR 1.1 © Digital Processing Systems (27-Jan-94)
; Script to install Personal Animation Recorder Software
;******************************************************************************

; set source to the same as the installer script
(set sourcedir (pathonly @icon))

(set makedir-help
 (cat	"You will need to select a directory to put PAR.  "
	"A drawer will be created if you select a directory that does not exist."
 )
)

;**************************** request a target path ***************************

(set target
 (askdir
	(prompt "Please select a directory where the software for PAR will go.")
	(help  makedir-help)
	(default (tackon @default-dest "PAR"))
 )
)

(set @default-dest target)

;****** Copy the PAR software, PARTest, README, etc. **********
(copyfiles
	(prompt "Copying PAR directory.")
	(help @copyfiles-help)
	(source (tackon sourcedir "PAR"))
	(dest target)
	(pattern "#?")
	(files)
	(infos)
)

;****** Make the importers directory, and copy importers ******

; Copy all of the importers (radio buttons for experts)
(copyfiles
	(prompt "Copying Importers.")
	(help @copyfiles-help)
	(source (tackon sourcedir "PAR/Importers"))
	(dest (tackon target "Importers"))
	(pattern "#?")
	(files)
	(confirm)
)


; Copy all of the Exporters (radio buttons for experts)
(copyfiles
	(prompt "Copying Exporters.")
	(help @copyfiles-help)
	(source (tackon sourcedir "PAR/Exporters"))
	(dest (tackon target "Exporters"))
	(pattern "#?")
	(files)
	(confirm)
)


;********************* Copy PAR.Hex & PAR_PAL.Hex to S: ***********************
(copyfiles
	(prompt "Copying PAR.Hex to S:")
	(source (tackon sourcedir "S"))
	(pattern "#?.Hex")
	(dest "S:")
)


;******************* Copy any ARexx files *********************
(if (> (exists "Rexx:" (noreq)) 1)
 (copyfiles
	(prompt "Copying ARexx files.")
	(help "These files will allow you to do special things.")
	(source (tackon sourcedir "Rexx"))
	(dest "Rexx:")
	(confirm)
	(pattern "#?")
	(infos)
	(files)
 )
 
)