include	"SNES.i"

	incdir	"!includes:OS3.0"
	include	"dos/dos.i"
	include	"dos/dosextens.i"

	incdir	"!includes:"
	include	"LVO/exec_lib.i"
	include	"LVO/dos_lib.i"
	include	"LVO/intuition_lib.i"

	section	code,code

	* prevent execution

	move.l	#-1,d0
	rts

ROM_GetHeader
* * * * * * * * * * * * * * * * * * * * * * * * *
* Reads the ROM-header from a SNES-ROM.		*
*						*
* IN:	a0 - ptr to filename.			*
*	a1 - ptr to ROMHeader data.		*
*						*
* Check RMH_HeaderValid before you access!!!	*
*						*
* * * * * * * * * * * * * * * * * * * * * * * * *

	movem.l	d0-a6,-(sp)

	move.l	a0,a4
	move.l	a1,a5

	clr.l	RMH_HeaderValid(a5)

	move.l	_DosBase,a6
	move.l	#DOS_FIB,d1
	moveq.l	#0,d2
	jsr	_LVOAllocDosObject(a6)		;allocate FIB
	move.l	d0,.FileInfoBlock
	beq	.Fail

	move.l	_DosBase,a6
	move.l	a4,d1
	move.l	#SHARED_LOCK,d2
	jsr	_LVOLock(a6)			;lock file
	move.l	d0,.FileLock
	beq	.Fail

	move.l	_DosBase,a6
	move.l	.FileLock,d1
	move.l	.FileInfoBlock,d2
	jsr	_LVOExamine(a6)			;examine file
	tst.l	d0
	beq	.Fail

	move.l	.FileInfoBlock,a0
	tst.l	fib_DirEntryType(a0)		;Is this a directory?
	bpl	.Fail

	move.l	fib_Size(a0),d0
	and.l	#8191,d0
	move.l	d0,FileHeaderSize

	move.l	fib_Size(a0),d0
	sub.l	FileHeaderSize,d0
	move.l	d0,prg_ROMSize

	move.l	_DosBase,a6
	move.l	.FileLock,d1
	jsr	_LVOUnLock(a6)

	move.l	#0,.FileLock

	move.l	_DosBase,a6
	move.l	a4,d1
	move.l	#MODE_OLDFILE,d2
	jsr	_LVOOpen(a6)
	move.l	d0,.FileHandle
	beq	.Fail

	move.l	_DosBase,a6
	move.l	.FileHandle,d1
	move.l	#$7FC0,d2
	add.l	FileHeaderSize,d2
	move.l	#OFFSET_BEGINNING,d3
	jsr	_LVOSeek(a6)

	move.l	_DosBase,a6
	move.l	.FileHandle,d1
	move.l	#.FileROMPlaceLow,d2
	add.l	#4,d2
	move.l	#RMH_SIZEOF-8,d3
	jsr	_LVORead(a6)

	move.l	_DosBase,a6
	move.l	.FileHandle,d1
	move.l	#$7FFA,d2
	add.l	FileHeaderSize,d2
	move.l	#OFFSET_BEGINNING,d3
	jsr	_LVOSeek(a6)

	move.l	_DosBase,a6
	move.l	.FileHandle,d1
	move.l	#.FileROMPlaceLow,d2
	add.l	#RMH_VBL_Vector,d2
	move.l	#4,d3
	jsr	_LVORead(a6)

	move.l	_DosBase,a6
	move.l	.FileHandle,d1
	move.l	#$FFC0,d2
	add.l	FileHeaderSize,d2
	move.l	#OFFSET_BEGINNING,d3
	jsr	_LVOSeek(a6)

	move.l	_DosBase,a6
	move.l	.FileHandle,d1
	move.l	#.FileROMPlaceHigh,d2
	add.l	#4,d2
	move.l	#RMH_SIZEOF-8,d3
	jsr	_LVORead(a6)

	move.l	_DosBase,a6
	move.l	.FileHandle,d1
	move.l	#$FFFA,d2
	add.l	FileHeaderSize,d2
	move.l	#OFFSET_BEGINNING,d3
	jsr	_LVOSeek(a6)

	move.l	_DosBase,a6
	move.l	.FileHandle,d1
	move.l	#.FileROMPlaceHigh,d2
	add.l	#RMH_VBL_Vector,d2
	move.l	#4,d3
	jsr	_LVORead(a6)


	lea.l	.FileROMPlaceLow,a0
	lea.l	.FileROMPlaceHigh,a1

	clr.l	d0
	move.w	RMH_Checksum(a0),d0
	add.w	RMH_ChecksumComplement(a0),d0

	clr.l	d1
	move.w	RMH_Checksum(a1),d1
	add.w	RMH_ChecksumComplement(a1),d1

	move.b	#0,d4

	lea.l	prg_ConfigBuffer,a3

	tst.l	CFG_ROMForce(a3)
	bne	.ForceMode

	cmp.l	#65535,d0
	bne	.CheckHiROM

	cmp.l	#65535,d1
	beq	.CheckHiROM

	move.l	#.FileROMPlaceLow,.FileROMHeaderValid

	move.b	#00,d4

	bra	.ROMMakeupSet

.CheckHiROM

	cmp.l	#65535,d0
	beq	.Fail

	cmp.l	#65535,d1
	bne	.Fail

	move.l	#.FileROMPlaceHigh,.FileROMHeaderValid

	move.b	#10,d4

	bra	.ROMMakeupSet

.ForceMode

	cmp.l	#1,CFG_ROMForce(a3)
	bne	.CheckHiForce

	move.l	#.FileROMPlaceLow,.FileROMHeaderValid

	move.b	#00,d4

	bra	.ROMMakeupSet

.CheckHiForce

	cmp.l	#2,CFG_ROMForce(a3)
	bne	.Fail

	move.l	#.FileROMPlaceHigh,.FileROMHeaderValid

	move.b	#10,d4

.ROMMakeupSet

	* copy structures

	move.l	_SysBase,a6
	move.l	.FileROMHeaderValid,a0
	move.l	a5,a1
	move.l	#RMH_SIZEOF,d0
	jsr	_LVOCopyMem(a6)

	move.b	d4,RMH_RomMakeup(a5)

	* search for end of name (trunc spaces)

	lea.l	RMH_ROMTitle+21(a5),a0

	move.l	#21,d1

.FindEnd
	subq.l	#1,d1
	move.b	-(a0),d0
	cmp.b	#32,d0
	beq	.FindEnd

	tst.l	d1
	ble	.NoEnd

	move.b	#0,1(a0)

.NoEnd

	* Rearrange vectors

	move.w	RMH_VBL_Vector(a5),d0
	ror.w	#8,d0
	move.w	d0,RMH_VBL_Vector(a5)

	move.w	RMH_RESET_Vector(a5),d0
	ror.w	#8,d0
	move.w	d0,RMH_RESET_Vector(a5)

	* Set OK signals

	st.l	RMH_HeaderValid(a5)

.Fail

	tst.l	.FileHandle
	beq	.no_fhandle

	move.l	_DosBase,a6
	move.l	.FileHandle,d1
	jsr	_LVOClose(a6)
	move.l	#0,.FileHandle

.no_fhandle

	tst.l	.FileLock
	beq	.no_lock

	move.l	_DosBase,a6
	move.l	.FileLock,d1
	jsr	_LVOUnLock(a6)

	move.l	#0,.FileLock


.no_lock

	tst.l	.FileInfoBlock
	beq	.no_FIB

	move.l	_DosBase,a6
	move.l	#DOS_FIB,d1
	move.l	.FileInfoBlock,d2
	jsr	_LVOFreeDosObject(a6)

	move.l	#0,.FileInfoBlock

.no_FIB

	movem.l	(sp)+,d0-a6
	rts

.FileInfoBlock		ds.l	1
.FileLock		ds.l	1
.FileHandle		ds.l	1
.FileROMHeaderValid	ds.l	1
.FileROMPlaceLow	ds.b	RMH_SIZEOF
.FileROMPlaceHigh	ds.b	RMH_SIZEOF

ROM_LoadImage
* * * * * * * * * * * * * * * * * * * * * * * * *
* Reads an entire ROM-image into buffer.	*
*						*
* IN:	a0 - ptr to filename.			*
*	a1 - ptr to ROM-buffer.			*
*	d0 - Size to load.			*
*						*
* * * * * * * * * * * * * * * * * * * * * * * * *

	movem.l	d0-a6,-(sp)

	move.l	a1,.FileMemPos
	move.l	d0,.FileSize

	move.l	_DosBase,a6
	move.l	a0,d1
	move.l	#MODE_OLDFILE,d2
	jsr	_LVOOpen(a6)
	move.l	d0,.FileHandle
	beq	.Fail

	move.l	_DosBase,a6
	move.l	.FileHandle,d1
	move.l	FileHeaderSize,d2
	move.l	#OFFSET_BEGINNING,d3
	jsr	_LVOSeek(a6)

	move.l	_DosBase,a6
	move.l	.FileHandle,d1
	move.l	.FileMemPos,d2
	move.l	.FileSize,d3
	jsr	_LVORead(a6)

	tst.l	.FileHandle
	beq	.no_fhandle

	move.l	_DosBase,a6
	move.l	.FileHandle,d1
	jsr	_LVOClose(a6)
	move.l	#0,.FileHandle

.no_fhandle

	movem.l	(sp)+,d0-a6
	st.l	d0
	rts

.Fail

	tst.l	.FileHandle
	beq	.fno_fhandle

	move.l	_DosBase,a6
	move.l	.FileHandle,d1
	jsr	_LVOClose(a6)
	move.l	#0,.FileHandle

.fno_fhandle

	movem.l	(sp)+,d0-a6
	clr.l	d0
	rts

.FileMemPos		ds.l	1
.FileSize		ds.l	1
.FileHandle		ds.l	1


	section	data,data

	* ROM Makeup list (How do i check for slow and fast rom?)

prg_ROMMakeupList

	dc.l	00,prg_ROMMakeupLowRomSlowRom
	dc.l	01,prg_ROMMakeupLowRomFastRom
	dc.l	10,prg_ROMMakeupHiROMSlowRom
	dc.l	11,prg_ROMMakeupHiROMFastRom
	dc.l	-1,prgROMMakeupUnknown

prg_ROMMakeupLowRomSlowRom	dc.b	"Low ROM / Slow ROM",0
prg_ROMMakeupLowRomFastRom	dc.b	"Low ROM / Fast ROM",0
prg_ROMMakeupHiROMSlowRom	dc.b	"Hi ROM / Slow ROM",0
prg_ROMMakeupHiROMFastRom	dc.b	"Hi ROM / Fast ROM",0
prgROMMakeupUnknown		dc.b	"ERROR: Unknown ROM setup",0

	even

	* ROM Type list

prg_ROMTypeList

	dc.l	00,prg_TypeROM
	dc.l	01,prg_TypeROMRAM
	dc.l	02,prg_TypeROMSRAM
	dc.l	03,prg_TypeROMDSP1
	dc.l	04,prg_TypeROMDSP1RAM
	dc.l	05,prg_TypeROMDSP1SRAM
	dc.l	06,prg_TypeFX
	dc.l	-1,prg_TypeUnknown


prg_TypeROM		dc.b	"Only ROM",0
prg_TypeROMRAM		dc.b	"ROM/RAM",0
prg_TypeROMSRAM		dc.b	"ROM/SRAM",0
prg_TypeROMDSP1		dc.b	"ROM/DSP1",0
prg_TypeROMDSP1RAM	dc.b	"ROM/DSP1/RAM",0
prg_TypeROMDSP1SRAM	dc.b	"ROM/DSP1/SRAM",0
prg_TypeFX		dc.b	"FX",0
prg_TypeUnknown		dc.b	"Unknown",0

	even

	* ROM Size list

prg_ROMSizeList
	dc.l	08,prg_ROMSize2MBit
	dc.l	09,prg_ROMSize4MBit
	dc.l	10,prg_ROMSize8MBit
	dc.l	11,prg_ROMSize16MBit
	dc.l	12,prg_ROMSize32MBit
	dc.l	-1,prg_ROMSizeUnknown

prg_ROMSize2MBit	dc.b	"2MBit (256kB)",0
prg_ROMSize4MBit	dc.b	"4MBit (512kB)",0
prg_ROMSize8MBit	dc.b	"8MBit (1MB)",0
prg_ROMSize16MBit	dc.b	"16MBit (2MB)",0
prg_ROMSize32MBit	dc.b	"32MBit (4MB)",0
prg_ROMSizeUnknown	dc.b	"Ambigious",0

	even

	* SRAM Size list

prg_SRAMSizeList
	dc.l	00,prg_SRAMSizeNone
	dc.l	01,prg_SRAMSize16kBit
	dc.l	02,prg_SRAMSize32kBit
	dc.l	03,prg_SRAMSize64kBit
	dc.l	-1,prg_SRAMSizeNone

prg_SRAMSizeNone		dc.b	"No SRAM",0
prg_SRAMSize16kBit		dc.b	"16kBit (2kB)",0
prg_SRAMSize32kBit		dc.b	"32kBit (4kB)",0
prg_SRAMSize64kBit		dc.b	"64kBit (8kB)",0

	even

	* Country list

prg_CountryList
	dc.l	00, prg_CountryJapan
	dc.l	01, prg_CountryUSA
	dc.l	02, prg_CountryEurope
	dc.l	03, prg_CountrySweden
	dc.l	04, prg_CountryFinland
	dc.l	05, prg_CountryDenmark
	dc.l	06, prg_CountryFrance
	dc.l	07, prg_CountryHolland
	dc.l	08, prg_CountrySpain
	dc.l	09, prg_CountryGermany
	dc.l	10, prg_CountryItaly
	dc.l	11, prg_CountryChina
	dc.l	12, prg_CountryIndonesia
	dc.l	13, prg_CountryKorea
	dc.l	-1, prg_CountryUnknown

prg_CountryJapan	dc.b	"Japan",0
prg_CountryUSA		dc.b	"USA",0
prg_CountryEurope	dc.b	"Europe",0
prg_CountrySweden	dc.b	"Sweden",0
prg_CountryFinland	dc.b	"Finland",0
prg_CountryDenmark	dc.b	"Denmark",0
prg_CountryFrance	dc.b	"France",0
prg_CountryHolland	dc.b	"Holland",0
prg_CountrySpain	dc.b	"Spain",0
prg_CountryGermany	dc.b	"Germany",0
prg_CountryItaly	dc.b	"Italy",0
prg_CountryChina	dc.b	"China",0
prg_CountryIndonesia	dc.b	"Indonesia",0
prg_CountryKorea	dc.b	"Korea",0
prg_CountryUnknown	dc.b	"Unknown",0

	cnop	0,4

	* License list

	;suspicious:

	;51 - Ninendo

prg_LicenseList
	dc.l	0,prg_LicenseInvalid
	dc.l	1,prg_LicenseNintendo
	dc.l	5,prg_LicenseZamuse
	dc.l	8,prg_LicenseCapcom
	dc.l	9,prg_LicenseHOT
	dc.l	10,prg_LicenseJaleco
	dc.l	11,prg_LicenseSTORM
	dc.l	15,prg_LicenseMebio
	dc.l	18,prg_LicenseGremlin
	dc.l	21,prg_LicenseCOBRA
	dc.l	22,prg_LicenseHuman
	dc.l	24,prg_LicenseHudson
	dc.l	26,prg_LicenseYanoman
	dc.l	28,prg_LicenseTecmo
	dc.l	30,prg_LicenseForum
	dc.l	31,prg_LicensePark
	dc.l	33,prg_LicenseTokai
	dc.l	34,prg_LicensePOW
	dc.l	35,prg_LicenseLoriciel
	dc.l	38,prg_LicenseEnix
	dc.l	40,prg_LicenseKemco
	dc.l	41,prg_LicenseSeta
	dc.l	45,prg_LicenseVisit
	dc.l	51,prg_LicenseNintendo2
	dc.l	53,prg_LicenseHECT
	dc.l	61,prg_LicenseLoriciel2
	dc.l	64,prg_LicenseSeika
	dc.l	65,prg_LicenseUBI
	dc.l	71,prg_LicenseSpectrum
	dc.l	73,prg_LicenseIrem
	dc.l	75,prg_LicenseRaya
	dc.l	76,prg_LicenseRenovation
	dc.l	77,prg_LicenseMalibu
	dc.l	79,prg_LicenseU.S.
	dc.l	80,prg_LicenseAbsolute
	dc.l	81,prg_LicenseAcclaim
	dc.l	82,prg_LicenseActivision
	dc.l	83,prg_LicenseAmerican
	dc.l	84,prg_LicenseGameTek
	dc.l	85,prg_LicenseHi
	dc.l	86,prg_LicenseLJN
	dc.l	90,prg_LicenseMindscape
	dc.l	93,prg_LicenseTechnos
	dc.l	95,prg_LicenseAmerican2
	dc.l	96,prg_LicenseTitus
	dc.l	97,prg_LicenseVirgin
	dc.l	98,prg_LicenseMaxis
	dc.l	103,prg_LicenseOcean
	dc.l	105,prg_LicenseElectronic
	dc.l	107,prg_LicenseLaser
	dc.l	110,prg_LicenseElite
	dc.l	111,prg_LicenseElectro
	dc.l	112,prg_LicenseInfogrames
	dc.l	113,prg_LicenseInterplay
	dc.l	114,prg_LicenseLucasArts
	dc.l	115,prg_LicenseSculptured
	dc.l	117,prg_LicenseSTORM2
	dc.l	120,prg_LicenseTHQ
	dc.l	121,prg_LicenseAccolade
	dc.l	122,prg_LicenseTriffix
	dc.l	124,prg_LicenseMicroprose
	dc.l	127,prg_LicenseKemco2
	dc.l	130,prg_LicenseNamcot
	dc.l	132,prg_LicenseKoei
	dc.l	134,prg_LicenseTokuma
	dc.l	136,prg_LicenseDATAM
	dc.l	139,prg_LicenseBullet
	dc.l	140,prg_LicenseVic
	dc.l	143,prg_LicenseIMax
	dc.l	145,prg_LicenseCHUN
	dc.l	146,prg_LicenseVideo
	dc.l	147,prg_LicenseBEC
	dc.l	151,prg_LicenseKaneco
	dc.l	153,prg_LicensePack
	dc.l	154,prg_LicenseNichibutsu
	dc.l	155,prg_LicenseTECMO
	dc.l	156,prg_LicenseImagineer
	dc.l	160,prg_LicenseWolf
	dc.l	164,prg_LicenseKonami
	dc.l	165,prg_LicenseK.Amusement
	dc.l	167,prg_LicenseTakara
	dc.l	169,prg_LicenseTechnos2
	dc.l	170,prg_LicenseJVC
	dc.l	172,prg_LicenseToei
	dc.l	173,prg_LicenseToho
	dc.l	175,prg_LicenseNamcot2
	dc.l	177,prg_LicenseASCII
	dc.l	178,prg_LicenseBanDai
	dc.l	180,prg_LicenseEnix2
	dc.l	182,prg_LicenseHalken
	dc.l	186,prg_LicenseCulture
	dc.l	187,prg_LicenseSunsoft
	dc.l	188,prg_LicenseToshiba
	dc.l	189,prg_LicenseSony
	dc.l	191,prg_LicenseSammy
	dc.l	192,prg_LicenseTaito
	dc.l	194,prg_LicenseKemco3
	dc.l	195,prg_LicenseSquare
	dc.l	196,prg_LicenseNHK
	dc.l	197,prg_LicenseData
	dc.l	198,prg_LicenseTonkin
	dc.l	200,prg_LicenseKOEI
	dc.l	202,prg_LicenseKonami2
	dc.l	205,prg_LicenseMeldac
	dc.l	206,prg_LicensePONY
	dc.l	207,prg_LicenseSotsu
	dc.l	209,prg_LicenseSofel
	dc.l	210,prg_LicenseQuest
	dc.l	211,prg_LicenseSigma
	dc.l	214,prg_LicenseNaxat
	dc.l	216,prg_LicenseCapcom2
	dc.l	217,prg_LicenseBanpresto
	dc.l	219,prg_LicenseHiro
	dc.l	221,prg_LicenseNCS
	dc.l	222,prg_LicenseHuman2
	dc.l	223,prg_LicenseRingler
	dc.l	224,prg_LicenseK.K.
	dc.l	226,prg_LicenseSotsu2
	dc.l	228,prg_LicenseTESoft
	dc.l	229,prg_LicenseEPOCH
	dc.l	231,prg_LicenseAthena
	dc.l	232,prg_LicenseAsmik
	dc.l	233,prg_LicenseNatsume
	dc.l	234,prg_LicenseKing
	dc.l	235,prg_LicenseAtlus
	dc.l	236,prg_LicenseSony2
	dc.l	238,prg_LicensePsygnosis
	dc.l	243,prg_LicenseBeam
	dc.l	244,prg_LicenseTec
	dc.l	255,prg_LicenseHudson2
	dc.l	-1,prg_LicenseUnknown	


prg_LicenseInvalid		dc.b	"<Invalid>",0
prg_LicenseNintendo		dc.b	"Nintendo",0
prg_LicenseZamuse		dc.b	"Zamuse",0
prg_LicenseCapcom		dc.b	"Capcom",0
prg_LicenseHOT			dc.b	"HOT B",0
prg_LicenseJaleco		dc.b	"Jaleco",0
prg_LicenseSTORM		dc.b	"STORM (Sales Curve) (1)",0
prg_LicenseMebio		dc.b	"Mebio Software",0
prg_LicenseGremlin		dc.b	"Gremlin Graphics",0
prg_LicenseCOBRA		dc.b	"COBRA Team",0
prg_LicenseHuman		dc.b	"Human/Field",0
prg_LicenseHudson		dc.b	"Hudson Soft",0
prg_LicenseYanoman		dc.b	"Yanoman",0
prg_LicenseTecmo		dc.b	"Tecmo (1)",0
prg_LicenseForum		dc.b	"Forum",0
prg_LicensePark			dc.b	"Park Place Productions / VIRGIN",0
prg_LicenseTokai		dc.b	"Tokai Engeneering (SUNSOFT?)",0
prg_LicensePOW			dc.b	"POW",0
prg_LicenseLoriciel		dc.b	"Loriciel / Micro World",0
prg_LicenseEnix			dc.b	"Enix",0
prg_LicenseKemco		dc.b	"Kemco (1)",0
prg_LicenseSeta			dc.b	"Seta Co.,Ltd.",0
prg_LicenseVisit		dc.b	"Visit Co.,Ltd.",0
prg_LicenseNintendo2		dc.b	"Nintendo (2?)",0
prg_LicenseHECT			dc.b	"HECT",0
prg_LicenseLoriciel2		dc.b	"Loriciel",0
prg_LicenseSeika		dc.b	"Seika Corp.",0
prg_LicenseUBI			dc.b	"UBI Soft",0
prg_LicenseSpectrum		dc.b	"Spectrum Holobyte",0
prg_LicenseIrem			dc.b	"Irem",0
prg_LicenseRaya			dc.b	"Raya Systems/Sculptured Software",0
prg_LicenseRenovation		dc.b	"Renovation Pruducts",0
prg_LicenseMalibu		dc.b	"Malibu Games (T*HQ Inc.) / Black Pearl",0
prg_LicenseU.S.			dc.b	"U.S. Gold",0
prg_LicenseAbsolute		dc.b	"Absolute Entertainment",0
prg_LicenseAcclaim		dc.b	"Acclaim",0
prg_LicenseActivision		dc.b	"Activision",0
prg_LicenseAmerican		dc.b	"American Sammy",0
prg_LicenseGameTek		dc.b	"GameTek",0
prg_LicenseHi			dc.b	"Hi Tech",0
prg_LicenseLJN			dc.b	"LJN Toys",0
prg_LicenseMindscape		dc.b	"Mindscape",0
prg_LicenseTechnos		dc.b	"Technos Japan Corp. (Tradewest)",0
prg_LicenseAmerican2		dc.b	"American Softworks Corp.",0
prg_LicenseTitus		dc.b	"Titus",0
prg_LicenseVirgin		dc.b	"Virgin Games",0
prg_LicenseMaxis		dc.b	"Maxis",0
prg_LicenseOcean		dc.b	"Ocean",0
prg_LicenseElectronic		dc.b	"Electronic Arts",0
prg_LicenseLaser		dc.b	"Laser Beam",0
prg_LicenseElite		dc.b	"Elite",0
prg_LicenseElectro		dc.b	"Electro Brain",0
prg_LicenseInfogrames		dc.b	"Infogrames",0
prg_LicenseInterplay		dc.b	"Interplay",0
prg_LicenseLucasArts		dc.b	"LucasArts",0
prg_LicenseSculptured		dc.b	"Sculptured Soft",0
prg_LicenseSTORM2		dc.b	"STORM (Sales Curve) (2)",0
prg_LicenseTHQ			dc.b	"THQ Software",0
prg_LicenseAccolade		dc.b	"Accolade Inc.",0
prg_LicenseTriffix		dc.b	"Triffix Entertainment",0
prg_LicenseMicroprose		dc.b	"Microprose",0
prg_LicenseKemco2		dc.b	"Kemco (2)",0
prg_LicenseNamcot		dc.b	"Namcot/Namco Ltd. (1)",0
prg_LicenseKoei			dc.b	"Koei/Koei! (second license?)",0
prg_LicenseTokuma		dc.b	"Tokuma Shoten Intermedia",0
prg_LicenseDATAM		dc.b	"DATAM-Polystar",0
prg_LicenseBullet		dc.b	"Bullet-Proof Software",0
prg_LicenseVic			dc.b	"Vic Tokai",0
prg_LicenseIMax			dc.b	"I'Max",0
prg_LicenseCHUN			dc.b	"CHUN Soft",0
prg_LicenseVideo		dc.b	"Video System Co., Ltd.",0
prg_LicenseBEC			dc.b	"BEC",0
prg_LicenseKaneco		dc.b	"Kaneco",0
prg_LicensePack			dc.b	"Pack in Video",0
prg_LicenseNichibutsu		dc.b	"Nichibutsu",0
prg_LicenseTECMO		dc.b	"TECMO (2)",0
prg_LicenseImagineer		dc.b	"Imagineer Co.",0
prg_LicenseWolf			dc.b	"Wolf Team",0
prg_LicenseKonami		dc.b	"Konami",0
prg_LicenseK.Amusement		dc.b	"K.Amusement",0
prg_LicenseTakara		dc.b	"Takara",0
prg_LicenseTechnos2		dc.b	"Technos Jap. ????",0
prg_LicenseJVC			dc.b	"JVC",0
prg_LicenseToei			dc.b	"Toei Animation",0
prg_LicenseToho			dc.b	"Toho",0
prg_LicenseNamcot2		dc.b	"Namcot/Namco Ltd. (2)",0
prg_LicenseASCII		dc.b	"ASCII Co. Activison",0
prg_LicenseBanDai		dc.b	"BanDai America",0
prg_LicenseEnix2		dc.b	"Enix",0
prg_LicenseHalken		dc.b	"Halken",0
prg_LicenseCulture		dc.b	"Culture Brain",0
prg_LicenseSunsoft		dc.b	"Sunsoft",0
prg_LicenseToshiba		dc.b	"Toshiba EMI/System Vision",0
prg_LicenseSony			dc.b	"Sony (Japan) / Imagesoft",0
prg_LicenseSammy		dc.b	"Sammy",0
prg_LicenseTaito		dc.b	"Taito",0
prg_LicenseKemco3		dc.b	"Kemco (3) ????",0
prg_LicenseSquare		dc.b	"Square",0
prg_LicenseNHK			dc.b	"NHK",0
prg_LicenseData			dc.b	"Data East",0
prg_LicenseTonkin		dc.b	"Tonkin House",0
prg_LicenseKOEI			dc.b	"KOEI",0
prg_LicenseKonami2		dc.b	"Konami USA",0
prg_LicenseMeldac		dc.b	"Meldac/KAZe",0
prg_LicensePONY			dc.b	"PONY CANYON",0
prg_LicenseSotsu		dc.b	"Sotsu Agency",0
prg_LicenseSofel		dc.b	"Sofel",0
prg_LicenseQuest		dc.b	"Quest Corp.",0
prg_LicenseSigma		dc.b	"Sigma",0
prg_LicenseNaxat		dc.b	"Naxat",0
prg_LicenseCapcom2		dc.b	"Capcom Co., Ltd. (2)",0
prg_LicenseBanpresto		dc.b	"Banpresto",0
prg_LicenseHiro			dc.b	"Hiro",0
prg_LicenseNCS			dc.b	"NCS",0
prg_LicenseHuman2		dc.b	"Human Entertainment",0
prg_LicenseRingler		dc.b	"Ringler Studios",0
prg_LicenseK.K.			dc.b	"K.K. DCE / Jaleco",0
prg_LicenseSotsu2		dc.b	"Sotsu Agency",0
prg_LicenseTESoft		dc.b	"T&ESoft",0
prg_LicenseEPOCH		dc.b	"EPOCH Co.,Ltd.",0
prg_LicenseAthena		dc.b	"Athena",0
prg_LicenseAsmik		dc.b	"Asmik",0
prg_LicenseNatsume		dc.b	"Natsume",0
prg_LicenseKing			dc.b	"King/A Wave",0
prg_LicenseAtlus		dc.b	"Atlus",0
prg_LicenseSony2		dc.b	"Sony Music",0
prg_LicensePsygnosis		dc.b	"Psygnosis / igs",0
prg_LicenseBeam			dc.b	"Beam Software",0
prg_LicenseTec			dc.b	"Tec Magik",0
prg_LicenseHudson2		dc.b	"Hudson Soft",0
prg_LicenseUnknown		dc.b	"Unknown",0

	even

	section	bss,bss

FileHeaderSize		ds.l	1
prg_ROMSize		ds.l	1