;
; Install Script for XFile 1.7 / 37.721
;
;
; ReqTools messages
;
(set #reqtoolsname "Libs/reqtools.library")
(set #reqtools-dest "LIBS:")

;
; XFile specific messages
;
(set @default-dest  "Xenolink:Utilities")
(set #xfileversion  "XFile 1.7 (37.721)")
(set #xfile-askdir  ("Where do you want to install %s?" #xfileversion))
(set #xfile-askdir2 ("Where do you want to install the documentation and other files for the %s distribution?" #xfileversion))
(set #install-msg   ("\n\nXFile installation script\nThis script installs XFile on your Amiga\n\n%s © 1991-1995 by Tommy Green\nAll rights reserved\nSpread as public domain" #xfileversion))

(set #prompt1       "Do you want to install reqtools.library 38.1266?")
(set #prompt2       "Where do you want to install XFile?")
(set #prompt3       "Do you want to install textfield.gadget 3.0?")
(set #prompt4       "Do you want to install the documentation?")
(set #prompt5       "Do you want to install the history file?")
(set #prompt6       "Do you want to install the configuration?")


;
; Textfield.Gadget specific messages
;
(set #os30-dest "SYS:Classes/Gadgets")
(set #os20-dest "/Gadgets")
(set #textfield-name "Libs/Textfield.gadget")

;
; Abort messages
;
(set #bad-OS ("Sorry, you need at least OS 2.04 (V37) to run %s. You also need Xenolink 1.90+." #xfileversion))

;
; Make sure we install on an OS higher than or equal to OS 2.04 (V37).
;
(if (< (/ (getversion) 65536) 37)
(
 (abort #bad-OS)
))

;
; Display install message
;
(message #install-msg)

;
; Copy reqtools.library to libs:
;
(copyfiles
        (prompt #prompt1)
        (source #reqtoolsname)
        (dest   #reqtools-dest)
        (help   @copyfiles-help)
        (infos)
        (confirm)
)

;
; Get default directory for installation
;
(set #xfile-dest
            (askdir
                   (prompt  #xfile-askdir)
                   (help    @askdir-help)
                   (default @default-dest)
            )
)

;
; Copy XFile to default directory
;
(copyfiles
         (prompt  #prompt2)
         (source  "XFile")
         (dest    #xfile-dest)
         (help    @copyfiles-help)
         (infos)
         (confirm)
)

;
; Find out if we run on an OS that supports DataTypes in SYS:Classes or not.
;
(if (< (/ (getversion) 65536) 39)
 (
  (makedir ("%s" #xfile-dest #os20-dest ))
  (copyfiles
         (prompt      #prompt3)
         (source      #textfield-name)
         (dest        ("%s%s" #xfile-dest #os20-dest ))
         (help        @copyfiles-help)
         (infos)
         (confirm)
  )
 )
 (
  (copyfiles
         (prompt      #prompt3)
         (source      #textfield-name)
         (dest        #os30-dest)
         (help        @copyfiles-help)
         (infos)
         (confirm)
  )
 )
)

;
; Get default directory for installation
;
(set #xfile-dest
            (askdir
                   (prompt  #xfile-askdir2)
                   (help    @askdir-help)
                   (default @default-dest)
            )
)

;
; Copying support files and documentation
;
(copyfiles
         (prompt  #prompt4)
         (source  "Docs/XFile.guide")
         (dest    #xfile-dest)
         (help    @copyfiles-help)
         (infos)
         (confirm)
)

(copyfiles
         (prompt  #prompt5)
         (source  "Docs/XFile.History")
         (dest    #xfile-dest)
         (help    @copyfiles-help)
         (infos)
         (confirm)
)

(makedir "XCONFIG:XFile" (infos))

(copyfiles
         (prompt  #prompt6)
         (source  "XFile.config")
         (dest    "XCONFIG:XFile/")
         (help    @copyfiles-help)
         (infos)
         (confirm)
)