*SOURCELISTING for Devpac or MasterSeka
*
* MAX
* expands (current active) window to maximum size
*
* by Gertjan 'Bugs' van Ratingen
*    P. Dijkmansstraat 1c
*    5611 RA  Eindhoven
*

MAX:	MOVEA.L	$4.W,A6			;execbase
	LEA	intname(pc),A1
	JSR	-$198(A6)		;openlib
	MOVEA.L	D0,A6			;intuitionbase
	MOVEA.L	56(A6),A4		;A4 => activescreen
	CMPA.L	#0,A4			;no screen?!
	BEQ.S	exit			;then quit
	MOVEA.L	52(A6),A5		;activewindow
	CMPA.L	#0,A5			;nothing?
	BEQ.S	exit			;then quit
	MOVEA.L	A5,A0
	JSR	-$138(A6)		;WindowToFront()
	MOVE.W	12(A4),D6		;screen width
	MOVE.W	14(A4),D7		;screen height
	MOVEA.L	A5,A0			;window
	MOVE.W	4(A5),D0		;dx:=window_leftedge
	NEG.W	D0			;dx:=-dx
	MOVE.W	6(A5),D1		;dy:=window_topedge
	NEG.W	D1			;dy:=-dy
	JSR	-$A8(A6)		;movewindow() to topleft corner

	MOVEA.L	A5,A0			;window
	MOVE.W	D6,D0			;dx:=screen width
	SUB.W	8(A5),D0		;dx:=dx-windowwidth
	MOVE.W	D7,D1			;dy:=screen height
	SUB.W	10(A5),D1		;dy:=dy-windowheight
	JSR	-$120(A6)		;sizewindow()

exit:	MOVEA.L	A6,A1			;intuitionbase
	MOVEA.L	$4.W,A6			;execbase
	JSR	-$19E(A6)		;closelibrary()
	MOVEQ	#0,D1
	RTS
 
intname	dc.b	'intuition.library',0
	END