/*
** ReverseANIM.adpro
**
** $VER: ReverseANIM.adpro 1.0.2 (6.1.93)
**
** This AREXX program will take an existing ANIM file and create a new
** anim that is reversed.
**
** Example ARexx program for controlling MorphPlus/ADPro by ASDG Incorporated.
**
** Copyright © 1990-1992 ASDG Incorporated  All Rights Reserved
*/

ADDRESS "ADPro"
OPTIONS RESULTS

NEWLINE = '0A'X

ADPRO_TO_FRONT

PSTATUS
oldPSTATUS = ADPRO_RESULT
PSTATUS "UNLOCKED"

GETFILE '"Enter ANIM To Reverse"' "ADPRO:"
IF (RC ~= 0) THEN DO
	OKAY1 "Error, no source anim specified."
	EXIT 10
END
fname = ADPRO_RESULT

CALL "FREDSCRIPTS:FREDFunctions/GetSaver" "ANIM"
IF (RESULT ~= 0) THEN
	EXIT RESULT

CALL "FREDSCRIPTS:FREDFunctions/GetLoader" "ANIM"
IF (RESULT ~= 0) THEN
	EXIT RESULT

GETFILE '"Enter of name of ANIM to create,"' "ADPRO:"
IF (RC ~= 0) THEN DO
	OKAY1 "Error, no dest anim specified."
	EXIT 10
END
nname = ADPRO_RESULT

LOAD fname "COUNT"
IF (RC ~= 0) THEN DO
	OKAY1 "Can't find ANIM file."
        EXIT 10
END

num = ADPRO_RESULT

continue = 0
DO WHILE (continue = 0)
        LOAD fname "FRAME" num
        IF (RC ~= 0) THEN DO
        	OKAY1 "Error during load" || NEWLINE ||,
                        "of frame " || num || "."
        	EXIT 10
        END
	SAVE nname "IMAGE" "APPEND"
	IF (RC ~= 0) THEN DO
		OKAY1 "Error during save" || NEWLINE ||,
			"of frame " || num || "."
		EXIT 10
        END
        num = num - 1
        IF (num = 0) THEN
        	continue = 1
END

SAVE nname "IMAGE" "QUIT"
IF (RC ~= 0) THEN DO
	OKAY1 "Error when closing dest anim."
        EXIT 10
END

PSTATUS oldPSTATUS

EXIT 0