;
; $PROJECT: StdIO-Device
;
; $VER: Install 1.1 (17.01.95)
;
; by
;
; Stefan Ruppert , Windthorststraße 5 , 65439 Flörsheim , GERMANY
;
; (C) Copyright 1995
; All Rights Reserved !
;
; $HISTORY:
;
; 17.01.95 : 001.001 : initial
;

(set #handler      (cat "StdIO-Handler"))

(set mode
     (askchoice
         (prompt @app-name)
         (help @askchoice-help)
         (choices "Install" "Remove")
     )
)

(if mode
        (set pmode "Remove")
        (set pmode "Install")
)

; get handlers dir
(set handlersdir
        (askdir
                (prompt "Where do the Handlers belong")
                (help @askdir-help)
                (default "L:")
        )
)

; now do install or remove
(if mode
        ; Remove
        (
                ; Show what we are doing
                (working "Removing " @app-name)

                ; Remove the non-standard pieces
                (delete (tackon handlersdir  #handler))
                (trap 4 (delete "devs:DOSDrivers/STDIO" (infos)))
                (trap 4 (delete "Storage:DOSDrivers/STDIO" (infos)))

                ; Don't want to use the confusing "Installation Complete" message
                ; when what we really did was remove things...
                (message "The \"" @app-name "\" components "
                         "that you specified have been successfully removed")
                (exit (quiet))
        )

        ; Install
        (
                (working "Installing " @app-name)

                ; Install the handler
                (copylib
                        (prompt (cat "Copying " @app-name))
                        (help @copylib-help)
                        (source #handler)
                        (dest handlersdir)
                        (confirm)
                )

                ; Install the descriptors
                (copyfiles
                        (prompt "Copying the DOSDriver description")
                        (help @copyfiles-help)
                        (source "STDIO")
                        (dest "DEVS:DOSDrivers/")
                        (infos)
                        (confirm)
                )

        )
)

(set @default-dest handlersdir)