;MS-DOS® For AmigaDOS®,   Copyright ©1996  Dave Lomax
;This Installer for $VER 3.6 (25.3.1996)

(complete 0)

(set #warn-kickstart-text
(cat	"\nBAD VERSION OF KICKSTART\n\n"
	"MSDOS for AmigaDOS, and DosWedge require KickStart 2.0 (V37) or higher.  They will not work on earlier versions.\n"
	"You currently are running KickStart V%ld.\n\n"
))

(set ver (/ (getversion) 65536) )

(if (< ver 37) (
	(set warning (#warn-kickstart-text ver) ) (message warning)
))

(set @DESTINATION
	(askdir
		(prompt "Where would you like MSDOS® For AmigaDOS® Installed?\n"
		        "(A directory called MSDOS will be created there)")
      		(help @askdir-help)
      		(default "SYS:System")
	)
)

(set @DEST (tackon @DESTINATION "MSDOS"))

(complete 5)

(makedir @DEST
	(prompt "\n\n\n\nCreating directory MSDOS")
	(help "\n\n\nI'm making a directory to bung all\n"
	      "of the MS-DOS® commands in.\n\n"
              "If you move it, you MUST change the\n"
              "User-Startup assign accordingly")
	(infos)
	(confirm)
)

(complete 5)

(copyfiles
	(prompt "\n\n\n\n"
                "Installing MS-DOS® Commands...\n\n"
                "This will copy across all the MS-DOS® commands\n")
	(help @copyfiles-help)
	(source "DOS6")
	(dest @DEST)
	(all)
	(infos)
)

(complete 40)

(set @DESTHELP
        (askdir
                (prompt "Where would you like the Help Guide Installed?")
                (help @askdir-help)
                (default @DEST)
        )
)

(complete 40)

(copyfiles
	(prompt "Copying MSDOS.Guide\n")
	(help "This will copy the MSDOS.Guide file\n"
	      "to where you have just selected\n")
	(source "MSDOS_36.Guide")
	(dest @DESTHELP)
	(infos)
	(confirm)
)

(complete 70)

(startup "[MSDOS® For AmigaDOS®     ©1996 Dave Lomax]"
	(prompt "\n\n\n\nAdding an assign to\n\nS:User-Startup")
	(help "This will add a line to your\n\n"
	      "S:User-Startup file which simply\n\n"
	      "makes an ASSIGN to its path.\n")
	(command (cat "Assign DOS6: " @DEST))
)

(complete 80)

(makeassign "DOS6" @DEST)

(complete 85)

(copyfiles
	(prompt "\n\n\nInstalling icons")
	(help "\n\nThis simply copies across all"
	      "\nthe icons which SnapShot your new"
	      "\ngoodies in exactly the right place."
	      "\nNothing to fear!")
	(source "Icons")
	(pattern "~MSDOS.info")
	(dest "DOS6:")
	(confirm)
)

(copyfiles
	(prompt "\n\n\nInstalling directory icon")
	(source "Icons/MSDOS.info")
	(dest "DOS6:/")
)

(complete 100)

(message "\n\n\nDon't forget!!\n\n"
         "You can't use .. & . & * yet\n"
         "until you have Installed DosWedge!\n\n"
         "Please install that now, by locating\n"
         "and double-clicking its Install icon\n\n"
         "Then reboot!")

(exit)