.key REMOVE/S
.bra {
.ket }

; $VER: MS-DOS-6 V3.5 (22.1.1996)

Echo " "

;Did they want it REMOVE-ing?
If {REMOVE} EQ REMOVE
	If Exists "RAM:MSDOS.ON"                ;Check it's already installed!
    	Path DOS6: remove
        Delete >NIL: "RAM:MSDOS.ON"             ;UN-install it!!
        Echo "MS-DOS removed!"
        Echo " "
        Quit >NIL:                              ;Break from this script!
    EndIf
EndIf

;Already started?
If Exists "RAM:MSDOS.ON"
	Echo "MS-DOS For AmigaDOS is already loaded!"
	Echo " "
	Echo "Useage:  MSDOS [REMOVE]"
Else
    Echo "Starting MS-DOS..."

	;Start up MS-DOS, by adding the DOS6: command path, & CLI prompt..
    	Path DOS6: ADD
    	Prompt "%S> "

	;Set loadsa command ALIASes, so that DOS6's commands are installed over AmigaDOS
    	Assign A: DF0: PATH
    	Assign B: DF1: PATH
    	Alias Attrib Protect [] quiet
    	Alias Backup Execute DOS6:BACKUP
    	Alias Buffers Addbuffers
    	Alias Call Execute
    	Alias Cd/ Cd /
    	Alias Cd\ Cd /
    	Alias Cd.. Cd /
    	Alias Chdir Cd
    	Alias ChkDsk Diskdoctor
    	Alias Choice Ask
    	Alias Cls Echo ""
    	Alias Copy DOS6:Copy [] quiet
    	Alias Country Setmap
    	Alias Date Execute DOS6:DATE
    	Alias DeFrag Reorg
    	Alias Del Delete [] quiet
    	Alias Del. Execute DOS6:DEL.
    	Alias DelTree Execute DOS6:DELTREE
    	Alias Dir DOS6:DF ANSI NOICONS LIST WEEKDAYS
    	Alias Dir, DOS6:DF ANSI LIST WEEKDAYS
    	Alias Dir/w DOS6:DF WIDE ANSI NOICONS
    	Alias Dir/a DOS6:DF ANSI LIST NOMUFS WEEKDAYS
    	Alias Dir/w/a DOS6:DF WIDE ANSI
    	Alias Dir/a/w DOS6:DF WIDE ANSI
    	Alias Edlin MEmacs
    	Alias Erase Delete [] force quiet
    	Alias Expand LHA x -a           ;Requires LHA!
    	Alias Exit EndCLI >NIL:
    	Alias FDisk SYS:Tools/HDToolBox
    	Alias FF Search : [] all nonum quiet quick file  ;Emulates the NORTON file-find!
    	Alias Find Search #? [] nonum quiet quick  ;Searches for a string!
    	Alias Format Execute DOS6:Format
    	Alias Goto Skip [] BACK         ;Back function KS3.0 UP
    	Alias Help DOS6:Help
    	Alias Install Resident
    	Alias KeyBuk Echo "Function not supported!"
    	Alias Label Execute DOS6:LABEL
    	Alias List DOS6:DF LIST ANSI NOICONS
    	Alias ListCommands Type DOS6:ListCommands
    	Alias MakeDir DOS6:MakeDir
        Alias Map Execute DOS6:MAP
        Alias Md DOS6:Makedir
    	Alias Mem Avail
    	Alias MKDir DOS6:Makedir
    	Alias Mode Prefs:Preferences
    	Alias Move DOS6:MOVE [] quiet
    	Alias Pause Ask "Press [RETURN] to continue..."
    	Alias PConsole Run >NIL: Printmanager ;Needs printmanager
    	Alias Print Printfiles -f
    	Alias QCd Cd []#?
    	Alias Rd Delete [] quiet
    	Alias Rem ;
    	Alias Ren Rename
    	Alias Restore Execute DOS6:RESTORE
    	Alias RmDir Execute DOS6:DelTree
        Alias ScanDisk DiskSalv
    	Alias Set Setenv
    	Alias SetVer Version
    	Alias SmartDrv PowerCache
    	Alias Stacks Stack
    	Alias Time Execute DOS6:TIME
    	Alias Ver Echo "MS-DOS Version 6.20"
    	Alias Vol Which
    	Alias VSafe Virus_Checker n             ;Needs VC
    	Alias XCopy "Copy CLONE [] all quiet noreq"

	;Show MS-DOS version
    	Echo "MSDOS® For AmigaDOS® ©1996 Dave Lomax, Shareware. Version 3.5"
    	Echo "MS-DOS Version 6.20"
	Echo " "

	;Set a flag in RAM just to say that MS-DOS is installed
    	Echo >"RAM:MSDOS.ON" "MS-DOS Loaded"

	;Install DOSKEY (MS-DOS version of alias!)
    	Alias DOSKey Alias
    	Echo "DOSKEY Installed."
EndIf

Echo " "