/*************************************************************************
* ExecARexxBlock.ttx:	Executes the selected block in the current file
*                       as ARexx Macro (asks for arguments)
* Author: 	        Roberto Fabbri, fabbri@dimi.uniud.it
* Distribution:		Copyright 1995 Roberto Fabbri
*			This file is freely distributable provided it is
*			distributed in its entirety.
*
* Version:		$VER: ExecARexxBlock.ttx 1.0 (03.06.95)
* Version history:
*               1.0 (03.06.95) Initial Release
**************************************************************************/

OPTIONS RESULTS

CALL TellUser("Executing Current Block")

GetScreenInfo

PARSE VAR RESULT dum dum width dum dum dum dum '"' screenname '"' .

outwin = '"CON:50/100/' || width || '/150/Executing ARexx Macro/Screen ' || screenname || '/Close/WAIT"'

GetBlk line.

RESULT=''

RequestStr PROMPT "Arguments"

argum=RESULT

IF ~Open('script', 't:Script', "w")  THEN DO
        CALL ReportError("Cannot Open Temp File")
        EXIT 5
END

CALL WriteLn('script','/* Temp Script */')

DO i=1 TO line.0
        CALL WriteLn('script',line.i)
END

CALL Close('script')
ADDRESS COMMAND "rx >" || outwin || " t:Script" argum
ADDRESS COMMAND "Delete t:Script FORCE"
CALL TellUser("Done")

EXIT 0

ReportError: PROCEDURE
	PARSE ARG msg
	BeepScreen
	SetStatusBar TEMPORARY msg
	RETURN

TellUser: PROCEDURE
	PARSE ARG msg
	SetStatusBar TEMPORARY msg
	RETURN