;
; Script d'installation pour ACal
;

(set @default-dest "SYS:WBStartup")


;===========================================================================
; Chaînes françaises

(if (= @language "français")
	(
		(set default_lang 2)
		
		(set #bad-kick "ACal nécessite au moins le Kickstart 2.04\nDésolé")
		
		(welcome "Bienvenue dans l'utilitaire d'installation d'ACal")
		(set #install-msg
			(cat "\nScript d'installation d'ACal v1.0\n"
			     "Ce script installe ACal sur votre Amiga.\n\n"
			     "© 1994-95 Denis Galiana"
			)
		)
		
		(set #acal-dir "Indiquez le répertoire où doit être copié ACal")

		(set #copy-acal "Copie du programme ACal et de son icône")

		(set #langage
			(cat "Choisissez les différentes traductions d'ACal "
			     "que vous voulez installer."
			)
		)
		
		(set #run-acal
			(cat "Le programme ACal va maintenant être lancé afin de vous "
			     "permettre de le configurer.\n\n"
			     "Dans le menu, choisissez 'Verrouiller fenêtre' afin de "
			     "pouvoir déplacer la fenêtre.\n"
			     "Puis, choisissez les fontes du jour et du mois.\n\n"
			     "Finallement, sauvegardez la configuration (position et "
			     "fontes) et quittez."
			)
		)

		(set #acal-running "Lancement du programme ACal ...")
	)
)


;===========================================================================
; english strings

(if (= @language "english")
	(
		(set default_lang 1)
		
		(set #bad-kick "ACal needs Kickstart 2.04 or more.\nSory")
		
		(welcome "Welcome in ACal installation utility")
		(set #install-msg
			(cat "\nInstallation script for ACal v1.0\n"
			     "This script installs ACal on your Amiga.\n\n"
			     "© 1994-95 Denis Galiana"
			)
		)
		
		(set #acal-dir "Please, select directory where ACal should be copied")

		(set #copy-acal "Copying ACal program and its icon")

		(set #langage
			(cat "Choose different translations of ACal "
			     "that you want to install."
			)
		)
		
		(set #run-acal
			(cat "ACal program is about to be run for you to set it up.\n\n"
			     "In the menu, select 'Lock window' to allow window movement.\n"
			     "Then, choose day and month fonts.\n\n"
			     "Finaly, save the configuration (position and fonts) "
			     "then quit."
			)
		)

		(set #acal-running "Run ACal program ...")
	)
)


;===========================================================================
; Regarde si la version du système est au moins 2.04 (37)


(if (< (/ (getversion) 65536) 37)
	(
		(message #bad-kick)
		(exit (quiet))
	)
)

;===========================================================================
; Début

(message #install-msg)

;===========================================================================
; Copie du programme dans sys:wbstartup

; Demande le répertoire

(set @default-dest
	(askdir
		(prompt #acal-dir)
		(help @askdir-help)
		(default "SYS:WBStartup")
	)
)

(copyfiles
	(prompt #copy-acal)
	(help @copyfiles-help)
	(source "ACal")
	(dest @default-dest)
	(infos)
	(confirm)
)

(complete 50)

;===========================================================================
; Installe la Locale

(if (AND (NOT (= (getassign "Locale") "")) (exists "libs:locale.library"))
	(
		(set lang
			(askoptions
				(prompt #langage)
				(help #langage-help)
				(choices
					"English"
					"Français"
					"Deutsch"
				)
				(default default_lang)
			)
		)

		(set n 0)
		(while
			(set language
				(select n
					"english"
					"français"
					"deutsch"
					""
				)
			)
			(
				(if (AND (IN lang n) (<> 1 n))
					(
						(copylib
							(prompt "")
							(help "")
							(source (cat "Catalogs/" language "/ACal.catalog"))
							(dest (cat "LOCALE:Catalogs/" language))
							(confirm)
						)
					)
				)
				(set n (+ n 1))
			)
		)
	)
)

(complete 80)

;===========================================================================
; Lancement du programme pour la sauvegarde des préférences

(message #run-acal)

(run (tackon @default-dest "ACal")
	(prompt #acal-running)
	(help "")
	(confirm)
)

(complete 100)