; Installer installation script for CatEdit
;$VER:Install 38.5 (25.2.94)

(set @default-dest "")

(set catedit "CatEdit")
(set catalogdir "Catalogs/")
(set reqtoolslib "libs/reqtools.library")

;================================================================================
; English strings

(set #bad-kick
	(cat "You must have Kickstart 2.04 or higher installed to use CatEdit!")
)

(set #welcome
	(cat "\nCatEdit installation\n\n\n"
             "This script installs CatEdit 1.1b\n"
             "on your Amiga.\n\n\n\n"
             "CatEdit © 1993-1994 Rafael D'Halleweyn\n"
             "All rights reserved\n\n"
             "(reqtools.library © Nico François)")
)

(set #where-catedit
	(cat "In wich drawer should CatEdit be installed?")
)

(set #which-language
	(cat "\nWhich languages should be installed?")
)
(set #which-language-help
	(cat "\nThe Amiga can be operated in many different languages. "
	     "If you want CatEdit to use the same language as the Amiga "
	     "Workbench a catalog file must be copied to your harddisk "
	     " for each language supported.\n\n"
	     "To reduce the amount of space consumed by the language "
	     "files, you can select to have only the files of specific "
	     "languages copied.\n\n"
	     "Simply check the boxes of the languages you wich to have "
	     "available on your system.\n\n")
)

(set #copying-reqtools
	(cat "Copying reqtools.library to LIBS:...")
)
(set #copying-reqtools-help
	(cat "CatEdit requires the reqtools.library in your LIBS: drawer\n\n")
)

;================================================================================
; make sure we are running under a 2.04 ROM

(if (< (/ (getversion) 65536) 37)
	(
		(abort #bad-kick)
	)
)

;================================================================================
;

(complete 0)

(message #welcome)

(welcome)
(set old_level @user-level)

(user 2)
(set cateditdir
	(askdir
		(prompt #where-catedit)
		(help @askdir-help)
		(default "SYS:Tools")
	)
)

(user old_level)
(copyfiles
	(prompt cateditdir)
	(source catedit)
	(dest cateditdir)
	(infos)
	(noposition)
)

(complete 70)

(if (exists "SYS:Locale")
	(
		(if (exists "LOCALE:")
			(
				(user 2)
				(set lang
					(askoptions
						(prompt #which-language)
						(help #which-language-help @askoptions-help)
						(choices
							"Dansk"
							"Deutsch"
							"English"
							"Español"
							"Nederlands"
							"Svenska")
						(default default_lang)
					)
				)
				(user old_level)
				(set n 0)
				(while (set language
						(select n
							"dansk"
							"deutsch"
							"english"
							"español"
							"nederlands"
							"svenska"
							"")
						)
					(
						(if (IN lang n)
							(
								(if (<> "english" language)
									(
										(makedir (cat "LOCALE:Catalogs/" language))
										(copyfiles
											(source (cat (cat catalogdir language) "/catedit.catalog"))
											(dest (cat "LOCALE:Catalogs/" language)))
									))
							))
						(set n (+ n 1))
					))
			))
	))

(complete 90)

(user old_level)
(copylib
  (prompt "\n" #copying-reqtools)
  (help #copying-reqtools-help @copylib-help)
  (source reqtoolslib)
  (dest "LIBS:")
  (confirm)
)

(complete 100)
(exit)