; == English strings =========================================================

(set default-lang 4)

(set #bad-kick "You must be using Kickstart 2.04+ to install ClipHistory")

(set #install-msg
  (cat
    "\n\nWelcome to the ClipHistory installation utility.\n\n"
    "This program lets you install ClipHistory on your Amiga.\n\n"
    "See the manual for more information about ClipHistory.\n\n"
    "ClipHistory © 1994  Magnus Holmgren."
  )
)

(set #welcome "Welcome to the ClipHistory installer utility.")

(set #copying "Copying ")

(set #were-cliphistory
  (cat
    "Where would you like to install ClipHistory?"
  )
)

(set #help-were-cliphistory
  (cat
    "    If you place ClipHistory in Sys:WBStartup, it will automatically "
    "be started each time you start your Amiga."
  )
)

(set #install-cliphistory-guide
  "Would you like to install ClipHistory.guide?"
)

(set #were-cliphistory-guide
  "Where would you like to install ClipHistory.guide?"
)

(set #help-were-reqchange-guide
  (cat
    "    ClipHistory.guide is the manual for ClipHistory in the special "
    "AmigaGuide® hypertext format. You need a program like AmigaGuide or "
    "MultiView to view it properly."
  )
)

(set #install-cliphistory-man
  "Would you like to install ClipHistory.man?"
)

(set #were-cliphistory-man
  "Where would you like to install ClipHistory.man?"
)

(set #help-were-reqchange-man
  (cat
    "    ClipHistory.man is the manual for ClipHistory in normal text "
    "format, suitable for any More-like program. If you already have "
    "installed ClipHistory.guide then you'll probably have no need for this "
    "file."
  )
)

(set #which-language "\nWhich languages should be installed?")

(set #which-language-help
  (cat
    "    The Amiga can be operated in many different languages. If you "
    "want ClipHistory to use the same language as the Amiga Workbench "
    "then a catalog file must be copied to your harddisk for each "
    "language supported.\n"
    "    To reduce the amount of space consumed by the language files, "
    "you can select to have only the files of specific languages "
    "copied.\n"
    "    Simply check the boxes of the languages you wish to have "
    "available on your system.\n"
    "    Please note that there are not language files for all listed "
    "languages."
  )
)

; == =========================================================

(if (= @language "dansk" )
  (
    (set default-lang 2)
  )
)

; == German strings =========================================================

(if (= @language "deutsch")
  (
    (set default-lang 1)
  )
)

; == =========================================================

(if (= @language "español")
  (
    (set default-lang 8)
  )
)

; == =========================================================
(if (= @language "français")
  (
    (set default-lang 16)
  )
)

; == =========================================================

(if (= @language "italiano")
  (
    (set default-lang 32)
  )
)

; == =========================================================

(if (= @language "nederlands")
  (
    (set default-lang 64)
  )
)

; == =========================================================

(if (= @language "norsk")
  (
    (set default-lang 128)
  )
)

; == =========================================================

(if (= @language "português")
  (
    (set default-lang 256)
  )
)

; == =========================================================

(if (= @language "suomi")
  (
    (set default-lang 512)
  )
)

; == Swedish strings =========================================================

(if (= @language "svenska")
  (
    (set default-lang 1024)

    (set #bad-kick
      "Du måste använda Kickstart 2.04+ för att installera ClipHistory"
    )

    (set #install-msg
      (cat
        "\n\nVälkommen till Installeraren.\n\n"
        "Det här programmet låter dig installera ClipHistory i din "
        "Amiga.\n\n"
        "Se manualen för information om hur ClipHistory får "
        "distribueras."
      )
    )

    (set #welcome "Välkommen till installeraren för ClipHistory.")

    (set #copying "Kopierar ")

    (set #were-cliphistory "Var vill du placera ClipHistory?")

    (set #help-were-cliphistory
      (cat
        "  Om du placerar ClipHistory i Sys:WBStartup, så kommer programmet "
        "automatiskt att startas varje gång du startar din Amiga."
      )
    )

    (set #install-cliphistory-guide "Vill du installera ClipHistory.guide?")

    (set #were-cliphistory-guide "Var vill du placera ClipHistory.guide?")

    (set #help-were-cliphistory-guide
      (cat
        "  ClipHistory.guide är manualen till ClipHistory i AmigaGuides "
        "speciella hypertextformat. Du behöver ett program som AmigaGuide "
        "eller MultiView för att se den ordentligt."
      )
    )

    (set #install-cliphistory-man "Vill du installera ClipHistory.man?")

    (set #were-cliphistory-man "Var vill du placera ClipHistory.man?")

    (set #help-were-cliphistory-man
      (cat
        "  ClipHistory.man är manualen till ClipHistory i vanligt textformat, "
        "lämplig för vilket More-liknande program som helst. Har du redan "
        "installerat ClipHistory.guide så behöver du förmodligen inte "
        "installera den här filen."
      )
    )

    (set #which-language "\nVilka språk vill du installera?")

    (set #which-language-help
      (cat
        "  Amigan kan arbeta med flera olika språk. Om du vill att "
        "ClipHistory ska använda samma språk som Amiga Workbench så "
        "måste en så kallad katalogfil kopieras till din systemdisk "
        "för varje språk.\n"
        "  För att minimera diskutrymmet för språkfiler kan du välja "
        "att bara installera filerna för vissa språk.\n"
        "  Markera bara rutorna för de språk du önskar installera i "
        "din dator."
        "  Obs: Det finns inte språkfiler för alla visade språk."
      )
    )
  )
)

; ============================================================================

(set @default-dest "")

; Check Kickstart version. Exit if not at least 2.0

(if (< (/ (getversion) 65536) 37)
  (abort #bad-kick)
)

(message #install-msg)

(welcome)

; Copy ClipHistory

(set destination
  (askdir
    (prompt  #were-cliphistory)
    (help    (cat #help-were-cliphistory "\n\n" @askdir-help))
    (default "Sys:WBStartup")
  )
)

(copylib
  (prompt (cat #copying "ClipHistory..."))
  (source "/ClipHistory")
  (dest   destination)
  (infos)
)

(complete 25)

; Copy ReqChange.guide

(if
  (askbool
    (prompt (cat "\n" #install-cliphistory-guide))
    (help   #help-were-cliphistory-guide)
  )

  (
    (set destination
      (askdir
        (prompt  #were-cliphistory-guide)
        (help    (cat #help-were-cliphistory-guide "\n\n" @askdir-help))
        (default "Work:")
      )
    )

    (copyfiles
      (prompt (cat #copying "ClipHistory.guide..."))
      (source "/ClipHistory.guide")
      (dest   destination)
      (infos)
    )

    ; Modify tooltypes of ClipHistory.guide if this is needed

    (if (< (/ (getversion) 65536) 39)
      (tooltype
        (dest (tackon destination "ClipHistory.guide"))
        (setdefaulttool "AmigaGuide")
      )
    )
  )
)

(complete 50)

; Copy ReqChange.man

(if
  (askbool
    (prompt (cat "\n" #install-cliphistory-man))
    (help   #help-were-cliphistory-man)
  )

  (
    (set destination
      (askdir
        (prompt  #were-cliphistory-man)
        (help    (cat #help-were-cliphistory-man "\n\n" @askdir-help))
        (default "Work:")
      )
    )

    (copyfiles
      (prompt (cat #copying "ClipHistory.man..."))
      (source "/ClipHistory.man")
      (dest   destination)
      (infos)
    )
  )
)

(complete 75)

; Copy catalog files

(if (= (exists "Locale:") 2)
  (
    (set lang
      (askoptions
        (prompt #which-language)
        (help   (cat #which-language-help "\n\n" @askoptions-help))
        (choices
          "Dansk"
          "Deutch"
          "English"
          "Español"
          "Français"
          "Italiano"
          "Nederlands"
          "Norsk"
          "Português"
          "Suomi"
          "Svenska"
        )
        (default default-lang)
      )
    )


    (set n 0)

    (while
      (set language
        (select n
          "Dansk"
          "Deutch"
          "English"
          "Español"
          "Français"
          "Italiano"
          "Nederlands"
          "Norsk"
          "Português"
          "Suomi"
          "Svenska"
          ""
        )
      )

      (
        (if (IN lang n)
          (if (<> 2 n)   ; No catalog for english strings...
            (
              (set catalogs (tackon "/Catalogs" language))

              (set destination (tackon "Locale:Catalogs" language))

              (makedir destination)

              (if (exists (tackon catalogs "cliphistory.catalog"))
                (copylib
                  (source (tackon catalogs "cliphistory.catalog"))
                  (dest destination)
                )
              )
            )
          )
        )

        (set n (+ n 1))
      )
    )
  )
)

(complete 100)

; End of Installer script