(set
	sendTo
	(askdir
		(prompt 'What directory?')
		(default 'APPLICATIONS:GraphDQ')
		(newpath)
		(help "You should install GraphDQ as a subdirectory of some larger group of applications.  I put GraphDQ into my \"APPLICATIONS:\" directory.  However, you may not have an APPLICATIONS: directory, or want one, in which case you should tell Installer right here, right now where to put it.")
	)
)
 
(makedir
	sendTo
	(prompt 'Creating ' sendTo'...')
	(confirm)
	(infos)
	(help 'I have to make some sort of destination directory!')
)
 
(copyfiles
	(prompt 'Copying relevant files to ' sendTo)
	(source '')
	(help 'Copying!')
	(dest sendTo)
	(all)
	(files)
	(infos)
)
 
(set
	assignTo
	(askdir
		(prompt 'In order to print graphs, I need to know where the AmigaDOS tool GraphicDump is located.')
		(default 'SYS:Tools/')
		(newpath)
		(help "If you don't know where GraphicDump is located, check real quickly by looking in your directories.  Naturally, the first place to look is in \"SYS:Tools/\".  If you've deleted it, you'll need to recopy it from your original AmigaDOS diskettes.")
	)
)
 
(set
	startCom
	(cat
		'assign TOOLS: '
		assignTo
		' add'
	)
)
 
(startup
	'GraphDQ'
	(prompt 'Making necessary changes...')
	(help 'Making necessary changes to S:User-Startup file')
	(command startCom)
)
 
(exit
	'Installation of GraphDQ is done!'
)