;	HardNTSC 1.1  (15-Jun-93)
;
;	by Martin Berndt


	include	asm:system.gs

	move.l	$4.w,a6
	cmpi.w	#36,LIB_VERSION(a6)
	bcs.s	quit
	lea	GfxName(pc),a1
	bsr.s	findname
	beq.s	quit
	move.l	d0,a3
	lea	IntuiName(pc),a1
	bsr.s	findname
	beq.s	quit
	move.l	d0,a4
	jsr	_LVOForbid(a6)
	lea	gb_MonitorList(a3),a0
	lea	NTSCName(pc),a1
	jsr	_LVOFindName(a6)
	move.l	d0,gb_default_monitor(a3)
	move.b	#60,VBlankFrequency(a6)
	move.w	#NTSC|TODA_SAFE,gb_DisplayFlags(a3)
	move.w	#MSF_REQUEST_NTSC,gb_monitor_id(a3)
	move.w	#1280,gb_NormalDPMX(a3)
	move.w	#1098,gb_NormalDPMY(a3)
	exg	a4,a6
	subq.w	#ra_SIZEOF,sp
	move.l	#NTSC_MONITOR_ID|HIRES_KEY,a0
	move.l	sp,a1
	moveq	#OSCAN_TEXT,d0
	jsr	_LVOQueryOverscan(a6)
	move.w	ra_MaxX(sp),d0
	addq.w	#1,d0
	move.w	d0,gb_NormalDisplayColumns(a3)
	move.w	ra_MaxY(sp),d0
	addq.w	#1,d0
	move.w	d0,gb_NormalDisplayRows(a3)
	addq.w	#ra_SIZEOF,sp
	exg	a4,a6
	jsr	_LVOPermit(a6)
quit	moveq	#0,d0
	rts

findname	lea	LibList(a6),a0
	jsr	_LVOFindName(a6)
	tst.l	d0
	rts

GfxName	dc.b	"graphics.library",0
IntuiName	dc.b	"intuition.library",0
NTSCName	dc.b	"ntsc.monitor",0
Version	dc.b	0,"$VER: HardNTSC 1.1 (15.6.93)",0
	even

	end