; Install script for ReqTools (Workbench 2.1 or higher)

(set @default-dest "")
(set old_level @user-level)

(set reqtoolslib "//libs20/reqtools.library")
(set catalogdir "//Catalogs/")

;=============================================================================
; English strings

(set default_lang 2)

(set #bad-kick
(cat "You must be using Kickstart 2.04 to install using this script."
	  " Double-click the 'Workbench_1.2-1.3' icon to install ReqTools on"
	  " Kickstart 1.2 or 1.3 machines."
))

(set #copying-reqtools "Copying reqtools.library (2.0 version) to Libs:")

(set #which-language "Which languages should be installed?")
(set #which-language-help
(cat "\nThe Amiga can be operated in many different"
	  " languages. If you want ReqTools requesters to"
	  " use the same language as the Amiga Workbench"
	  " then a catalog file must be copied to your"
	  " system disk for each language supported.\n\n"
	  "To reduce the amount of space consumed by the"
	  " language files, you can select to have only the"
	  " files of specific languages copied.\n\n"
	  "Simply check the boxes of the languages you wish"
	  " to have available on your system.\n\n"
	  @askoptions-help
))

;=============================================================================
; Dutch strings

(if (= @language "nederlands")
(

(set default_lang 8)

(set #bad-kick
(cat "U moet Kickstart 2.04 gebruiken om met dit installatie script te"
	  " installeren. Dubbel-klik het 'Kick_1.2-1.3' ikoon om ReqTools"
	  " te installeren op Kickstart 1.2 of 1.3 machines."
))

(set #copying-reqtools "Ik kopieer reqtools.library (2.0 versie) naar Libs:")

(set #which-language
(cat "Welke talen moeten geïnstalleerd worden?"
))
(set #which-language-help
(cat "\nDe Amiga kan werken in verschillende talen."
	  " Als u wilt dat ReqTools in dezelfde taal werkt"
	  " dan moet er voor elke taal een bestand naar"
	  " uw systeem disk gekopieerd worden.\n\n"
	  "Om de groote van het geheugen die de taal bestanden"
	  " innemen te verkleinen, kunt u een keuze maken uit"
	  " de talen, die vervolgens naar uw systeem disk worden"
	  " gekopieerd .\n\nU hoeft alleen die talen die u op"
	  " uw systeem wilt hebben aan te klikken.\n\n"
     @askoptions-help
))

))

;=============================================================================
; French strings

(if (= @language "français")
(

(set default_lang 4)

; string needs to be changed!!!
(set #bad-kick
(cat "Il vous faut utiliser Kickstart 2.04 ..."
))

(set #copying-reqtools "Copie du fichier reqtools.library (version 2.0) vers Libs:")

(set #which-language
(cat "Quelles sont les langues à installer ?"
))

; string needs to be changed!!!
(set #which-language-help
(cat "\nL'Amiga peut fonctionner dans différentes langues. "
     "Plusieurs fichiers doivent être copiés sur le disque dur "
     "pour chaque langue utiliséee\n\n"
     "Pour réduire la quantité d'espace utilisé par ces fichiers, "
     "vous devez sélectionner seulement les langues qui vous seront "
     "utiles.\n\n"
     "Cochez les langues que vous souhaitez disponibles "
     "sur votre système\n\n"
     @askoptions-help
))

))

;=============================================================================
; German strings

(if (= @language "deutsch")
(

(set default_lang 1)

; string needs to be changed!!!
(set #bad-kick
(cat "Sie müssen Kickstart 2.04 zum Installieren ..."
))

(set #copying-reqtools "Kopieren Datei reqtools.library (2.0 Version) nach Libs:")

(set #which-language
(cat "Welche Sprachen sollen installiert werden?"
))

; string needs to be changed!!!
(set #which-language-help
(cat "\nDer Amiga kann in vielen verschiedenen Sprachen betrieben werden. "
     "Für jede verwendete Sprache müssen mehrere Dateien auf Ihre "
     "Festplatte kopiert werden.\n\n"
     "Um den Platz in Grenzen zu halten, den die Sprachentreiberdateien "
     "einnehmen, können Sie wählen, nur die Treiber für bestimmte "
     "Sprachen zu installieren.\n\n"
     "Klicken Sie einfach die Felder derjenigen Sprachen an, die Sie in "
     "Ihrem System verfügbar haben wollen, so daß diese Sprachen mit "
     "einem Häkchen markiert sind.\n\n"
     @askoptions-help
))

))

;=============================================================================
; make sure we are running under a 2.04 ROM

(if (< (/ (getversion) 65536) 37)
(
    (abort #bad-kick)
))

;=============================================================================

(copylib
	(prompt "\n" #copying-reqtools)
	(help @copylib-help)
	(source reqtoolslib)
	(dest "Libs:")
	(confirm)
)

(if (exists "SYS:Locale")
(
	(if (exists "LOCALE:")
	(
		(user 2)
		(set lang (askoptions (prompt #which-language)
									 (help #which-language-help)
									 (choices "Deutsch" "English" "Français" "Nederlands")
							       (default default_lang)
					 )
		)
		(user old_level)

		(set n 0)
		(while (set language (select n "deutsch" "english" "français" "nederlands" ""))
		(
			(if (IN lang n)
			(
				(if (<> 1 n)
				(
					(makedir (cat "LOCALE:Catalogs/" language))
					(copyfiles (source (cat catalogdir language))
								  (dest (cat "LOCALE:Catalogs/" language))
								  (all)
					)
				))
			))
			(set n (+ n 1))
		))
	))
))