; $VER: Installieren Deutsch 1.0 (11.4.92)

	(complete 0)
	(welcome)

; Zuerst wird nach dem Zielverzeichnis für das Hauptprogramm gefragt
; Standardvorgabe ist `Work:term'.

	(set Hauptprogramm_Ziel "Work:term")

	(set Hauptprogramm_Ziel
		(askdir
			(prompt	"Bitte wählen Sie die Schublade aus,"
				"in der das `term' Hauptprogramm "
				"installiert werden soll!" )

			(help @askdir-help)
			(default Hauptprogramm_Ziel)
		)
	)

; Jetzt wird die Datei kopiert...

	(copyfiles
		(dest Hauptprogramm_Ziel)

		(source "term")

		(infos)
	)

	(complete 10)

; Nun zu den Dokumentationsdateien.

	(if
		(askbool
			(prompt "Möchten Sie die Programmdokumentation "
				"installieren?"
			)

			(help	"Die Programmdokumentation beschreibt die "
				"einzelnen Funktionen des Hauptprogrammes "
				"und der ARexx-Schnittstelle. Da die Daten "
				"in gepacktem Zustand vorliegen, wird der "
				"Installationsvorgang etwas Zeit benötigen. "
				@askbool_help
			)

			(default 1)
		)
		(
			(run (":C/Unpack term.dok %s" (tackon Hauptprogramm_Ziel "term.dok")))

			(complete 20)

			(run (":C/Unpack termRexx.dok %s" (tackon Hauptprogramm_Ziel "termRexx.dok")))

			(complete 30)

			(run ("Copy #?.dok.info %s" Hauptprogramm_Ziel))

			(complete 40)
		)
	)

; Fonts sollen installiert werden

	(if
		(askbool
			(prompt "Sollen die von `term' benötigten speziellen "
				"Zeichensätze installiert werden?"
			)

			(help	"`term' benötigt um verschiedene Terminal"
				"emulationen zu unterstützen, zwei spezielle "
				"Zeichensätze: einen Graphikzeichensatz und "
				"einen `IBM-PC' Zeichensatz."
				@askbool_help)

			(default 1)
		)
		(
			(run ("Copy Fonts Fonts: All Quiet"))

			(complete 50)
		)
	)

; Nun zum Kopieren der vorhandenen xpr-Libraries.

	(if
		(askbool
			(prompt "Möchten Sie die für Datentransfer benötigten "
				"XPR-Bibliotheken installieren?"
			)

			(help	"Die XPR-Bibliotheken haben die Aufgabe, "
				"Daten nach bestimmten Protokollen zu "
				"übertragen. Ohne diese Bibliotheken wird "
				"`term' in seiner Leistungsfähigkeit "
				"stark eingeschränkt."
				@askbool_help)

			(default 1)
		)
		(
			(run ("Copy XPR_Libs/#?.library Libs: All Quiet"))

			(complete 60)
		)
	)

; Sollen auch die dazugehörigen Dokumentationsdateien kopiert werden?

	(if
		(askbool
			(prompt "Sollen die zu den XPR-Bibliotheken gehörenden "
				"Dokumentationsdateien installiert werden?"
			)

			(help	"Die Dokumentationsdateien zu den Bibliotheken "
				"informieren über Aufrufparameter und von den "
				"Bibliotheken zur Verfügung gestellte Funktionen. "
				@askbool_help)

			(default 1)
		)
		(
			(run ("Copy XPR_Libs/#?.do#? %s All Quiet" Hauptprogramm_Ziel))

			(complete 70)
		)
	)

; Nun zu den Bildschirmemulationslibraries.

	(if
		(askbool
			(prompt "`term' unterstützt die Verwendung externer "
				"Terminalemulations-Bibliotheken. Sie sind "
				"für das korrekte Funktionieren des Programmes "
				"nicht zwingend notwendig, stellen aber eine "
				"sinnvolle Erweiterung dar. "
				"Möchten Sie die Terminalemulations-Bibliotheken "
				"installieren?"
			)

			(help	"Die Terminalemulationsbibliotheken können "
				"optional anstatt der eigebauten Routinen "
				"verwendet werden. Sie werden aber nicht unbedingt "
				"benötigt."
				@askbool_help)

			(default 1)
		)
		(
			(run ("Copy XEM_Libs/#?.library Libs: All Quiet"))

			(copyfiles
				(source "XEM_Libs/Env")

				(dest "ENV:")

				(all)
			)

			(copyfiles
				(source "XEM_Libs/Env")

				(dest "ENVARC:")

				(all)
			)

			(complete 80)
		)
	)

; Zuletzt werden noch die optionalen Bibliotheken kopiert.

	(if
		(askbool
			(prompt "`term' macht, falls vorhanden, Gebrauch von "
				"einer Bibliothek, die das Konkurrieren von "
				"mehreren Programmen um die serielle Schnittste"
				"regelt. Soll diese Bibliothek "
				"installiert werden?"
			)

			(help	"Die hier zu installierende Bibliothek ist "
				"für den Einsatz zusammen mit anderen Programmen "
				"gedacht, die die serielle Schnittstelle ebenfalls "
				"benötigen. Die Bibliothek regelt den konkurrierenden "
				"Zugriff auf die Schnittstelle, wird aber nicht "
				"unbedingt benötigt."
				@askbool_help)

			(default 1)
		)
		(
			(copyfiles
				(source "Extra_Libs/OwnDevUnit.library")

				(dest "Libs:")

				(files)
			)

			(complete 90)
		)
	)

	(complete 100)

	(set @default_dest Hauptprogramm_Ziel)
	(exit)