;****************************

(set #sub-dir "data")		;sub directory containing data files
(set #readme-file "README")	;name of readme file
(set #cleanup "install.slave")	;files to delete after install
(set #last-file "data/70")	;last file whdload should create

;****************************

;----------------------------
; Checks if given program is reachable via the path
; if not abort install
; IN:  #program - to check
; OUT: -

(procedure P_chkrun
  (if
    (= 0 (run ("cd SYS:\nWhich %s" #program)))
    ("")
    (abort ("You must install \"%s\" first !\nIt must be accessible via the path.\nYou can find it in the whdload package." #program))
  )
)

;****************************

(if
  (exists #readme-file)
  (if
    (= 0 (run ("SYS:Utilities/Multiview %s" #readme-file)))
    ("")
    (run ("SYS:Utilities/More %s" #readme-file))
  )
)

(set #program "WHDLoad")
(P_chkrun)

(set @default-dest
  (askdir
    (prompt ("Where should \"%s\" installed ?\nA drawer \"%s\" will automatically created." @app-name @app-name))
    (help @askdir-help)
    (default "RAM:")
    (disk)
  )
)
(set #dest (tackon @default-dest @app-name))
(if
  (exists #dest)
  (
    (set #choice
      (askbool
        (prompt ("\nDirectory \"%s\" already exists.\n Should it be deleted ?" #dest))
        (default 1)
        (choices "Delete" "Skip")
        (help @askbool-help)
      )
    )
    (if
      (= #choice 1)
      (run ("Delete \"%s\" \"%s.info\" All" #dest #dest))
    )
  )
)
(makedir #dest
  (help @makedir-help)
  (infos)
)

;----------------------------

(makedir 
  (tackon #dest "data")
  (help @makedir-help)
)

(copyfiles
  (help @copyfiles-help)
  (source ("%s.slave" @app-name))
  (dest #dest)
)
(copyfiles
  (help @copyfiles-help)
  (source "install.slave")
  (dest #dest)
)
(copyfiles
  (help @copyfiles-help)
  (source ("%s.inf" @app-name ))
  (newname ("%s.info" @app-name ))
  (dest #dest)
)
(if
  (exists #readme-file)
  (copyfiles
    (help @copyfiles-help)
    (source #readme-file)
    (dest #dest)
  )
)
(if
  (= #sub-dir "")
  ("")
  (
    (makedir #dest
      (help @makedir-help)
    )
  )
)

(run ("cd \"%s\"\nwhdload install.slave WriteDelay=50" #dest))

(if
  (exists (tackon #dest #last-file))
  ("")
  (abort "The Install was unable to create all nesseccary files !")
)

;----------------------------

(run ("cd %s\nDelete %s ALL QUIET FORCE" #dest #cleanup))

(exit)