; This is test of many of the features of the Installer
; Prints out debugging info if run from CLI

(complete 0)

(set InstallDir
	(askdir
		(prompt "Where do you want to install SerTrans?\nA Directory named SerTrans will created there")
		(help @askdir-help)
		(default "SYS:")
	)
)

(complete 10)

(Set DestDir
	(tackon InstallDir "SerTrans")
)

(complete 20)

(Set ExtraDir
	(tackon DestDir "Extras")
)

(complete 30)

(Set LocaleDir
	(tackon DestDir "Locale")
)

(complete 40)

(makedir
	DestDir
	(infos)
)

(complete 50)

(if
	(askbool
		(prompt	"Do you want to install the Extras?")
		(help	"Extras Are: Extra Icons and the Connect Program")
	)
	(
		(makedir
		ExtraDir
		(infos)
		)

(complete 60)

		(copyfiles
		(source "Extras")
		(dest ExtraDir)
		(all)
		(infos)
		(noposition)
		)
	)
)

(complete 70)

(copyfiles
	(source "")
	(dest DestDir)
	(pattern "~(Install|Catalogs|Libs|Extras|Docs|Fonts)#?")
	(infos)
	(noposition)
)

(complete 80)

(copylib
	(prompt "Copying SerTrans.Library to LIBS:")
	(help "Copy's the SerTrans.Library to LIBS:")
	(source "Libs/sertrans.library")
	(dest "LIBS:")
	(confirm)
)

(complete 90)

(copyfiles
	(prompt "Copying catalog files")
	(help @copyfiles-help)
	(source "Catalogs")
	(dest "LOCALE:Catalogs")
	(confirm)
	(choices "english" "deutsch")
)

(complete 100)