; $VER: zmime.install 1.0 (24.1.96) by Ralph Seichter

(if (= @language "deutsch")
	(
		(set #select-destdir-prompt
			(cat
				"Bitte wählen Sie das Verzeichnis, in dem " @app-name
				" installiert werden soll (Hilfstext beachten)."
			)
		)

		(set #select-destdir-help
			(cat
				"Geben Sie bitte den vollständigen Pfad an. In diesem "
				"Verzeichnis werden später die Verzeichnisse 'Rexx' und "
				"'Catalogs' erzeugt, falls sie das komplette " @app-name
				"-Paket installieren möchten."
			)
		)

		(set #select-install-files-prompt
			(cat
				"Bitte wählen Sie alle Teile des " @app-name "-Pakets, die "
				"installiert werden sollen."
			)
		)

		(set #sample-config "Beispiel-Konfigurationsdatei")

		(set #arexx-scripts "ARexx-Skripten")

		(set #german-catalog "Deutschsprachige Katalog-Datei")

		(set options-mask -1)
	)
)

(if (= @language "english")
	(
		(set #select-destdir-prompt
			(cat
				"Please select the directory in which " @app-name " shall be "
				"installed (see help text)."
			)
		)

		(set #select-destdir-help
			(cat
				"Please specify the full destination path name. In this directory, "
				"the subdirectories 'Rexx' and 'Catalogs' will be created, if you "
				"choose to install the complete " @app-name " package."
			)
		)

		(set #select-install-files-prompt
			(cat
				"Please select all the parts of the " @app-name " package you wish "
				"to have installed."
			)
		)

		(set #sample-config "Configuration example")

		(set #arexx-scripts "ARexx scripts")

		(set #german-catalog "German catalog file")

		(set options-mask 15)
	)
)

(set @default-dest
	(askdir
		(prompt #select-destdir-prompt)
		(help #select-destdir-help)
		(default "SYS:Tools")
	)
)

(set bitmask
	(askoptions
		(prompt #select-install-files-prompt)
		(help @askoptions-help)
		(choices
			@app-name
			(cat @app-name ".guide")
			#sample-config
			#arexx-scripts
			#german-catalog
		)
		(default options-mask)
	)
)

(if (in bitmask 0)
	(copyfiles
		(dest @default-dest)
		(source @app-name)
		(infos)
	)
)

(if (in bitmask 1)
	(copyfiles
		(dest @default-dest)
		(source (cat @app-name ".guide"))
		(infos)
	)
)

(if (in bitmask 2)
	(copyfiles
		(dest @default-dest)
		(source (cat @app-name ".config"))
		(infos)
	)
)

(if (in bitmask 3)
	(
		(set name (tackon @default-dest "Rexx"))
		(makedir name)
		(copyfiles
			(dest name)
			(source "Rexx")
			(all)
		)
	)
)

(if (in bitmask 4)
	(
		(set name (tackon @default-dest "Catalogs"))
		(makedir name)
		(set name (tackon name "deutsch"))
		(makedir name)
		(copyfiles
			(dest name)
			(source (cat "Catalogs/deutsch/" @app-name ".catalog"))
		)
	)
)

; EOF