/* Programme Rexx pour DB qui joue votre chanson favoris du CD choisit.
 *
 * Il nécessite le démon InfraRexx pour tourner
 *
 * Anders Callertun 1994
 * 1994-11-13 Première version
 * 1994-11-15 Quelques messages d'erreurs rajoutés.
 * 1994-11-19 Fait une version anglaise/suédoise.
 * 1995-10-09 Version française
 */

options results

lang = GetLang()

if ~show(p,infrarexx) then do
 interpret OKAY1 sourceline(lang+1)
 exit
end

GETFIELD 'group'
group = result
GETFIELD 'title'
title = result
GETFIELD 'number'
number = result

current_cd = '"'title'"' sourceline(lang+4) group

if getclip('current_cd')=='' then do
 interpret OKAY2 sourceline(lang+2)
 if result = 1 then do
  call setclip('current_cd',current_cd)
 end
 else call setclip('current_cd',sourceline(lang+5))
end

if getclip('current_cd') ~= current_cd then do
 address infrarexx 'CD_OPEN_CLOSE'
 interpret OKAY2 sourceline(lang+3)
 if result = 0 then exit
end

call setclip('current_cd',current_cd)

do while number>10      /* C'est comment vous choisissez un morceau >10 */
 address infrarexx 'CD_PLUS_10' /* sur un lecteur de CD de JVC. */
 number = number-10     /* Vous pouvez changer ceci */
end           /* pour votre lecteur de CD. */

address infrarexx 'CD_'number
address infrarexx 'CD_PLAY'   /* Inutile avec JVC. */

exit

GetLang:
 if open(lang_file,'ENV:language',r) then do
  language = readln(lang_file)
  call close(lang_file)
  select
   when language = 'svenska' then return sourceline()-2*6
   when language = 'français' then return sourceline()-3*6
/* Si vous ajouter votre propre langage, vous devez aussi ajouter un autre 'when' :
   when language = '<language>' then return sourceline()-3*6
*/   otherwise ;
  end
 end

 return sourceline()-1*6
end

/*
Ici vous mettrez votre propre langage. Si vous le faite, envoyez moi une copy
uuencodé de votre fichier à d91-aca@nada.kth.se, pour l'inclure dans la prochaine
distribution de DB.

'InfraRexxDaemon körs inte!'||'0a0a'x || 'Om du inte vet vad InfraRexx är, läs filen'||'a'x || '"About the examples" för att få reda på mer.'
'Har du'||'a'x || current_cd || 'a'x 'i din CD spelare nu?'
'Byt ut' || 'a'x || getclip('current_cd') || 'a'x || 'mot' || 'a'x || current_cd'!'
av
den okända CDn

'The InfraRexxDaemon is not running!'||'0a0a'x || 'If you don''t know what InfraRexx is, please read the file'||'a'x ||'"About the examples" to find out more.'
'Do you have'||'a'x || current_cd || 'a'x 'in your CD player now?'
'Please replace' || 'a'x || getclip('current_cd') || 'a'x || 'with' || 'a'x || current_cd'!'
by
the unknown CD

'Le démon InfraRexx ne tourne pas!'||'0a0a'x || 'Si vous ne savez pas ce qu'est InfraRexx, lisez le fichier'||'a'x ||'"A Propos des Exemples" pour en savoir plus.'
'Avez vous'||'a'x || current_cd || 'a'x 'dans votre lecteur de CD?'
'Remplacez' || 'a'x || getclip('current_cd') || 'a'x || 'avec' || 'a'x || current_cd'!'
avec
Le CD inconnu
*/