****************************************************************************
*                                                                           *
* 		   ARENA LOADER-1 CODED BY MELT DOWN/ARENA 		    *
*                                                                           *
*****************************************************************************

; Include the macros

	Incdir	Df1:
	Include	Source/Macro

*****************************************************************************

; Dont forget to use chip ram

	Chip

SINEPLANE	=	$7d000
ROTATEDPNTS	=	$7e000
X1INC		=	-4
X1ADD		=	2

X2INC		=	3
X2ADD		=	2

MENUSCREEN	=	$60118
MENUSCREEN1	=	$606b8
SCROLLSPEED	=	1
AMTEXT		=	14			; 14 Max Text
AMFILES		=	9			; AMOUNT OF FILES
UPARROW		=	$67
DOWNARROW	=	$65
RETURN		=	$77
FILECNT		=	$80

*****************************************************************************

; Kill the operating system for good mesure

	Clr.l	FileCnt
	Move.l	4,A6
	Jsr	-132(A6)
	Move.l	(a6),A6
	Move.l	(a6),A6
	Move.l	38(a6),OldCopper
	
*****************************************************************************

; Init Logo Bitmaps

	Move.l	#Logo,D0
	PlaneOn	D0,Log1l+2,Log1h+2
	Add.l	#35*40,D0
	PlaneOn	D0,Log2l+2,Log2h+2

*****************************************************************************

; Clear Some memory

	Lea	$70000,A1
	Move.l	#$f000/4,d0
Clr
	Clr.l	(a1)+
	Dbf	D0,Clr
	
	Lea	$60000,A1
	Move.l	#$f000/4,d0
Clr1
	Clr.l	(a1)+
	Dbf	D0,Clr1

	Bsr	Bpinit
		
*****************************************************************************

; Load custom and set up copper list

	Lea	Custom,A5
	Move.l	#Copper,Cop1lch(a5)
	Bsr	PrintMainMenu

*****************************************************************************

; Main routine here

Mouse
	Cmp.b	#$77,$dff006
	Bne	Mouse
	
	Rept	ScrollSpeed
	Bsr	Scrolly
	Endr
	Bsr	DoSine

	Bsr	DBuff				; Need To Buffer
	Bsr	Clear				; Clear The Shit
	Bsr	Rotate				; Rotate
	Bsr	DoConects			; Draw Lines
	Bsr	Fill				; Filleto Fish
	Bsr	Rm
	Bsr	CheckArrow
	Bsr	UpDateCopper
	Add.w	#2,Xrotation
	And.w	#510,Xrotation
	SaveAll
	Bsr	Bpmusic
	LoadAll
	Btst	#$6,$bfe001
	Beq.s	Leave
	Cmp.b	#return,$bfec01
	Bne.s	Mouse

*****************************************************************************

; Return operating system and go back to user
Leave
	Move.l	OldCopper,$dff080
	Move.l	4,a6
	Jsr	-138(A6)
 	clr.w	$dff0a8
	clr.w	$dff0b8
	clr.w	$dff0c8
	clr.w	$dff0d8
	move.w	#$f,$dff096
	Clr.l	D0				; No error
	Rts
	
*****************************************************************************

	Include	Source/SndMon.s
	
*****************************************************************************

OldCopper
	Dc.l	0
	
*****************************************************************************

UpDateCopper
	Move.l	FileCnt,D0
	Mulu	#8,D0
	Add.l	#142,D0
	Move.b	d0,Sell
	Add.b	#8,D0
	Move.b	d0,Selh
	Rts
	
*****************************************************************************

CheckArrow
	Cmp.b	#DownArrow,$bfec01
	Bne.s	NoUpAr
	Cmp.l	#AmFiles-1,FileCnt
	Beq.s	NoAdd1
	Add.l	#1,FileCnt			; Set To Inc
	Clr.b	$bfec01
NoAdd1
	Rts
NoUpAr
	Cmp.b	#UpArrow,$bfec01
	Bne.s	NoDownAr
	Tst.l	FileCnt
	Beq.s	NoDownAr
	Sub.l	#1,FileCnt			; Set To Down
	Clr.b	$bfec01
NoDownAr
	Rts
	
*****************************************************************************

; Read the mouse

RM 
	Move.b	$dff00a,D0
	Cmp.b	OldMs,D0
	Bgt	AddMs
	Blt	SubMs
	Rts
AddMs
	Move.b	d0,OldMs
	Cmp.l	#AmFiles-1,FileCnt
	Beq.s	SkipAdd
	Add.l	#1,FileCnt
SkipAdd
	Rts
SubMs
	Move.b	d0,OldMs
	Tst.l	FileCnt
	Beq.s	SkipSub
	Sub.l	#1,FileCnt
SkipSub
	Rts
	
OldMs
	Dc.l	0
*****************************************************************************

; Print Menu

PrintMainMenu
	Lea	TitleText,A0
	Lea	MenuScreen,A1
	Move.l	#(4*40)-1,D0			; Amount Of Chars
	Bsr	PrintShit
	Lea	MenuText,A0
	Lea	MenuScreen1,A1
	Move.l	#(AmText*40)-1,D0		; Amount Of Chars
	Bsr	PrintShit
	Rts

PrintShit
	Clr.l	D7
Print
	Clr.l	D1
	Move.b	(a0)+,D1
	Sub.b	#32,D1
	Divu	#40,D1				; Divide by Chars
	Swap	D1
	Move.w	d1,-(a7)
	Swap	D1
	Mulu	#8*40,D1			; Length of fnt*8
	Add.w	(a7)+,D1
	Add.l	#Font,D1			; Get to Char
	
	Movem.l	d0-d7/a0-a6,-(a7)
	Move.l	D1,A0
	Rept	8
	Move.b	(a0),(a1)
	Add.w	#40,A0
	Add.w	#40,A1
	Endr
	Movem.l	(a7)+,d0-d7/a0-a6
	Add.w	#1,a1
	Add.w	#1,D7
	Cmp.w	#40,D7
	Bne	NoResetCords
	Clr.l	D7
	Sub.l	#40,A1
	Add.l	#40*8,A1
NoResetCords
	Dbf	d0,Print
	Rts

*****************************************************************************

Scrolly
	Cmp.l	#0,Scrolled
	Bgt	ShiftScroll
	Move.l	#8,Scrolled
	Clr.l	D1
	Move.l	ScrollPtr,A0
	Move.b	(a0)+,D1
	Cmp.b	#$ff,D1
	Bne	NoScroll
	Move.l	#ScrollMes,A0
	Move.b	(A0)+,d1
NoScroll
	Move.l	A0,ScrollPtr
	Sub.b	#32,D1
	Divu	#40,D1				; Divide by Chars
	Swap	D1
	Move.w	d1,-(a7)
	Swap	D1
	Mulu	#8*40,D1			; Length of fnt*8
	Add.w	(a7)+,D1
	Add.l	#Font,D1			; Get to Char
	Lea	ScrollerSpace+45,A1
	Move.l	D1,A0
	Rept	8
	Move.b	(a0),(a1)
	Add.w	#40,A0
	Add.w	#46,A1
	Endr
	Blitwait
	Move.l	#ScrollerSpace,Bltapth(a5)
	Move.l	#ScrollerSpace-2,Bltdpth(a5)
	Move.l	#$89f00000,Bltcon0(A5)
	Move.w	#0,Bltamod(a5)
	Move.w	#0,Bltdmod(a5)
	Move.l	#-1,Bltafwm(a5)
	Move.w	#9*64+23,Bltsize(a5)
	Move.w	#$00fc,Smth+2
ShiftScroll
	Sub.l	#1,Scrolled
	Sub.w	#$0011,Smth+2
	Rts
Scrolled
	Dc.l	0
ScrollPtr            
	Dc.l	ScrollMes
ScrollMes
	Include	loader/Scrolltext.BAK
	Dc.b	255
	Even

*****************************************************************************

DoSine
	Blitwait
	Move.l	#Sineplane,Bltdpth(a5)
	Move.w	#0000,Bltdmod(a5)
	Move.l	#$01000000,Bltcon0(a5)
	Move.l	#-1,Bltafwm(a5)
	Move.w	#48*64+23,Bltsize(a5)
	Blitwait
	Move.w	#44,bltamod(a5)
	Move.w	#44,bltcmod(a5)
	Move.w	#44,bltdmod(a5)
	Move.l	#$0bfa0000,Bltcon0(a5)
	Move.l	#-1,Bltafwm(a5)
	Add.w	#X1inc,Sin1ptr
	And.w	#$7e,Sin1ptr
	Add.w	#X2inc,Sin2ptr
	And.w	#$7e,Sin2ptr
	
	Lea	Sin1(pc),a0
	Add.w	Sin1ptr,a0			; A0 Holds Current Sin Pos
	Lea	Sin1(pc),a1
	Add.w	Sin2ptr,a1			; A1 Holds Current Sin Pos

	Move.l	#ScrollerSpace,d0		; Scroler In Memory
	Move.l	#SinePlane,d1			; Sine Dest
	Move.l	#X1add,d2			; Add to sine
	Move.l	#X2add,d3			; Add to sine
	Move.w	#8*64+1,D4			; Size
Blitmac	Macro
	Add.w	(a0),d1
	Add.w	(a1),d1
	Move.l	d0,Bltapth(a5)
	Move.l	d1,Bltcpth(a5)
	Move.l	d1,Bltdpth(a5)
	Move.w	#\1,Bltafwm(a5)
	Move.w	d4,Bltsize(a5)
	Sub.w	(a0),d1
	Sub.w	(a1),d1
	Add.w	D2,A0
	Add.w	D3,A1
	Endm
	Rept	23
	Blitmac	%1111111100000000
	Blitmac	%0000000011111111
	Add.w	#2,d0
	Add.w	#2,d1
	Endr
	Rts
	
*****************************************************************************

Sin1ptr
	Dc.w	0
Sin2ptr
	Dc.w	90
Sin1	
	Rept	5
	dc.w	20*46,20*46,20*46,20*46,19*46,19*46,18*46,18*46
	dc.w	17*46,16*46,16*46,15*46,14*46,13*46,12*46,11*46
	dc.w	10*46,9*46,8*46,7*46,6*46,5*46,4*46,4*46
	dc.w	3*46,2*46,2*46,1*46,1*46,0*46,0*46,0*46
	dc.w	0*46,0*46,0*46,0*46,1*46,1*46,2*46,2*46
	dc.w	3*46,4*46,4*46,5*46,6*46,7*46,8*46,9*46
	dc.w	10*46,11*46,12*46,13*46,14*46,15*46,16*46,16*46
	dc.w	17*46,18*46,18*46,19*46,19*46,20*46,20*46,20*46
	Endr

*****************************************************************************

Font
	Incbin	Gfx/R-8x8.bm
	
*****************************************************************************

Dbuff
	Eor.w	#$3000,Buff			; Change Buffer
	Eor.w	#$3000,Bit1l+2			; Change Bitmap Ptr
	Rts
	
*****************************************************************************

Fill
	Blitwait
	Add.l	#10240-2,A0			; Plane Size -2
						; Now At Bottom Of Screen
	Move.l	#$09f0000a,Bltcon0(a5)		; D=A Desending And Fill
	Move.l	#$ffffffff,bltafwm(a5)		; Use All Bits And Why Not
	Move.l	a0,bltapth(a5)			; Set Ketchup
	Move.l	a0,bltdpth(a5)			; Set THE IN PLACE
	Move.w	#0,Bltamod(a5)			; Dont Skip 
	Move.w	#0,Bltdmod(a5)			; To My Loop
	Move.w	#255*64+20,bltsize(a5)		; Do The Full Screen
	Rts

*****************************************************************************

Clear
	Blitwait				; Blitter Nasty But Why Do
						; I Have To Wait????
	Move.l	#$01000000,Bltcon0(a5)		; Clear
	Move.w	#$0000,Bltdmod(a5)		; Skip No Bytes
	Move.l	#$70000,a1			; Base Of Screen
	Add.w	Buff,A1				; Add Base Ptr 
	Move.l	a1,Bltdpth(A5)			; Set Dest
	Move.l	#-1,Bltafwm(a5)			; Use All Bits
	Move.w	#80*64+20,Bltsize(a5)		; Fill Half Screen
	Movem.l	a0-a6/d0-d7,-(a7)		; Save The Regs
	Movem.l	RegFiller(pc),a1-a6/d0-d7	; Clear The Regs
	Move.l	#$70000,a0			; Pntr To Screen
	Add.w	Buff,A0				; Add Base Ptr
	Add.l	#6400,a0			; Bttm Of Screen
	Rept	58				; Rept it 58 times
; 3200/56 = 57.14 Rnd Up = 58
	Movem.l	a1-a6/d0-d7,-(a0)		; Clear 56 Butes
	Endr					; End repeat
	Movem.l	(a7)+,a0-a6/d0-d7		; Restor Regs
	Rts
RegFiller
	Dcb.l	16,0
	Rts

*****************************************************************************

SinCalc	Macro
	move.w	d0,d2				; Store The X
	move.w	d1,d3				; Store The Y
	move	64(a2,d6),d4			; Get Cosine Of Angle X
	move	-64(a2,d6),d5			; Get Sine Of Angle X
	muls	d4,d0				; X cos (a)
	muls	d5,d1				; Y sin (a)
	sub.l	d1,d0				; X cos (a) - y sin (a)
	add.l	d0,d0				; Double it
	swap	d0				; swap it ( divu 65536 )
	muls	d5,d2				; X sin (a)
	muls	d4,d3				; Y cos (a)
	add.l	d2,d3				; y cos (a) + x sin (a)
	add.l	d3,d3				; double it
	swap	d3				; swap it ( divu 65536 )
	Endm

Rotate
	Lea	RotatedPnts,A0			; Dest For Points
	Lea	StablePnts,A1			; Get Points 
	lea	VecSin+64,a2			; Get Sine
	Move.w	(a1)+,d7			; Number Of Points
Calculate
	move.w	(a1)+,d0			; Get X
	move.w	(a1)+,d1			; Get Y
	move.w	ZRotation,d6			; rotation
; X1 = X COS(A)-Y SIN(A)
; Y1 = Y COS(A)+X SIN(A)
	SinCalc
	Move.w	D0,X1Space			; Store X
	Move.w	D3,D0				; D0=Y
	Move.w	(a1)+,D1			; D1=Z
	move.w	YRotation,d6			; rotation
; Y2 = Y1 COS(B)-Z SIN(B)
; Z1 = Z  COS(B)+Y1 SIN(B)
	SinCalc	
	Move.w	D0,Y2Space			; Store Y
	Move.w	D3,D0				; Shift Z
	Move.w	X1Space,D1			; Get X
	Move.w	XRotation,D6
; X2 = Z1 COS(C)-X1 SIN(C)
; Z2 = X1  COS(C)+Z1 SIN(C)
	SinCalc	
	Move.w	Y2Space,D1

	Add.w	#160,D0
	Add.w	#75,D1
	Move.w	d0,(a0)+
	Move.w	d1,(a0)+
	Dbf	D7,Calculate
	Rts

*****************************************************************************

DoConects
	Move.w	#40,$60(a5)			; Screen In Bytes
	Move.l	#-$8000,$72(a5)			; Set to line ??????
	Move.l	#-1,$44(a5)			; The Mask
	Lea	RotatedPnts,A3			; Pointer To Points
	Lea	ConectPnts,A4			; Pointer To Connects
	Move.w	(a4)+,D7			; Number Of Connects
	Lea	$70000,A0			; Pnt to screen
	Add.w	Buff,A0				; Add buff
	Move.l	#40,D5				; 40 Bytes accross
DrawLoop
	Move.w	(a4)+,d4			; Conect These
	Move.w	(a3,d4),D0			; Get X
	Move.w	2(a3,d4),D1			; Get Y
	Move.w	(a4)+,d4			; Conect These
	Move.w	(a3,d4),D2			; Get X1
	Move.w	2(a3,d4),D3			; Get Y1
	Movem.l	a0/d5,-(A7)

;		  LINEDRAW ROUTINE FOR USE WITH FILLING:
; Preload:  d0=X1  d1=Y1  d2=X2  d3=Y2  d5=Screenwidth  a0=address  a5=$dff000 
; $dff060=Screenwidth (word)  $dff072=-$8000 (longword)  $dff044=-1 (longword)

	cmp.w	d1,d3
	bgt.s	line1
	exg	d0,d2
	exg	d1,d3
	beq.s	out
line1:	move.w	d1,d4
	muls	d5,d4
	move.w	d0,d5
	add.l	a0,d4
	asr.w	#3,d5
	add.w	d5,d4
	moveq	#0,d5
	sub.w	d1,d3
	sub.w	d0,d2
	bpl.s	line2
	moveq	#1,d5
	neg.w	d2
line2:	move.w	d3,d1
	add.w	d1,d1
	cmp.w	d2,d1
	dbhi	d3,line3
line3:	move.w	d3,d1
	sub.w	d2,d1
	bpl.s	line4
	exg	d2,d3
line4:	addx.w	d5,d5
	add.w	d2,d2
	move.w	d2,d1
	sub.w	d3,d2
	addx.w	d5,d5
	and.w	#15,d0
	ror.w	#4,d0
	or.w	#$a4a,d0
waitblt:btst	#6,2(a5)
	bne.s	waitblt
	move.w	d2,$52(a5)
	sub.w	d3,d2
	lsl.w	#6,d3
	addq.w	#2,d3
	move.w	d0,$40(a5)
	move.b	oct(PC,d5.w),$43(a5)
	move.l	d4,$48(a5)
	move.l	d4,$54(a5)
	movem.w	d1/d2,$62(a5)
	move.w	d3,$58(a5)
out:	
	Movem.l	(A7)+,a0/d5
	Dbf	D7,DrawLoop
	Rts
	
*****************************************************************************

oct:	dc.l	$3431353,$b4b1757   

*****************************************************************************

; Varibles For Vector Routine

VecSin	Incbin	Binary/Sin
	Incbin	Binary/Sin
Y2Space	Dc.w	0
X1Space	Dc.w	0
Xrotation
	Dc.w	000
YRotation
	Dc.w	0
ZRotation
	Dc.w	00
Buff
	Dc.w	$0000
XY	Macro
	Dc.w	(\1/8)*6,\2,0
	Endm
Conect	Macro
	Dc.w	\1*4,\2*4
	Endm
StablePnts
	Dc.w	46-1				; Number of points
	XY	-200,50
	XY	-150,-50
	XY	-70,-50
	XY	-50,-30
	XY	-50,-10
	XY	-70,10
	XY	-30,50
	XY	-60,50
	XY	-90,20
	XY	-90,50
	XY	-110,70
	XY	-110,-10
	XY	-70,-10
	XY	-70,-30
	XY	-120,-30
	XY	-120,50

	XY	-170,30
	XY	-140,30
	XY	-140,-30

	XY	-60,-50
	XY	20,-50
	XY	20,-30
	XY	-40,-30
		
	XY	-40,-10
	XY	10,-10
	XY	10,10
	XY	-20,10
	XY	-20,20
	XY	-10,30
	XY	30,30
	XY	30,-50
	XY	90,10
	XY	90,-70
	XY	110,-50
	XY	110,50
	XY	50,-10
	XY	50,50
	XY	-20,50
	XY	-40,30
	
	XY	120,-50
	XY	150,-50
	XY	200,50
	XY	120,50
	
	XY	140,30
	XY	170,30
	XY	140,-30
ConectPnts			
	Dc.w	46-1				; Number of connects		
	Conect	0,1
	Conect	1,2
	Conect	2,3
	Conect	3,4
	Conect	4,5
	Conect	5,6
	Conect	6,7
	Conect	7,8
	Conect	8,9
	Conect	9,10
	Conect	10,11
	Conect	11,12
	Conect	12,13
	Conect	13,14
	Conect	14,15
	Conect	15,0
	
	Conect	16,17
	Conect	17,18
	Conect	18,16
	
	Conect	19,20
	Conect	20,21
	Conect	21,22
	Conect	22,19
	
	Conect	23,24
	Conect	24,25
	Conect	25,26
	Conect	26,27
	Conect	27,28
	Conect	28,29
	Conect	29,30
	Conect	30,31
	Conect	31,32
	Conect	32,33
	Conect	33,34
	Conect	34,35
	Conect	35,36
	Conect	36,37
	Conect	37,38
	Conect	38,23
	
	Conect	39,40
	Conect	40,41
	Conect	41,42
	Conect	42,39

	Conect	43,44
	Conect	44,45
	Conect	45,43
	
*****************************************************************************

; All copper list after here

Copper
; ---- Simple Screen setup ----
	Spr_Off					; Switch sprites off
	Cmove	$2871,Diwstrt
	Cmove	$2cc1,Diwstop
	Cmove	$0028,Ddfstrt
	Cmove	$00d0,Ddfstop
	Cmove	$0002,Bpl1mod			
	Cmove	$0002,Bpl2mod
	Cmove	$0007,bpl1pth
	Cmove	$d05c,bpl1ptl
	Cmove	$0007,bpl2pth
	Cmove	$d000,bpl2ptl
	Cmove	$2600,bplcon0
	Cmove	$0000,Color00
	Cmove	$0222,Color09
Smth	Cmove	$0000,Bplcon1

; ---- Rasters Behind Sine ----

	Cmove	$0F68,Color01
	Cwait	50,0
	Cmove	$0F79,Color01
	Cwait	52,0
	Cmove	$0F8a,Color01
	Cwait	54,0
	Cmove	$0F9b,Color01
	Cwait	56,0
	Cmove	$0FAc,Color01
	Cwait	58,0
	Cmove	$0FBd,Color01
	Cwait	60,0
	Cmove	$0FCe,Color01
	Cwait	62,0
	Cmove	$0FDf,Color01
	Cwait	64,0
	Cmove	$0FCe,Color01
	Cwait	66,0
	Cmove	$0FBd,Color01
	Cwait	68,0
	Cmove	$0FAc,Color01
	Cwait	70,0
	Cmove	$0F9b,Color01
	Cwait	72,0
	Cmove	$0F8a,Color01
	Cwait	74,0
	Cmove	$0F79,Color01
	Cwait	76,0
	Cmove	$0F68,Color01
	Cwait	78,0
	Cmove	$0F57,Color01

; ---- Copper Bar -1-

	Cwait	90,0
	Cmove	$0200,Bplcon0
	Cmove	$0000,Bplcon1
	Cmove	$0000,Bpl1mod
	Cmove	$0000,Bpl2mod
	Cmove	$0038,Ddfstrt
	Cmove	$0005,Color00
	Cwait	91,0
	Cmove	$0126,Color00
	Cwait	92,0
	Cmove	$0459,Color00
	Cwait	93,0
	Cmove	$099d,Color00
	Cwait	94,0
	Cmove	$0bbe,Color00
	Cwait	95,0
	Cmove	$0889,Color00
	Cwait	96,0
	Cmove	$0444,Color00
	Cwait	97,0
	Cmove	$0333,Color00
	Cwait	98,0
	Cmove	$0003,Color00

; ---- Set Up Vector Bitmaps ----

	Cmove	$2600,Bplcon0
	Cmove	$0007,Bpl2pth
Bit1l
	Cmove	$0000,Bpl2ptl
	Cmove	$0006,Bpl1pth
	Cmove	$0000,Bpl1ptl
	Cmove	$002f,Color09			; Vector Colour
	Cmove	$049b,Color01			; Vector Colour

Sell
	Cwait	142,0
	Cmove	$fff,Color01
Selh
	Cwait	150,0
	Cmove	$049b,Color01			; Vector Colour
	
	Pal

; ---- Copper Bar ----

	Cwait	1,0
	Cmove	$0200,Bplcon0
	Cmove	$0005,Color00
	Cwait	2,0
	Cmove	$0126,Color00
	Cwait	3,0
	Cmove	$0459,Color00
	Cwait	4,0
	Cmove	$099d,Color00
	Cwait	5,0
	Cmove	$0bbe,Color00
	Cwait	6,0
	Cmove	$0889,Color00
	Cwait	7,0
	Cmove	$0444,Color00
	Cwait	8,0
	Cmove	$0333,Color00
	Cwait	9,0
	Cmove	$0000,Color00
	Cwait	12,0
	Cmove	$2200,Bplcon0
	Cmove	$0eca,Color01
	Cmove	$0aaf,Color02
	Cmove	$0433,Color03
Log1l	Cmove	$0000,Bpl1ptl
Log1h	Cmove	$0000,Bpl1pth
Log2l	Cmove	$0000,Bpl2ptl
Log2h	Cmove	$0000,Bpl2pth
SetI	Macro
	Cwait	\1,0
	Cmove	\2,Color01
	Cmove	\3,Color02
	Endm
	SetI	14,$444,$006
	SetI	15,$444,$118
	SetI	16,$444,$006
	SetI	17,$444,$006
	SetI	18,$555,$006
	SetI	19,$666,$118
	SetI	20,$777,$129
	SetI	21,$888,$23a
	SetI	22,$999,$34a
	SetI	23,$aaa,$45b
	SetI	24,$bbb,$56c
	SetI	25,$ccc,$67c
	SetI	26,$ddd,$78d
	SetI	27,$eee,$89e
	SetI	28,$fff,$9be
	SetI	29,$eee,$bcf
	SetI	30,$ddd,$9be
	SetI	31,$ccc,$89e
	SetI	32,$bbb,$78d
	SetI	33,$aaa,$67c
	SetI	34,$999,$56c
	SetI	35,$888,$45b
	SetI	36,$777,$34a
	SetI	37,$666,$23a
	SetI	38,$555,$129
	SetI	39,$444,$118
	SetI	40,$444,$006
	SetI	41,$444,$006
	SetI	42,$444,$118
	SetI	43,$444,$006
	Cwait	45,0
	Cmove	$0200,Bplcon0
	Endcop

*************************$****************************************************

SCROLLERSPACE	DCB.B	9*46

*****************************************************************************

 Even
TitleText
	Include	Loader/MenuText	

*****************************************************************************

Logo
	Incbin	Gfx/SArena.Bm
	
*****************************************************************************

bpsong	incbin Snd/Sound
		
*****************************************************************************