*****************************************************************************
*                                                                           *
*                             New Intro For Arena                           *
*                                                                           *
*  Start Date : 23/3/91                                                     *
* Last Update : 01/4/91                                                     *
*   							      Code : Slaine *
*                                                                           *
*****************************************************************************

; Include the macros

	Incdir	Df1:
	Include	Source/Macro

*****************************************************************************

FadeSpeed	=	1
ScrollSpeed	=	3

*****************************************************************************

; Dont forget to use chip ram

	Chip
	
*****************************************************************************

; Kill the operating system for good mesure

	Kill		
	
*****************************************************************************

; Init Sprites
	Move.l	#Sprite,D0
	PlaneOn	D0,Spr0l+2,Spr0h+2
	Move.l	#Sprite1,D0
	PlaneOn	D0,Spr1l+2,Spr1h+2
	Move.l	#Sprite2,D0
	PlaneOn	D0,Spr2l+2,Spr2h+2

*****************************************************************************

; Load custom and set up copper list

	Lea	Custom,A5
	Move.l	#Copper,Cop1lch(a5)
	Move.w	#%1000011111100000,Dmacon(a5)	
	
*****************************************************************************

; Clear Some Memory

	Blitwait
	Move.l	#$70000,Bltdpth(a5)
	Move.l	#-1,Bltafwm(a5)
	Move.w	#0,Bltdmod(a5)
	Move.l	#$01000000,Bltcon0(a5)
	Move.w	#512*64+60,Bltsize(a5)

*****************************************************************************

	Blitwait
	
*****************************************************************************

	Lea	LogoBits+2,A0
	Moveq	#3-1,d7
	Move.l	#Logo,D0
LogoB
	Move.w	d0,(a0)
	Addq	#4,a0
	Swap	d0
	Move.w	d0,(a0)
	Addq	#4,a0
	Swap	d0
	Add.l	#70*40,d0
	Dbf	D7,LogoB

*****************************************************************************

	SaveAll
	Jsr	BpInit
	LoadAll
	
*****************************************************************************

; Main routine here

Mouse
	Cmp.b	#$c0,$dff006
	Bne.s	Mouse
	Bsr	Feild
	Bsr	SetNights
	Bsr	Fading
	Bsr	Riders
	Eor.l	#$5000,ScreenPtr
	Eor.l	#$5000,Buff1
	Eor.l	#$5000,Buff2
	Bsr	Clear
	Bsr	DoScroll
	SaveAll
	Jsr	BpMusic
	LoadAll
	Tstmice	Mouse				; Pressed the mouse
	
*****************************************************************************

 	clr.w	$dff0a8
	clr.w	$dff0b8
	clr.w	$dff0c8
	clr.w	$dff0d8
	move.w	#$f,$dff096

*****************************************************************************

	Move.l	#50,D6
EndLoop
	Pos
	SaveAll
	Bsr	SetNights1
	Move.l	#FadeDown,A1
	Lea	SnurkCol+2,a0
	Move.l	#3-1,D7
	Move.l	#0,D6
	Move.l	#4,D5
	Bsr	FadeLoop
	Move.l	#FadeDown,A1
	Lea	Nit+6,a0
	Move.l	#84-1,D7
	Move.l	#8,D5
	Move.l	#0,D6
	Bsr	FadeLoop
	Lea	BlueFade+2,A0
	Move.l	#FadeDown,A1
	Move.l	#6-1,d7
	Move.l	#0,d6
	Move.l	#4,d5
	Bsr	FadeLoop

	LoadAll

	Dbf	D6,EndLoop
	
*****************************************************************************

; Return operating system and go back to user

	Heal
	Clr.l	D0				; No error
	Rts
	
*****************************************************************************

Feild
	Lea	Sprite+1,A0
	Move.l	#9,d7
SpriteLoop1
	Add.b	#3,(A0)
	Add.w	#24,a0
	Add.b	#4,(A0)
	Add.w	#24,a0
	Dbf	D7,SpriteLoop1
	Lea	Sprite1+1,A0
	Move.l	#9,d7
SpriteLoop2
	Add.b	#2,(A0)
	Add.w	#24,a0
	Add.b	#3,(A0)
	Add.w	#24,a0
	Dbf	D7,SpriteLoop2
	Lea	Sprite2+1,A0
	Move.l	#9,d7
SpriteLoop3
	Add.b	#1,(A0)
	Add.w	#24,a0
	Add.b	#2,(A0)
	Add.w	#24,a0
	Dbf	D7,SpriteLoop3
	Rts


*****************************************************************************

Clear
	Blitwait				; Blitter Nasty But Why Do
	Move.l	#$01000000,Bltcon0(a5)		; Clear
	Move.w	#$0000,Bltdmod(a5)		; Skip No Bytes
	Move.l	ScreenPtr,A1
	Move.l	a1,Bltdpth(A5)			; Set Dest
	Move.l	#-1,Bltafwm(a5)			; Use All Bits
	Move.w	#100*64+24,Bltsize(a5)		; Fill Half Screen
	Movem.l	a0-a6/d0-d7,-(a7)		; Save The Regs
	Movem.l	RegFiller(pc),a1-a6/d0-d7	; Clear The Regs
	Move.l	ScreenPtr,A0
	Add.l	#9600,A0

; 4800/56 = 85.71 Rnd Up = 86
	Rept	86				; Rept it 58 times
	Movem.l	a1-a6/d0-d7,-(a0)		; Clear 56 Butes
	Endr					; End repeat
	Movem.l	(a7)+,a0-a6/d0-d7		; Restor Regs
	Rts
RegFiller
	Dcb.l	16,0
	Rts
	
*****************************************************************************

SetNights
	Cmp.b	#45,BarPos1
	Beq.s	LeaveBarPos1
	Add.b	#1,BarPos1
LeaveBarPos1
	Cmp.b	#113,BarPos2
	Beq.s	LeaveBarPos2
	Add.b	#2,BarPos2
	Lea	BlueFade+2,A0
	Move.l	#6-1,d7
	Move.l	#2,d6
	Move.l	#4,d5
	Move.l	#StarFade1,A1
	Bsr	FadeLoop
LeaveBarPos2
	Cmp.b	#40,BarPos3
	Beq.s	LeaveBarPos3
	Sub.b	#1,BarPos3
LeaveBarPos3
	Rts

SetNights1
	Cmp.b	#35,BarPos1
	Beq.s	LeaveBarPos1a
	Sub.b	#1,BarPos1
LeaveBarPos1a
	Cmp.b	#35,BarPos2
	Beq.s	LeaveBarPos2a
	Sub.b	#2,BarPos2
LeaveBarPos2a
	Cmp.b	#60,BarPos3
	Beq.s	LeaveBarPos3a
	Add.b	#1,BarPos3
LeaveBarPos3a
	Rts
	
*****************************************************************************

Fading	
	Tst.w	Shafting
	Beq.s	GoShaft
	Sub.w	#1,Shafting
	Rts
GoShaft
	Move.w	#Fadespeed,Shafting		; Fade Del
	Bsr	TstSomeShit
	Lea	FadeDest+2,A0
	Move.l	FadePtr,A1
	Move.l	#8-1,D7
	Move.l	#2,D6
	Move.l	#4,D5
FadeLoop
	Move.w	(a0),d0				; Current Colour
	Move.w	(a1),d1				; What Colour Do We Want
	Bsr	DoFade
	Move.w	d4,(a0)				; Store New Col
	Add.w	d5,a0
	Add.w	d6,a1
	Dbf	D7,FadeLoop
	Rts
DoFade
	Move.w	d0,D2
	Move.w	d1,d3
	And.w	#$00f,D2			; Get Blue
	And.w	#$00f,D3			; Get Blue
	Cmp.w	d2,d3				; Check Both
	Blt.s	FadeBlueDown			; If Lower Add
	Bgt.s	FadeBlueUp			; If Higher Sub
	Bra	LeaveBlue			; Or Leave Alone
FadeBlueUp
	Add.w	#$001,D2			; Add To The Blue
	Bra	LeaveBlue			
FadeBluedown
	Sub.w	#$001,D2			; Sub From The Blue
	Bra	LeaveBlue
LeaveBlue
	Move.w	D2,D4				; Store It
	Move.w	d0,D2
	Move.w	d1,d3
	And.w	#$0f0,D2			; Get Green
	And.w	#$0f0,D3			; Get Green
	Cmp.w	d2,d3				; Check Both
	Blt.s	FadeGreenDown
	Bgt.s	FadeGreenUp
	Bra	LeaveGreen
FadeGreenUp
	Add.w	#$010,D2
	Bra	LeaveGreen
FadeGreendown
	Sub.w	#$010,D2
	Bra	LeaveGreen
LeaveGreen
	Or.w	D2,D4
	Move.w	d0,D2
	Move.w	d1,d3
	And.w	#$f00,D2			; Get Red
	And.w	#$f00,D3			; Get Red
	Cmp.w	d2,d3				; Check Both
	Blt.s	FadeRedDown
	Bgt.s	FadeRedUp
	Bra	LeaveRed
FadeRedUp
	Add.w	#$100,D2
	Bra	LeaveRed
FadeReddown
	Sub.w	#$100,D2
	Bra	LeaveRed
LeaveRed
	Or.w	D2,D4
	Rts

TstSomeShit
	Tst.l	ShaftDel
	Beq.s	DoTheDoFade	
	Sub.l	#1,ShaftDel
	Rts
DoTheDoFade	
	Move.l	#16+(100/Fadespeed),ShaftDel
	Move.l	ShaftPtr,A0
	Move.l	(a0)+,d0
	Cmp.l	#-1,d0
	Bne.s	OkShaft
	Move.l	#ShaftTab,A0
	Move.l	(a0)+,d0
OkShaft
	Move.l	A0,ShaftPtr
	Move.l	D0,FadePtr
	Rts
	
*****************************************************************************

Riders
	Move.l	NightColPtr,A0
	Add.l	#2,A0
	Cmp.l	#NightCols+NightColsize,A0
	Blt.s	RiderNoEnd
	Move.l	#NightCols,A0
RiderNoEnd
	Move.l	A0,NightColPtr
	Move.l	A0,Bltapth(a5)
	Move.l	#Night1+2,Bltdpth(a5)
	Move.l	#$ffffffff,Bltafwm(a5)
	Move.l	#$09f00000,Bltcon0(a5)
	Move.w	#$0000,Bltamod(a5)
	Move.w	#$0002,Bltdmod(a5)
	Move.w	#46*64+1,Bltsize(a5)
	Move.w	#-4,Bltamod(a5)
	Move.l	#Night2+2,Bltdpth(a5)
	Move.w	#46*64+1,Bltsize(a5)
	Move.w	#0,Bltamod(a5)
	Move.l	#Night3+2,Bltdpth(a5)
	Move.w	#46*64+1,Bltsize(a5)
	Rts

*****************************************************************************

X1Inc	Dc.w	0
X2Inc	Dc.w	0
Sin1Inc	Dc.w	0
Sin2Inc	Dc.w	0
Sin1Pt	Dc.w	0
Sin2Pt	Dc.w	0

SineOn
	Dc.l	0			; 1 = Sine
SineSmth
	Dc.w	0
	
SinTab
	Include	Source/0-50sin
	Include	Source/0-50sin
	Include	Source/0-50sin
	Include	Source/0-50sin

*****************************************************************************

DoScroll
	Tst.l	SineOn
	Beq	NoSine
	Tst.w	SineSmth
	Bne	ScrollOnSine
	Move.w	#8,SineSmth
	Clr.l	D0
	Move.l	ScrollPtr,A0
	Move.b	(a0)+,D0
	Cmp.b	#-1,D0
	Bne.s	NoSineEnd
	Move.l	#ScrollText,A0
	Move.b	(a0)+,d0
NoSineEnd
	Cmp.b	#253,D0
	Bne.s	SineBack
	Move.l	#0,SineOn
	Move.b	(a0)+,d0
SineBack
	Move.l	A0,ScrollPtr
	Sub.b	#32,d0				
	Divu	#20,d0				
	Move.w	d0,d1				
	Mulu	#40*16,d1			
	Swap	d0				
	Add.w	d0,d0				
	Add.w	d0,d1				
	Lea	Font,A2
	Add.w	D1,A2
	Move.l	A2,Bltapth(A5)
	Move.l	#$7a000+46,Bltdpth(A5)
	Move.w	#38,Bltamod(A5)
	Move.w	#46,Bltdmod(A5)
	Move.l	#-1,Bltafwm(A5)
	Move.l	#$09f00000,Bltcon0(a5)
	Move.w	#16*64+1,Bltsize(A5)
ScrollOnSine
	Sub.w	#1,SineSmth
	Move.l	#$7a002,Bltapth(A5)
	Move.l	#$7a000,Bltdpth(A5)
	Move.w	#0,Bltamod(A5)
	Move.w	#0,Bltdmod(A5)
	Move.l	#-1,Bltafwm(A5)
	Move.l	#$e9f00000,Bltcon0(a5)
	Move.w	#16*64+24,Bltsize(A5)

	Move.w	#46,Bltamod(a5)
	Move.w	#46,Bltcmod(a5)
	Move.w	#46,Bltdmod(a5)
	Move.l	#$0bfa0000,Bltcon0(a5)
	Move.l	#-1,Bltafwm(a5)
	Move.l	Sin1Inc,D7
	Add.l	D7,Sin1pt
	And.l	#$07fe07fe,Sin1pt
	Lea	Bltapth(a5),A1
	Lea	Bltcpth(a5),A2
	Lea	Bltdpth(a5),A3
	Lea	Bltsize(a5),A4
	Lea	Bltafwm(a5),A6
	Lea	SinTab,A0
	Add.w	Sin1pt,A0
	Lea	Sintab,A5
	Add.w	Sin2pt,A5
	Move.l	#$7a000,D0
	Move.l	ScreenPtr,D1
	Add.w	#4,D1
	Move.w	#16*64+1,D2
	Moveq	#0,D3
	Moveq	#0,D4
	Move.w	X1inc,D5
	Move.w	X2inc,D6
BlitMac	Macro
	Add.w	(a0,d3),d1
	Add.w	(a5,d4),d1
	Move.l	D0,(a1)
	Move.l	D1,(a2)	
	Move.l	D1,(a3)	
	Move.w	#\1,(a6)
	Move.w	D2,(a4)
	Sub.w	(a0,d3),d1
	Sub.w	(a5,d4),d1
	Add.w	D5,D3
	Add.w	D6,D4
	Endm
	Rept	20
	BlitMac	$8000
	BlitMac	$4000
	BlitMac	$2000
	BlitMac	$1000
	BlitMac	$0800
	BlitMac	$0400
	BlitMac	$0200
	BlitMac	$0100
	BlitMac	$0080
	BlitMac	$0040
	BlitMac	$0020
	BlitMac	$0010
	BlitMac	$0008
	BlitMac	$0004
	BlitMac	$0002
	BlitMac	$0001
	Add.w	#2,D0
	Add.w	#2,D1
	Endr
	Lea	Custom,A5
	Rts
	
NoSine
	Rept	ScrollSpeed
	Bsr	ScrityPel
	Endr
	Tst.w	ScrollS
	Bne	Sctrollon
	Moveq	#0,D0
	Move.l	ScrollPtr,A0
	Move.b	(a0)+,d0
	Cmp.b	#-1,d0
	Bne.s	ScrollEnd
	Move.l	#ScrollText,A0
	Move.b	(a0)+,d0
ScrollEnd	
	Cmp.b	#254,d0
	Bne.s	NoSineing
	Move.l	#1,SineOn
	Move.b	(a0)+,X1inc+1
	Move.b	(a0)+,X2inc+1
	Move.b	(a0)+,Sin1Inc+1
	Move.b	(a0)+,Sin2Inc+1
	Move.b	(a0)+,D0
NoSineing
	Cmp.b	#253,D0
	Bne.s	SineOff
	Move.l	#0,SineOn
	Move.b	(a0)+,D0
SineOff
	Move.l	A0,ScrollPtr
	Sub.b	#32,d0
	Muls	#30,d0
	Lea	CharTab,A0
	Add.l	D0,A0
	Lea	CurChar,A1
	Move.l	#29,D7
Shift
	Move.b	(a0)+,(a1)+
	Dbf	D7,Shift
	Move.w	#6,ScrollS
Sctrollon
	Add.w	#4,Yptr
	And.w	#255,Yptr
	Add.w	#4,xptr
	And.w	#127,xptr
	Clr.l	d0
	Clr.l	d1
	Clr.l	d2
	Clr.l	d3
	Move.l	ScreenPtr,A0
	Lea	BobInfo,A1
	Lea	Ytab,A2
	Add.w	Yptr,A2
	Lea	Xtab,A3
	Add.w	Xptr,A3
	Lea	CharSpace,A6
	Move.w	#44,Bltcmod(A5)
	Move.w	#44,Bltdmod(A5)
	Move.w	#-2,Bltamod(A5)
	Move.l	#$ffff0000,Bltafwm(a5)
	Move.l	#$0bfa0000,Bltcon0(a5)
	Move.w	#21,D7
	Move.w	SnurkScroll,D1			; X
BlitLoop
	Move.w	#5-1,d6				; Down
BlitLoop1
	Addq	#2,a2
	Addq	#2,a3
	Move.b	(a6)+,d0
	Cmp.b	#" ",d0
	Beq.s	SkipBlit
	Movem.l	d1-d2/a0,-(a7)
	Add.w	(a3),d1
	Ror.l	#4,D1
	Add.w	d1,d1
	Add.w	(a2),d2
	Add.w	D1,A0
	Add.w	D2,A0
	Swap	D1
	Or.w	#$0bfa,D1
	Move.w	d1,Bltcon0(a5)
	Move.l	A1,Bltapth(a5)
	Move.l	A0,Bltcpth(a5)
	Move.l	A0,Bltdpth(a5)
	Move.w	#16*64+2,Bltsize(a5)
	Movem.l	(a7)+,d1-d2/a0
SkipBlit
	Add.w	#16*48,d2
	Dbf	D6,BlitLoop1
	Sub.w	#6,A3
	Moveq	#0,D2
	Add.w	#16,d1
	Dbf	D7,BlitLoop
	Rts

ScrityPel
	Sub.w	#2,SnurkScroll
	Cmp.w	#0,SnurkScroll
	Bgt.s	GoSub
	Move.w	#15,SnurkScroll
	Lea	CharSpace,A0
	Lea	CharSpace+5,A1
	Move.l	#(6*6)-2,d7
	Sub.w	#1,ScrollS
ShiftLoop
	Move.b	(a1)+,(a0)+
	Move.b	(a1)+,(a0)+
	Move.b	(a1)+,(a0)+
	Move.b	(a1)+,(a0)+
	Move.b	(a1)+,(a0)+
	Dbf	D7,ShiftLoop
	Add.w	#8,yptr
	Add.w	#4,Xptr
GoSub
	Rts

*****************************************************************************

SnurkScroll
	Dc.w	15
ScreenPtr
	Dc.l	$70000
	
*****************************************************************************

ScrollS
	Dc.w	0
YPtr
	Dc.w	0
YTab
	Rept	2
	dc.w	96*48,96*48,96*48,95*48,95*48,95*48,94*48,93*48
	dc.w	92*48,91*48,90*48,89*48,88*48,87*48,85*48,84*48
	dc.w	82*48,80*48,78*48,77*48,75*48,73*48,71*48,69*48
	dc.w	66*48,64*48,62*48,60*48,57*48,55*48,53*48,50*48
	dc.w	48*48,46*48,43*48,41*48,39*48,36*48,34*48,32*48
	dc.w	30*48,27*48,25*48,23*48,21*48,19*48,18*48,16*48
	dc.w	14*48,12*48,11*48,9*48,8*48,7*48,6*48,5*48
	dc.w	4*48,3*48,2*48,1*48,1*48,1*48,0*48,0*48
	dc.w	0*48,0*48,0*48,1*48,1*48,1*48,2*48,3*48
	dc.w	4*48,5*48,6*48,7*48,8*48,9*48,11*48,12*48
	dc.w	14*48,16*48,18*48,19*48,21*48,23*48,25*48,27*48
	dc.w	30*48,32*48,34*48,36*48,39*48,41*48,43*48,46*48
	dc.w	48*48,50*48,53*48,55*48,57*48,60*48,62*48,64*48
	dc.w	66*48,69*48,71*48,73*48,75*48,77*48,78*48,80*48
	dc.w	82*48,84*48,85*48,87*48,88*48,89*48,90*48,91*48
	dc.w	92*48,93*48,94*48,95*48,95*48,95*48,96*48,96*48
	Endr

XPtr
	Dc.w	0
Xtab
	Rept	7
	dc.w	15,15,15,15,14,14,14,13
	dc.w	13,12,12,11,10,10,9,8
	dc.w	7,7,6,5,5,4,3,3
	dc.w	2,2,1,1,1,0,0,0
	dc.w	0,0,0,0,1,1,1,2
	dc.w	2,3,3,4,5,5,6,7
	dc.w	7,8,9,10,10,11,12,12
	dc.w	13,13,14,14,14,15,15,15
	Endr

*****************************************************************************

CharSpace
	Rept	5
	Dc.b	"     "
	Dc.b	"     "
	Dc.b	"     "
	Dc.b	"     "
	Dc.b	"     "
	Dc.b	"     "
	Endr
CurChar
	Dc.b	"     "
	Dc.b	"     "
	Dc.b	"     "
	Dc.b	"     "
	Dc.b	"     "
	Dc.b	"     "

CharTab 
	Include	Source/SnurkFnt2
 even
 
*****************************************************************************

ScrollPtr
	Dc.l	ScrollText
ScrollText
	Include	Intro-1/ScrollText
	DC.B	255
 even

*****************************************************************************

SprMac	Macro
	Dc.b	\1,\2,\1+5,\3
	Dc.w	%01010,%00110
	Dc.w	%11101,%00011
	Dc.w	%11011,%10111
	Dc.w	%11111,%11111
	Dc.w	%01110,%01110
	Endm
SprMac1	Macro
	Dc.b	\1,\2,\1+5,\3
	Dc.w	%00000,%01000
	Dc.w	%01000,%10100
	Dc.w	%00000,%01000
	Dc.w	%00000,%00000
	Dc.w	%00000,%00000
	Endm
SprMac2	Macro
	Dc.b	\1,\2,\1+5,\3
	Dc.w	%00000,%00000
	Dc.w	%01000,%00000
	Dc.w	%00000,%00000
	Dc.w	%00000,%00000
	Dc.w	%00000,%00000
	Endm

*****************************************************************************

Sprite
	SprMac	117,028,0
	SprMac	127,172,0
	SprMac	137,058,0
	SprMac	147,207,0
	SprMac	157,135,0
	SprMac	167,092,0
	SprMac	177,073,0
	SprMac	187,126,0
	SprMac	197,144,0
	SprMac	207,028,0
	SprMac	217,213,0
	SprMac	227,166,0
	SprMac	237,012,0
	SprMac	247,213,0
	SprMac	002,093,6
	SprMac	012,122,6
	SprMac	022,051,6
	SprMac	032,134,6
	Dcb.w	20,0
Sprite1
	SprMac1	117,209,0
	SprMac1	127,187,0
	SprMac1	137,113,0
	SprMac1	147,090,0
	SprMac1	157,213,0
	SprMac1	167,015,0
	SprMac1	177,026,0
	SprMac1	187,129,0
	SprMac1	197,160,0
	SprMac1	207,171,0
	SprMac1	217,075,0
	SprMac1	227,130,0
	SprMac1	237,096,0
	SprMac1	247,166,0
	SprMac1	002,097,6
	SprMac1	012,169,6
	SprMac1	022,083,6
	SprMac1	032,182,6
	Dcb.w	20,0
Sprite2
	SprMac2	117,035,0
	SprMac2	127,014,0
	SprMac2	137,094,0
	SprMac2	147,028,0
	SprMac2	157,095,0
	SprMac2	167,140,0
	SprMac2	177,105,0
	SprMac2	187,186,0
	SprMac2	197,147,0
	SprMac2	207,035,0
	SprMac2	217,114,0
	SprMac2	227,085,0
	SprMac2	237,249,0
	SprMac2	247,088,0
	SprMac2	002,080,6
	SprMac2	012,004,6
	SprMac2	022,063,6
	SprMac2	032,253,6
	Dcb.w	20,0
	
*****************************************************************************

; All copper list after here

Copper
	Spr_Off					; Switch sprites off
	Cmove	$0003,Bplcon2
Spr0l	Cmove	$0000,Spr0ptl
Spr0h	Cmove	$0000,Spr0pth
Spr1l	Cmove	$0000,Spr1ptl
Spr1h	Cmove	$0000,Spr1pth
Spr2l	Cmove	$0000,Spr2ptl
Spr2h	Cmove	$0000,Spr2pth
	Cmove	$2c81,Diwstrt
	Cmove	$2cc1,Diwstop
	Cmove	$0038,Ddfstrt
	Cmove	$00d0,Ddfstop
	Cmove	$0000,Bplcon1
	Cmove	$0000,Bpl1mod			
	Cmove	$0000,Bpl2mod
LogoBits
	Cmove	$0000,Bpl1ptl
	Cmove	$0000,Bpl1pth
	Cmove	$0000,Bpl2ptl
	Cmove	$0000,Bpl2pth
	Cmove	$0000,Bpl3ptl
	Cmove	$0000,Bpl3pth
	Cmove	$3200,Bplcon0
Barpos1
	Cwait	20,40				; 45
Night1
	Rept	47
	Cmove	$0000,color00
	Endr
FadeDest
	Cmove	$0000,Color00
	Cmove	$0fff,Color01
	Cmove	$0eee,Color02
	Cmove	$0ddd,Color03
	Cmove	$0ccc,Color04
	Cmove	$0bbb,Color05
	Cmove	$0aaa,Color06
	Cmove	$0999,Color07
Barpos2
	Cwait	35,40				; 113
Night2
	Rept	47
	Cmove	$0000,color00
	Endr
	Cmove	$0000,Color00
	Cmove	$0200,Bplcon0

	Cwait	118,0
	Cmove	$2200,Bplcon0
Buff1
	Cmove	$0004,Bpl1ptl
	Cmove	$0007,Bpl1pth
Buff2
	Cmove	$0004+48,Bpl2ptl
	Cmove	$0007,Bpl2pth
SnurkCol
	Cmove	$0666,Color01
	Cmove	$0fff,Color02
	Cmove	$0aaa,Color03
	Cmove	$0008,Bpl1mod			
	Cmove	$0008,Bpl2mod
	Cmove	$0001,Bplcon1
	Cmove	$0000,Color16
BlueFade
	Cmove	$0000,Color17
	Cmove	$0000,Color18
	Cmove	$0000,Color19
	
	Cmove	$0000,Color21
	Cmove	$0000,Color22
	Cmove	$0000,Color23
BAR		Macro
	DC.B 	\1,$09,$FF,$FE
	DC.W 	COLOR03,\2
	ENDM


Nit	Bar	120,$0F9
	Bar	122,$0FA
	Bar	124,$0FB
	Bar	126,$0FC
	Bar	128,$0FD
	Bar	130,$0FE
	Bar	132,$0FF
	Bar	134,$0EF
	Bar	136,$0DF
	Bar	138,$0CF
	Bar	140,$0BF
	Bar	142,$0AF
	Bar	144,$09F
	Bar	146,$08F
	Bar	148,$07F
	Bar	150,$06F
	Bar	152,$05F
	Bar	154,$04F
	Bar	156,$03F
	Bar	158,$02F
	Bar	160,$01F
	Bar	162,$00F
	Bar	164,$10F
	Bar	166,$20F
	Bar	168,$30F
	Bar	170,$40F
	Bar	172,$50F
	Bar	174,$60F
	Bar	176,$70F
	Bar	178,$80F
	Bar	180,$90F
	Bar	182,$A0F
	Bar	184,$B0F
	Bar	186,$C0F
	Bar	188,$D0F
	Bar	190,$E0F
	Bar	192,$F0F
	Bar	194,$F0E
	Bar	196,$F0D
	Bar	198,$F0C
	Bar	200,$F0B
	Bar	212,$F0A
	Bar	214,$F09
	Bar	216,$F08
	Bar	218,$F07
	Bar	220,$F06
	Bar	222,$F05
	Bar	224,$F04
	Bar	226,$F03
	Bar	228,$F02
	Bar	230,$F01
	Bar	232,$F00
	Bar	234,$F10
	Bar	236,$F20
	Bar	238,$F30
	Bar	240,$F40
	Bar	242,$F50
	Bar	244,$F60
	Bar	246,$F70
	Bar	248,$F80
	Bar	250,$F90
	Bar	252,$FA0
	Bar	254,$FB0
	DC.W	$FFDD,$FFFE
	Dc.w	Color03,$fb0
	Bar	1,$FC0
	Bar	3,$FD0
	Bar	5,$FE0
	Bar	7,$FF0
	Bar	9,$EF0
	Bar	11,$DF0
	Bar	13,$CF0
	Bar	15,$BF0
	Bar	17,$AF0
	Bar	19,$9F0
	Bar	21,$8F0
	Bar	23,$7F0
	Bar	25,$6F0
	Bar	27,$5F0
	Bar	29,$4F0
	Bar	31,$3F0
	Bar	33,$2F0
	Bar	35,$1F0
	Bar	37,$0F0
	Bar	39,$0E0
Barpos3
	Cwait	60,40				; 113
Night3
	Rept	47
	Cmove	$0000,color00
	Endr
	Cmove	$0000,Color00
	Endcop

*****************************************************************************

FadePtr
	Dc.l	FadeCol2
	
*****************************************************************************

ShaftPtr
	Dc.l	ShaftTab
ShaftTab
	Dc.l	FadeCol1				; Fade This Lot
	Dc.l	FadeCol2				; Fade This Lot
	Dc.l	FadeCol3				; Fade This Lot
	Dc.l	FadeCol4
	dc.l	fadecol5
	dc.l	fadecol6
	dc.l	fadecol7
	dc.l	fadecol8
	dc.l	fadecol9		
	Dc.l	-1
ShaftDel
	Dc.l	0
Shafting
	Dc.w	0
	
*****************************************************************************

FadeCol1
	Dc.w	$111,$0cf,$0ad,$08b,$079,$068,$046,$034	; Fade Cols
FadeCol2
	Dc.w	$111,$c0f,$a0d,$80b,$709,$608,$406,$304	; Fade Cols
FadeCol3
	Dc.w	$111,$0ff,$0dd,$0bb,$099,$077,$055,$033	; Fade Cols
FadeCol4
	Dc.w	$111,$fff,$ddd,$bbb,$999,$778,$556,$334	; Fade Cols
FadeCol5
	Dc.w	$111,$f47,$d03,$b03,$902,$802,$601,$401	; Fade Cols
FadeCol6
	Dc.w	$111,$4f3,$1d0,$1b0,$190,$070,$050,$030	; Fade Cols
FadeCol7
	Dc.w	$111,$f81,$c60,$a50,$940,$740,$630,$420	; Fade Cols
FadeCol8
	Dc.w	$111,$71f,$50c,$40a,$308,$307,$205,$203	; Fade Cols
FadeCol9
	Dc.w	$111,$ef1,$bc0,$9a0,$780,$670,$450,$340	; Fade Cols
StarFade1
	Dc.w	$00f,$00a,$005,$00f,$00a,$005
FadeDown
	Dc.w	$000,$000,$000,$000,$000,$000,$000,$000
		
*****************************************************************************

NightColPtr
	Dc.l	NightCols
NightCols
; Colours To Go Through Night Rider
	Rept	2
	Dc.w	$f00,$f01,$f02,$f03,$f04
	Dc.w	$f05,$f06,$f07,$f08,$f09,$f0a,$f0b,$f0c,$f0d,$f0e
	Dc.w	$f0f,$e1f,$d2f,$c3f,$b4f,$a5f,$96f,$87f,$78f,$69f
	Dc.w	$5af,$4bf,$3cf,$2df,$1ef,$0ff,$1fe,$2fd,$3fc,$4fb
	Dc.w	$5fa,$6f9,$7f8,$8f7,$9f6,$af5,$bf4,$cf3,$df2,$ef1
	Dc.w	$ff0,$ff1,$ff2,$ff3,$ff4,$ff5,$ff6,$ff7,$ff8,$ff9
	Dc.w	$ffa,$ffb,$ffc,$ffd,$ffe,$fff,$fee,$fdd,$fcc,$fbb
	Dc.w	$faa,$f99,$f88,$f77,$f66,$f55,$f44,$f33,$f22,$f11
	Endr
NightColsize=(*-Nightcols)/2

*****************************************************************************

BobInfo
	Dc.w	%0011111111111100
	Dc.w	%0111111111111110
	Dc.w	%1110000000000111
	Dc.w	%1101111111111011
	Dc.w	%1101111111111011
	Dc.w	%1101111111111011
	Dc.w	%1101111111111011
	Dc.w	%1101111111111011
	Dc.w	%1101111111111011
	Dc.w	%1101111111111011
	Dc.w	%1101111111111011
	Dc.w	%1101111111111011
	Dc.w	%1101111111111011
	Dc.w	%1101111111111011
	Dc.w	%1110000000000111
	Dc.w	%0111111111111110
	Dc.w	%0011111111111100

*****************************************************************************

Logo
	Incbin	Gfx/Fade70
	
*****************************************************************************

Font
	Incbin	Gfx/FX-FONT2.bm

 Even

*****************************************************************************

	Include	Source/SndMon.s
Bpsong	incbin "Snd/Sound"

*****************************************************************************