/** VLTPhoneDelete.rexx
*
*   Select the entries to be deleted.
*
*   By W.G.J. Langeveld, February 1992.
*
**/
if show("l", "rexxarplib.library") = 0 then do
   check = addlib('rexxsupport.library', 0, -30, 0)
   check = addlib('rexxarplib.library',  0, -30, 0)
   check = addlib('rexxmathlib.library', 0, -30, 0)
end
/*
*   Get VLT port and screen names and size
*/
vltport = address()
cols = ScreenCols(vltport)
if cols == -1 then do
   vltscreen = ""
   cols = ScreenCols()
   rows = ScreenRows()
end
else do
   vltscreen = vltport
   rows = ScreenRows(vltscreen)
end
/*
*   Check if we're set up right
*/
call pragma('W','NULL')

if ~exists("VLTPhoneBook:") then do
   "@VLTPhoneSetup.rexx"
   exit
end
/*
*   Use a multiple select file requester. This works only under 2.0
*/
test = GetFile(80, 50, "VLTPhoneBook:",, "Select Entries to Delete",  ,
               vltscreen, "MULTISELECT", files)
if test = "" then exit

if files.0 = 0 then exit
/*
*   Delete the entries.
*/
test = Request(80, 50, "This operation will delete "files.0" entries",,   ,
               " Delete Them ", " No! Stop! ", vltscreen)
if test == "" then exit

do i = 1 to files.0
   address COMMAND "delete >nil: "files.i
end

exit