/*
    $VER: BrettBestellen.zprx V1.0 (30.8.94) Copyright (c) Jan Ritzerfeld

    Dies ist ein ARexx-Skript für Zodiac's  Point,  mit  dem  man  auf
    bequeme  Weise  schon eingerichtete Bretter wieder bestellen kann,
    falls die Boxsoft einfach welche ausgetragen hat.

    Sie dürfen dieses Skript beliebig kopieren,  solange  es  zusammen
    mit  Zodiac's  Point  eingesetzt wird, aber verändern Sie es bitte
    nicht ohne Erlaubnis des Autors.

    Sie erreichen den Autor wie folgt:

       Jan Ritzerfeld         Tel. : +49 2421 65177
       Dornheckweg 9          EMail: j.ritzerfeld@darkness.gun.de
       52355 Düren-Birgel

    Hinweise zur Installation:

    Kopieren sie dieses Skript in  das  Rexx-Verzeichnis  von  ZP  und
    fügen  sie  danach  der  Datei  'fkeys.zp'  auf Wunsch den Eintrag
    "F1:SYS:Rexxc/RX ZP:Rexx/BrettBestellen.zprx %s" hinzu.
*/

/* Der Konfigurations-Teil des Skriptes:

   Hier bitte die Netzadresse von MAPS angeben. */

maps = 'maps@darkness.gun.de'

/* Und hier bitte den MAPS-Befehl zum Brettbestellen eintragen. */

add = 'ADD'


/* Das eigentliche Programm: Änderungen sind nicht mehr gestattet! */

GUILOCK ON
options failat 10
signal on syntax

parse arg zpPort
if (zpPort = '') then
  zpPort = 'ZPoint'
address value zpPort
options results

call addlib('rexxsupport.library',0,-30,0)

temp = 'T:ba'pragma('I')
call delete(temp)


WHICHLEVEL
level = result
if (level = 'MAINMENU') then
  do
  REQUESTNOTIFY 'Ein Brett kann man nur aus dem Brett- oder Nachrichtenmenü bestellen!'
  GUILOCK OFF
  exit
  end

if (level = 'BOARDMENU') then
  ENTERBOARD
  GUILOCK ON

BOARDINFO LABEL
name = result
REQUESTRESPONSE 'Das Brett 'name' wirklich bestellen?'
if (rc) then
  do
  GUILOCK ON
  call Open('MapsAdd',temp,'W')
  call writeln('MapsAdd',name)
  call Close('MapsAdd')
  WRITEMESSAGE temp 'RECEIVER' maps 'SUBJECT' add
  end

GUILOCK ON
if (level = 'BOARDMENU') then
  BOARDMENU

call delete(temp)
GUILOCK OFF
exit


syntax: /* Ein Fehler ist aufgetreten ! */

REQUESTNOTIFY 'Schade auch, Fehler in Zeile' SIGL ':' ERRORTEXT(rc) ':-('
GUILOCK OFF

exit