(set @default-dest "")

(if (NOT (exists "Mail:" (noreq)))

     (
       (set name
          (askdir
            (prompt "Assigning Mail:\nPlease choose a directory where your comms\nprograms are.")
            (help @askdir-help)
            (default "Work:")
            (disk)
          )
       )

       (startup "Pick-Tag"
          (prompt "Some instructions need to be added to the \"S:user-startup\" so that your system will be properly configured to use Pick-Tag.")
          (help @startup-help)
          (command "assign Mail: " name)
       )

       (makeassign "Mail" name
          (safe)
       )
     )
)


(if (exists "Mail:Pick-Tag.cfg" (noreq))
  (
    (delete "Mail:Pick-Tag.cfg"
        (prompt "Ok to delete the old Pick-Tag.cfg?.")
        (help "This new version of Pick-Tag cannot read the old\nconfig so it needs to be deleted.")
        (confirm)
    )

  )
)

(if (exists "AZSpell:" (noreq))

  (
    (copyfiles
        (prompt "Copying Pick-Tag.")
        (help @copyfiles-help)
        (source "")
        (pattern "Pick-Tag#?")
        (dest "Mail:")
        (infos)
        (files)
        (confirm)
    )


    (copyfiles
        (prompt "Copying script for AZSpell.")
        (help @copyfiles-help)
        (source "")
        (pattern "AZ_Check")
        (dest "AZSpell:")
        (files)
        (confirm)
    )
  )


    (copyfiles
        (prompt "Copying Pick-Tag & files.")
        (help @copyfiles-help)
        (source "")
        (pattern "(Pick-Tag#?|AZ_Check)")
        (dest "Mail:")
        (infos)
        (files)
        (confirm)
    )



)



(if (exists "Mail:Taglines" (noreq))

    (copyfiles
        (prompt "I see you've already got taglines. I will copy mine as Mail:Taglines_NEW")
        (help "Selecting proceed will copy my taglines over to your disk and name them Mail:Taglines_NEW.\nYou can then use Pick-Tag to combine them.")
        (source "Taglines")
        (dest "Mail:")
        (newname "Taglines_NEW")
        (files)
        (confirm)
    )

    (copyfiles
        (prompt "Copying taglines to Mail:")
        (help @copyfiles-help)
        (source "")
        (pattern "Taglines")
        (dest "Mail:")
        (files)
        (confirm)
    )

)


(copylib
        (prompt "Copying reqtools.library to Libs:")
        (help @copylib-help)
        (source "Libs/reqtools.library")
        (dest "Libs:")
        (confirm)
)