failat 40
setenv dlinstalldir ""
echo "                                "
echo "Deadlock Issue #9 HD Compatible "
echo "CLI-Based Installer "
echo 
echo "Enter path you wish to install to : " noline
if "$KickStart" GT "37.00"
   if exists "c:requestfile"
      c:requestfile drawer "ram:" savemode title="Select path to install to"  drawersonly  > env:DLInstallDir
      echo $dlinstalldir
   else
      setenv >Nil: DLInstallDir ?
   endif
else
   setenv >Nil: DLInstallDir ?
endif
if $DLInstallDir EQ ""
   echo "Installation aborted by User.."
else
if exists $DLInstallDir
LAB Start
   cd >NIL: $DLInstallDir
   if fail
      echo 'Error: Cannot change directory..'
   else
      echo "Attempting to install Deadlock #9 to directory" $DlInstallDir
      echo "Copying 'DeadlockArticles09.dat'.."  noline
      copy dl09:DeadlockArticles09.dat $DLInstallDir
      if not warn
	   echo "Done"
	   echo "Copying 'DeadlockGFX09.dat'.." noline
	   copy dl09:DeadlockGFX09.dat $DLInstallDir

	   if not warn
		echo "Done"
		echo "Copying 'dl09.exe'.." noline
		copy dl09:Dl09.exe $DlInstallDir
		if not warn
		   echo "Done"
		   echo 
		   echo "Creating Script.." 
			
		   echo assign dl09: $dlinstalldir > Deadlock09
		   echo "Deadlock will cater for both Normal monitors and Multisync monitors"
		   echo "the routines vary slightly."
		   ask  "Do you use a Multisync monitor (y/n) :"
		   if warn 
			echo "MULTISYNC switch added to Deadlock script"
  		        echo "dl09.exe multisync hdinstalled" >> Deadlock09
		   else
			echo "Deadlock will run as normal.."
			echo "dl09.exe hdinstalled" >> Deadlock09
		   endif
		   echo assign dl09: remove >> Deadlock09
 echo ";this mag will run from workbench and cli" >> Deadlock09
 echo ";but it is better to run from cli. see Readme file for info" >> Deadlock09
 copy dl09:Deadlock09.info $dlinstalldir
		   echo "Install Complete"
		else
		skip fail

		endif
	   else
		skip	fail
           endif
      else
lab fail
	echo "Installation failed"
      endif
   endif
else
   echo "could not find $DLInstallDir"
   ask "Shall I create '$DLInstallDir' as a directory:"
   if warn
      echo "Making directory $DLInstallDir.." noline
      makedir "$DLInstallDir"
      echo "Done"
      skip Start BACK
    else
      echo "Install Aborted by User"      
    endif
endif
endif