/* ------------------------------------------------------------------ *
 * ARexx-Skript zur Übernahme einer Adresse als DataBase in ProWrite. *
 * Es ist komplizierter (fragt nach Vor- und Nachnamen) und soll dem  *
 * fortgeschrittenen Anwender als Referenz dienen.                    *
 *                                                                    *
 * 19.08.93, Jörg Richter                                             *
 * ------------------------------------------------------------------ */

OPTIONS RESULTS
RequestText 'Bitte Nachnamen eingeben:'
IF RC ~= 0 THEN EXIT 5
nachname = result
RequestText 'Bitte Vornamen eingeben:'
vorname = result

ADDRESS DataBase

FINDBASE 'Adressen.db'
base = RC
IF base ~= -1 THEN
  BASE base
ELSE
  DO
    BASE 5
    Open 'Adressen.db'
  END

LeftTotal

weiter = 1
IF vorname ~= '' THEN
  DO i = 1 WHILE weiter = 1
    SearchNext nachname
    IF RC = 0 THEN
      DO
        GetData $F3
        IF result = vorname THEN weiter = 0
      END
    ELSE
      weiter = 2
  END
ELSE
  DO
    SearchNext nachname
    IF RC = 0 THEN weiter = 0
  END

IF weiter = 0 THEN
  DO
    Print 'T:out.txt' 'Adressen_ProWrite.prt'
    ADDRESS
    InsertText 'T:out.txt'
  END
ELSE
  DO
    ADDRESS
    Request1 'Suchbegriff nicht gefunden'
  END