opt	o+,a+

Start	move.l	4.w,a6
	lea	dosname,a1
	jsr	-408(a6)		* OldOpenLib
	lea	dosbase,a0
	move.l	d0,(a0)
	beq.s	Fehler

	lea	locname,a1
	jsr	-408(a6)		* OldOpenLib
	lea	locbase,a0
	move.l	d0,(a0)
	beq.s	Fehler
	
	move.l	dosbase,a6
	jsr	-60(a6)		* Output
	lea	output,a0
	move.l	d0,(a0)
	beq.s	Fehler

	move.l	locbase,a6

Hauptprogramm
	sub.l	a0,a0
	lea	catname,a1
	sub.l	a2,a2
	jsr	-150(a6)		* OpenCatalogA
	tst.l	d0
	beq.s	Fehler
	move.l	d0,a5
	
	moveq	#1,d7
	move.l	#$B3,d6
	
.loop	move.l	a5,a0
	move.l	d7,d0
	lea	null,a1
	jsr	-72(a6)		* GetCatalogString	
	
	move.l	d0,a0
	bsr.s	Ausgabe
	
	addq.l	#1,d7
	cmp.l	d6,d7
	ble.s	.loop
	
	move.l	a5,a0
	jsr	-36(a6)		* CloseCatalog
	
Fehler	move.l	4.w,a6
	move.l	dosbase,a1
	jsr	-414(a6)		* CloseLib
	move.l	locbase,a1
	jsr	-414(a6)		* CloseLib
	moveq	#0,d0
	rts

Ausgabe	movem.l	d0-d7/a0-a6,-(sp)
	move.l	dosbase,a6
	move.l	d0,d2
Loop1	tst.b	(a0)+
	bne.s	Loop1
	move.l	a0,d3
	sub.l	d2,d3
	subq.l	#1,d3
	move.l	output,d1
	jsr	-48(a6)		* Write
	
	move.l	output,d1
	lea	Return,a0
	move.l	a0,d2
	moveq	#1,d3
	jsr	-48(a6)		* Write
	movem.l	(sp)+,d0-d7/a0-a6
	rts

dosbase	dc.l	0
locbase	dc.l	0
output	dc.l	0
	
LocName	dc.b	'locale.library',0
DosName	dc.b	'dos.library',0
Return	dc.b	10
CatName	dc.b	'sys/workbench.catalog',0
null	dc.b	0