*** INCLUDES ***

		incdir	include:

		include	exec/exec_lib.i
		include	libraries/dos_lib.i

*** CODE ***
		move.b	(a0),CmdLineChar	

		lea	DOSName,a1
		clr.l	d0
		CALLEXEC OpenLibrary
		tst.l	d0
		beq	NoDOSLib
		move.l	d0,_DOSBase

		move.b	CmdLineChar,d0

		cmp.b	#"f",d0
		beq	Mode60Hz
		cmp.b	#"F",d0
		beq	Mode60Hz
		cmp.b	#"s",d0
		beq	Mode50Hz
		cmp.b	#"S",d0
		beq	Mode50Hz

		CALLDOS Output
		move.l	d0,d1
		move.l	#ErrorText,d2
		move.l	#ErrorTextLength,d3
		CALLDOS Write
		bra	CloseUp

Mode50Hz	move.w	#$20,$dff1dc
		bra	CloseUp

Mode60Hz	move.w	#$00,$dff1dc

CloseUp		move.l	_DOSBase,a1
		CALLEXEC CloseLibrary
NoDOSLib	rts

*** DATA ***

DOSName		dc.b	"dos.library",0
		even
_DOSBase	dc.l	0

CmdLineChar	dc.b	0
		even

ErrorText	dc.b	"SetSpeed v1.0   (c) 1990 Chris Simpson",10,13,10,13
		dc.b    "USAGE: SetSpeed x where x = S or s for 50Hz mode",13,10
		dc.b	"                        x = F or f for 60Hz mode",13,10,13,10
		dc.b	"Note that your Amiga must have a Fatter Agnus for this program to work!",13,10,13,10
ErrorTextLength	equ	*-ErrorText
		even