;``````````À````````````````````````````
;'INSIGHT Q&A' COLUMN JULY, 1991 ISSUE
;
;KOALA MULTICOLOR HI-RES DISPLAYER
;BY GUARDIAN (Q&A COLUMN)
;
;ASSEMBLER: TURBO ASSEMBLER 5.01
;COMPUTER : C64 (OR C128 IN 64 MODE.)
;```````````````````````````````````````

         *= $1000

         SEI
         LDX #$00        ;COPY
LOOP     LDA $8328,X     ;COLOR DATA
         STA $D800,X     ;TO COLOR RAM
         LDA $8428,X     ;($D800-$DBFF)
         STA $D900,X
         LDA $8528,X
         STA $DA00,X
         LDA $8628,X
         STA $DB00,X
         LDA $7F40,X     ;COPY COLOR
         STA $4400,X     ;DATA TO
         LDA $8040,X     ;SCREEN RAM
         STA $4500,X     ;($4400-$47FF)
         LDA $8140,X
         STA $4600,X
         LDA $8240,X
         STA $4700,X
         INX
         BNE LOOP

         LDA $8710       ;BACKGROUND
         STA $D021       ;COLOR DATA

         LDA #$3B        ;ENTER MULTI-
         STA $D011       ;-COLOR HI-RES
         LDA #$D8        ;MODE.
         STA $D016

         LDA $DD02       ;SWITCH TO
         ORA #$03        ;BANK 2
         STA $DD02       ;OF VIC-II
         LDA $DD00       ;RAM
         AND #$FC
         ORA #$02
         STA $DD00

         LDA #$18        ;SET CORRECT
         STA $D018       ;BITMAP BANK

MAINLP   JMP MAINLP