; Install script for ColourCycle 1.0
; $VER: ColourCycleInstallScript 1.0 (02.2.95)

; Strings and help information

(set bad-kick
(cat "This application requires KickStart 3.0 or greater!"
))

(set copy-main-help
(cat "This will install the ColourCycle software.\n\n"
	 "The 'ColourCycle' option refers to the main program.\n"
	 "The 'ColourCycle.guide' option refers to the AmigaGuide online context sensitive help.\n"
	 "The 'Colours' option refers to the sample projects. A new drawer called 'Colours' will be created automatically"
))

(set copy-icon-help "This will install a default icon to use for all ColourCycle projects.")

(set install-msg
(cat "Installation program for ColourCycle 1.0\n"
"An Intuition Screen Colour Cycler!\n\n"
"© Copyright 1994, 1995 Stuart MacKinnon. All rights reserved.\n\n"
"ColourCycle is Shareware. Please register if you use ColourCycle regulary!"
))

(set copy-guide "Do you wish to install the AmigaGuide documentation?")
(set copy-guide-help
(cat "This file outlines all of ColourCycle's features. It also outlines\n"
	 "icon tooltypes, menu functions, gadget functions, shareware\n"
	 "information etc\n\n"
	 "This file will also be used for the online help system."
))

(set copy-examples "Do you wish to install the Sample projects?")
(set copy-examples-help
(cat "The example projects will give you an\n"
	 "idea of what is possible with ColourCycle."
))

; make sure Kick 3.0 or higher is available

(if (< (/ (getversion) 65536) 39)
(
	(abort bad-kick)
))


(message install-msg)

(welcome)

; Install Program

(set colourcycle-dir
	(askdir
		(prompt "Please select a directory where ColourCycle can be installed. A directory called ColourCycle will be created here.\n")
		(help @askdir-help)
		(default (@default-dest))
		(newpath)
	)
)

(set @default-dest
	(tackon colourcycle-dir "ColourCycle")
)
;(prompt ("Creating ColourCycle directory..."))
(makedir @default-dest
	(prompt "Creating directory ColourCycle in the chosen place...")
	(infos)
	(help @makedir-help)
)

(copyfiles
	(prompt "Installing ColourCycle...")
	(source "")
	(dest @default-dest)
	(choices "ColourCycle" "ColourCycle.guide" "Colours")
	(help copy-main-help)
	(confirm)
	(infos)
)

(set exists-name
	(tackon @default-dest "ColourCycle.guide")
)

(if (exists exists-name (noreq))
	(copyfiles
		(source "AADA.pic")
		(dest @default-dest)
	)
)

(set exists-name
	(tackon @default-dest "Colours")
)

(set tool-name
	(tackon @default-dest "ColourCycle")
)

(if (exists exists-name (noreq))
	(foreach exists-name "#?"
		(
			(set icon-name
				(tackon exists-name @each-name)
			)
			(tooltype
				(dest icon-name)
				(setdefaulttool tool-name)
			)
		)
	)
)

(if	(askbool
		(prompt "Install the default icon in the ENVARC: drawer?")
		(default 0)
		(help copy-icon-help)
	)
	(
		(makedir "ENVARC:ColourCycle")
		(makedir "ENV:ColourCycle")
		(copyfiles
			(source "def_ColourCycleFile.info")
			(dest "ENVARC:ColourCycle")
		)
		(copyfiles
			(source "def_ColourCycleFile.info")
			(dest "ENV:ColourCycle")
;			(noguage)
		)
		(tooltype
			(dest "ENV:ColourCycle/def_ColourCycleFile")
			(setdefaulttool tool-name)
			(noposition)
		)
		(tooltype
			(dest "ENVARC:ColourCycle/def_ColourCycleFile")
			(setdefaulttool tool-name)
			(noposition)
		)
	)
)

(exit (quiet))