/*
 * RefoldMarks.ole
 *
 * USAGE: RefoldMarks.ole
 *
 * This module of my OLE system let to draw some little lines marking the
 * fold lines.
 *
 * HISTORY:
 * v1.01	a few bugs fixed
 *
 * v1.02	added a little gadget to preview refolds
 *
 * v1.03	bug fixed when module exit
 *
 * v1.04	aligned with the new server design v1.10
 *
 * $(C): (1994, Rocco Coluccelli, Bologna)
 * $VER: RefoldMarks.ole 1.04 (30.Nov.1994)
 */

OPTIONS RESULTS

PARSE ARG oleclip
PARSE VALUE GETCLIP(oleclip) WITH jobID modID box.left box.top char.w char.h olewin oleport olehost . . olepipe locale config .

IF ~SHOW('C',config) THEN
	refoldmarks = 2
ELSE
	PARSE VALUE GETCLIP(config) WITH refoldmarks','

	doallpages = 0

	folds. = 0
	folds.1.1 = 50
	folds.2.1 = 32; folds.2.2 = 68
	folds.3.1 = 26; folds.3.2 = 51; folds.3.3 = 76

DO j = 4 TO 10
	DO i = 1 TO j
		folds.j.i = i * 100 % (j + 1)
	END
END


ADDRESS VALUE oleport

IF OPENPORT(olehost) == NULL() THEN DO
	ERROR jobID modID 1 olehost
	SETJOB jobID 'end'
	EXIT 10
	END

rt_TAG = 'rt_pubscrname=' || userscreen 'rtez_flags=ezreqf_centertext'
st = GUIGads()
DO UNTIL st = 'end'

	CALL WAITPKT(olehost)
	pkt = GETPKT(olehost)

	IF pkt == NULL() THEN ITERATE

	PARSE VALUE GETARG(pkt) WITH cmd argv .
	SELECT

		WHEN cmd = 'MARKS' THEN DO
			PARSE VALUE GETARG(pkt,1) WITH n0 n1 .

			refoldmarks = RTGetLong(refoldmarks,,GetLocale(1),,rt_TAG 'rtgl_min=1 rtgl_max=9')

			g_str.n0 = refoldmarks; g_str.n1 = refoldmarks
			CALL Gadgets(2,n0,n1)
			CALL SETCLIP(config,refoldmarks',')
		END

		WHEN cmd = 'PAGE' THEN DO
			PARSE VALUE GETARG(pkt,1) WITH n0 .
			doallpages = ~doallpages
			g_str.n0 = doallpages
			CALL Gadgets(2,n0)
		END

		WHEN cmd = 'UNICONIFY' THEN
			CALL Gadgets(8,1,g_gads)

		WHEN cmd = 'HELP' THEN
			ABOUT jobID modID 'HELP' || st

		WHEN cmd = 'START' | cmd = 'QUIT' THEN
			st = 'end'

		OTHERWISE NOP
	END

	CALL REPLY(pkt,0)

END

CALL CLOSEPORT(olehost)

IF cmd = 'QUIT' THEN EXIT 0

folds = folds.refoldmarks.1
DO i = 2 TO refoldmarks
	folds = folds folds.refoldmarks.i
END
CALL SETCLIP(olepipe,doallpages folds)

SETJOB jobID modID + 1
EXIT 0


GetLocale: PROCEDURE EXPOSE locale
ARG strID

	strID = 'þ'strID'þ'; PARSE VALUE GETCLIP(locale) WITH (strID)text'Þ'

RETURN text


GUIGads:

	g_offx. = 2;	g_offx.1 = 0;			g_offx.3 = 2
	g_offy. = 2;	g_offy.1 = char.h + 1;	g_offy.3 = 3
	g_wid. = 8;				g_wid.1 = 0;			g_wid.3 = 12
	g_hei. = char.h + 4;	g_hei.1 = char.h + 1;	g_hei.3 = char.h + 6
	g_sx = char.w % 2;	g_sy = char.h % 4
	g_onoff. = 0
	g_offx.6 = 0;	g_offy.6 = 0;	g_hei.6 = 60

	box.left = box.left + g_sx; box.top = box.top + 2 * g_sy
	box.w = 24 * char.w

	n = 1; nmain = 1

	x = box.left; y = box.top
	CALL IniGad(6,1,2,,refoldmarks); x1 = x
	y = y + 4 * g_sy
	CALL IniGad(2,0,2,'MARKS %1' n  n - 1,refoldmarks)
	CALL IniGad(1,0,1,,GetLocale(1)); x = x1
	y = y + g_hei.6 - g_hei.2 - 8 * g_sy
	CALL IniGad(4,0,2,'PAGE%1' n,doallpages,GetLocale(2))

	y = y + g_hei.3 + 8 * g_sy
	CALL IniGad(2,3,0,'HELP',GetLocale(3))
	g_gads = IniGad(2,1,0,'START',GetLocale(4))

	box.h = y + g_hei.2 + 2 * g_sy - box.top
	WINDOW jobID modID (box.w + 2 * g_sx) (box.h + 2 * g_sy) 1 1
	CALL Gadgets(4,1,g_gads)

RETURN nmain


Gadgets:

	IF ARG(1) < 4 THEN
		DO i = 2 TO ARG(); n = ARG(i)
			IF ARG(1) ~= 1 THEN CALL DelGad(n,g_type.n)
			IF ARG(1) ~= 3 THEN CALL NewGad(n,g_type.n)
		END

	ELSE IF ARG(1) < 7 THEN
		DO n = ARG(2) TO ARG(3)
			IF ARG(1) ~= 4 THEN CALL DelGad(n,g_type.n)
			IF ARG(1) ~= 6 THEN CALL NewGad(n,g_type.n)
		END

	ELSE IF ARG(1) = 8 THEN
		DO n = ARG(2) TO ARG(3)
			IF g_onoff.n THEN CALL NewGad(n,g_type.n)
		END

	ELSE DO
		DO n = ARG(2) TO ARG(3)
			g_onoff.n = 0
			IF g_type.n ~= 1 & t ~= 6 THEN CALL RemoveGadget(olewin,GAD.n)
		END
		CALL SetAPen(olewin,0)
		CALL RectFill(olewin,box.left,box.top,box.left + box.w,box.top + box.h)
		CALL RefreshGadgets(olewin)
		END
RETURN


DelGad:
PARSE ARG n,t

	g_onoff.n = 0

	IF t ~= 1 & t ~= 6 THEN CALL RemoveGadget(olewin,GAD.n)

	x = g_xpos.n - g_offx.t; y = g_ypos.n - g_offy.t
	CALL SetAPen(olewin,0)
	CALL RectFill(olewin,x,y,x + g_len.n,y + g_hei.t)

RETURN


NewGad:
PARSE ARG n,t

	g_onoff.n = 1

	IF t = 2 THEN
		CALL AddGadGet(olewin,g_xpos.n,g_ypos.n,GAD.n,g_str.n,g_msg.n)

	ELSE IF t = 4 THEN
		CALL AddGadGet(olewin,g_xpos.n,g_ypos.n,GAD.n,D2C(32 + g_str.n * 183),g_msg.n)

	ELSE IF t = 6 THEN DO
		CALL SetApen(olewin,2)
		CALL RectFill(olewin,g_xpos.n,g_ypos.n,g_xpos.n + g_len.n,g_ypos.n + g_hei.t)

		x1 = g_xpos.n + g_len.n % 10
		x2 = x1 + g_len.n % 10
		ny = g_str.n
		CALL SetApen(olewin,1)
		DO j = 1 TO ny
			y = g_ypos.n + (folds.ny.j * g_hei.t) % 100
			CALL Move(olewin,x1,y); CALL Draw(olewin,x2,y)
		END
	END

	ELSE DO
		CALL SetAPen(olewin,1)
		CALL Move(olewin,g_xpos.n,g_ypos.n)
		CALL Text(olewin,g_str.n)
	END
RETURN


IniGad:
PARSE ARG t,na,nx,g_msg.n,g_str.n,var

	x = x + nx * g_sx

	IF t = 6 THEN
		g_len.n = 2 * g_hei.t % 3
	ELSE
		g_len.n = LENGTH(g_str.n) * char.w + g_wid.t

	IF na > 0 THEN x = box.left + (na - 1) * (box.w - g_len.n) % 2 + nx * g_sx

	g_xpos.n = x + g_offx.t; g_ypos.n = y + g_offy.t; g_type.n = t
	x = x + g_len.n
	n = n + 1

	IF t = 4 THEN CALL IniGad(1,0,1,,var)

RETURN n - 1